basis/alien/libraries/finder/linux/linux.factor

   1 ! Copyright (C) 2013 Björn Lindqvist, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: alien.libraries.finder arrays assocs
   4 combinators.short-circuit io io.encodings.utf8 io.files
   5 io.files.info io.launcher kernel sequences sets splitting system
   6 unicode.categories ;
   7 IN: alien.libraries.finder.linux
   8
   9 <PRIVATE
  10
  11 CONSTANT: mach-map {
  12     { ppc.64 { "libc6" "64bit" } }
  13     { x86.32 { "libc6" "x32" } }
  14     { x86.64 { "libc6" "x86-64" } }
  15 }
  16
  17 : parse-ldconfig-lines ( string -- triple )
  18     [
  19         "=>" split1 [ [ blank? ] trim ] bi@
  20         [
  21             " " split1 [ "()" in? ] trim "," split
  22             [ [ blank? ] trim ] map
  23             [ "OS ABI:" head? not ] filter
  24         ] dip 3array
  25     ] map ;
  26
  27 : load-ldconfig-cache ( -- seq )
  28     "/sbin/ldconfig -p" utf8 [ lines ] with-process-reader
  29     rest parse-ldconfig-lines ;
  30
  31 : ldconfig-arch ( -- str )
  32     mach-map cpu of { "libc6" } or ;
  33
  34 : name-matches? ( lib triple -- ? )
  35     first swap ?head [ ?first CHAR: . = ] [ drop f ] if ;
  36
  37 : arch-matches? ( lib triple -- ? )
  38     [ drop ldconfig-arch ] [ second swap subset? ] bi* ;
  39
  40 : ldconfig-matches? ( lib triple -- ? )
  41     { [ name-matches? ] [ arch-matches? ] } 2&& ;
  42
  43 : ldconfig-find-soname ( lib -- seq )
  44     load-ldconfig-cache [ ldconfig-matches? ] with filter
  45     [ third ] map ;
  46
  47 PRIVATE>
  48
  49 M: linux find-library*
  50     "lib" prepend ldconfig-find-soname [
  51         { [ exists? ] [ file-info regular-file? ] } 1&&
  52     ] map-find nip ;