basis/alien/libraries/finder/linux/linux.factor

   1 ! Copyright (C) 2013 Björn Lindqvist, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: alien.libraries alien.libraries.finder arrays assocs
   4 combinators.short-circuit io io.encodings.utf8 io.files
   5 io.files.info io.launcher kernel sequences sets splitting system
   6 unicode.categories ;
   7 IN: alien.libraries.finder.linux
   8
   9 <PRIVATE
  10
  11 CONSTANT: mach-map {
  12     { ppc.64 { "libc6" "64bit" } }
  13     { x86.32 { "libc6" "x32" } }
  14     { x86.64 { "libc6" "x86-64" } }
  15 }
  16
  17 : parse-ldconfig-lines ( string -- triple )
  18     [
  19         "=>" split1 [ [ blank? ] trim ] bi@
  20         [ " " split1 [ "()" in? ] trim "," split ] dip 3array
  21     ] map ;
  22
  23 : load-ldconfig-cache ( -- seq )
  24     "/sbin/ldconfig -p" utf8 [ lines ] with-process-reader
  25     rest parse-ldconfig-lines ;
  26
  27 : ldconfig-arch ( -- str )
  28     mach-map cpu of { "libc6" } or ;
  29
  30 : ldconfig-matches? ( lib triple -- ? )
  31     { [ first head? ] [ nip second ldconfig-arch subset? ] } 2&& ;
  32
  33 : ldconfig-find-soname ( lib -- seq )
  34     load-ldconfig-cache [ ldconfig-matches? ] with filter [ third ] map ;
  35
  36 PRIVATE>
  37
  38 M: linux find-library
  39     "lib" ".so" surround ldconfig-find-soname [
  40         { [ exists? ] [ file-info regular-file? ] } 1&&
  41     ] map-find nip ;