basis/alien/libraries/finder/linux/linux.factor

   1 ! Copyright (C) 2013 Björn Lindqvist, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license
   3 USING: alien.libraries alien.libraries.finder arrays assocs
   4 combinators.short-circuit io io.encodings.utf8 io.files
   5 io.files.info io.launcher kernel sequences sets splitting system
   6 unicode.categories ;
   7 IN: alien.libraries.finder.linux
   8
   9 <PRIVATE
  10
  11 CONSTANT: mach-map {
  12     { ppc.64 { "libc6" "64bit" } }
  13     { x86.32 { "libc6" "x32" } }
  14     { x86.64 { "libc6" "x86-64" } }
  15 }
  16
  17 : parse-ldconfig-lines ( string -- triple )
  18     [
  19
  20         "=>" split1 [ [ blank? ] trim ] bi@
  21         [ " " split1 [ "()" in? ] trim "," split ] dip 3array
  22     ] map ;
  23
  24 : load-ldconfig-cache ( -- seq )
  25     "/sbin/ldconfig -p" utf8 [ lines ] with-process-reader
  26     rest parse-ldconfig-lines ;
  27
  28 : ldconfig-arch ( -- str )
  29     mach-map cpu of { "libc6" } or ;
  30
  31 : ldconfig-matches? ( lib triple -- ? )
  32     { [ first head? ] [ nip second ldconfig-arch subset? ] } 2&& ;
  33
  34 : ldconfig-find-soname ( lib -- seq )
  35     load-ldconfig-cache [ ldconfig-matches? ] with filter [ third ] map ;
  36
  37 PRIVATE>
  38
  39 M: linux find-library
  40     "lib" ".so" surround ldconfig-find-soname [
  41         { [ exists? ] [ file-info regular-file? ] } 1&&
  42     ] map-find nip ;