basis/alien/syntax/syntax-docs.factor

   1 IN: alien.syntax
   2 USING: alien alien.c-types alien.parser alien.libraries
   3 classes.struct help.markup help.syntax see ;
   4
   5 HELP: DLL"
   6 { $syntax "DLL\" path\"" }
   7 { $values { "path" "a pathname string" } }
   8 { $description "Constructs a DLL handle at parse time." } ;
   9
  10 HELP: ALIEN:
  11 { $syntax "ALIEN: address" }
  12 { $values { "address" "a non-negative hexadecimal integer" } }
  13 { $description "Creates an alien object at parse time." }
  14 { $notes "Alien objects are invalidated between image saves and loads, and hence source files should not contain alien literals; this word is for interactive use only. See " { $link "alien-expiry" } " for details." } ;
  15
  16 ARTICLE: "syntax-aliens" "Alien object literal syntax"
  17 { $subsections
  18     POSTPONE: ALIEN:
  19     POSTPONE: DLL"
  20 } ;
  21
  22 HELP: LIBRARY:
  23 { $syntax "LIBRARY: name" }
  24 { $values { "name" "a logical library name" } }
  25 { $description "Sets the logical library for consequent " { $link POSTPONE: FUNCTION: } ", " { $link POSTPONE: C-GLOBAL: } " and " { $link POSTPONE: CALLBACK: } " definitions, as well as " { $link POSTPONE: &: } " forms." }
  26 { $notes "Logical library names are defined with the " { $link add-library } " word." } ;
  27
  28 HELP: FUNCTION:
  29 { $syntax "FUNCTION: return name ( parameters ) ;" }
  30 { $values { "return" "a C return type" } { "name" "a C function name" } { "parameters" "a comma-separated sequence of type/name pairs; " { $snippet "type1 arg1, type2 arg2, ..." } } }
  31 { $description "Defines a new word " { $snippet "name" } " which calls the C library function with the same " { $snippet "name" } " in the logical library given by the most recent " { $link POSTPONE: LIBRARY: } " declaration."
  32 $nl
  33 "The new word must be compiled before being executed." }
  34 { $examples
  35 "For example, suppose the " { $snippet "foo" } " library exports the following function:"
  36 { $code
  37     "void the_answer(char* question, int value) {"
  38     "    printf(\"The answer to %s is %d.\n\",question,value);"
  39     "}"
  40 }
  41 "You can define a word for invoking it:"
  42 { $unchecked-example
  43     "LIBRARY: foo\nFUNCTION: void the_answer ( c-string question, int value ) ;"
  44     "\"the question\" 42 the_answer"
  45     "The answer to the question is 42."
  46 } }
  47 "Using the " { $link c-string } " type instead of " { $snippet "char*" } " causes the FFI to automatically convert Factor strings to C strings. See " { $link "c-strings" } " for more information on using strings with the FFI."
  48 { $notes "Note that the parentheses and commas are only syntax sugar and can be omitted; they serve no purpose other than to make the declaration easier to read. The following definitions are equivalent:"
  49 { $code
  50     "FUNCTION: void glHint ( GLenum target, GLenum mode ) ;"
  51     "FUNCTION: void glHint GLenum target GLenum mode ;"
  52 }
  53 "To make a Factor word with a name different from the C function, use " { $link POSTPONE: FUNCTION-ALIAS: } "." } ;
  54
  55 HELP: FUNCTION-ALIAS:
  56 { $syntax "FUNCTION-ALIAS: factor-name
  57     return c_name ( parameters ) ;" }
  58 { $values { "factor-name" "a Factor word name" } { "return" "a C return type" } { "name" "a C function name" } { "parameters" "a comma-separated sequence of type/name pairs; " { $snippet "type1 arg1, type2 arg2, ..." } } }
  59 { $description "Defines a new word " { $snippet "factor-name" } " which calls the C library function named " { $snippet "c_name" } " in the logical library given by the most recent " { $link POSTPONE: LIBRARY: } " declaration."
  60 $nl
  61 "The new word must be compiled before being executed." }
  62 { $notes "Note that the parentheses and commas are only syntax sugar and can be omitted. They serve no purpose other than to make the declaration easier to read." } ;
  63
  64 { POSTPONE: FUNCTION: POSTPONE: FUNCTION-ALIAS: } related-words
  65
  66 HELP: TYPEDEF:
  67 { $syntax "TYPEDEF: old new" }
  68 { $values { "old" "a C type" } { "new" "a C type" } }
  69 { $description "Aliases the C type " { $snippet "old" } " under the name " { $snippet "new" } "." }
  70 { $notes "This word differs from " { $link typedef } " in that it runs at parse time, to ensure correct ordering of operations when loading source files. Words defined in source files are compiled before top-level forms are run, so if a source file defines C binding words and uses " { $link typedef } ", the type alias won't be available at compile time." } ;
  71
  72 HELP: ENUM:
  73 { $syntax "ENUM: type/f words... ;" }
  74 { $values { "type" "a name to typedef to int or f" } { "words" "a sequence of word names" } }
  75 { $description "Creates a sequence of word definitions in the current vocabulary. Each word pushes an integer according to the rules of C enums." }
  76 { $notes "This word emulates a C-style " { $snippet "enum" } " in Factor. While this feature can be used for any purpose, using integer constants is discouraged unless it is for interfacing with C libraries. Factor code should use " { $link "words.symbol" } " or " { $link "singletons" } " instead." }
  77 { $examples
  78     "Here is an example enumeration definition:"
  79     { $code "ENUM: color_t red { green 3 } blue ;" }
  80     "It is equivalent to the following series of definitions:"
  81     { $code "CONSTANT: red 0" "CONSTANT: green 3" "CONSTANT: blue 4" }
  82 } ;
  83
  84 HELP: C-TYPE:
  85 { $syntax "C-TYPE: type" }
  86 { $values { "type" "a new C type" } }
  87 { $description "Defines a new, opaque C type. Since it is opaque, " { $snippet "type" } " will not be directly usable as a parameter or return type of a " { $link POSTPONE: FUNCTION: } " or as a slot of a " { $link POSTPONE: STRUCT: } ". However, it can be used as the type of a " { $link pointer } "."
  88 { $snippet "C-TYPE:" } " can also be used to forward declare C types, allowing circular dependencies to occur between types. For example:"
  89 { $code """C-TYPE: forward
  90 STRUCT: backward { x forward* } ;
  91 STRUCT: forward { x backward* } ; """ } }
  92 { $notes "Primitive C types are displayed using " { $snippet "C-TYPE:" } " syntax when they are " { $link see } "n." } ;
  93
  94 HELP: CALLBACK:
  95 { $syntax "CALLBACK: return type ( parameters ) ;" }
  96 { $values { "return" "a C return type" } { "type" "a type name" } { "parameters" "a comma-separated sequence of type/name pairs; " { $snippet "type1 arg1, type2 arg2, ..." } } }
  97 { $description "Defines a new function pointer C type word " { $snippet "type" } ". The newly defined word works both as a C type and as a wrapper for " { $link alien-callback } " for callbacks that accept the given return type and parameters. The ABI of the callback is decided from the ABI of the active " { $link POSTPONE: LIBRARY: } " declaration." }
  98 { $examples
  99     { $code
 100         "CALLBACK: bool FakeCallback ( int message, void* payload ) ;"
 101         ": MyFakeCallback ( -- alien )"
 102         "    [| message payload |"
 103         "        \"message #\" write"
 104         "        message number>string write"
 105         "        \" received\" write nl"
 106         "        t"
 107         "    ] FakeCallback ;"
 108     }
 109 } ;
 110
 111 HELP: &:
 112 { $syntax "&: symbol" }
 113 { $values { "symbol" "A C global variable name" } }
 114 { $description "Pushes the address of a symbol named " { $snippet "symbol" } " from the current library, set with " { $link POSTPONE: LIBRARY: } "." } ;
 115
 116 HELP: typedef
 117 { $values { "old" "a C type" } { "new" "a C type" } }
 118 { $description "Aliases the C type " { $snippet "old" } " under the name " { $snippet "new" } "." }
 119 { $notes "Using this word in the same source file which defines C bindings can cause problems, because words are compiled before top-level forms are run. Use the " { $link POSTPONE: TYPEDEF: } " word instead." } ;
 120
 121 { POSTPONE: TYPEDEF: typedef } related-words
 122
 123 HELP: c-struct?
 124 { $values { "c-type" "a C type" } { "?" "a boolean" } }
 125 { $description "Tests if a C type is a structure defined by " { $link POSTPONE: STRUCT: } "." } ;
 126
 127 HELP: C-GLOBAL:
 128 { $syntax "C-GLOBAL: type name" }
 129 { $values { "type" "a C type" } { "name" "a C global variable name" } }
 130 { $description "Defines a new word named " { $snippet "name" } " which accesses a global variable in the current library, set with " { $link POSTPONE: LIBRARY: } "." } ;