basis/ascii/ascii.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators.short-circuit hints kernel math math.order
   4 sequences strings ;
   5 IN: ascii
   6
   7 : ascii? ( ch -- ? ) 0 127 between? ; inline
   8 : blank? ( ch -- ? ) " \t\n\r" member? ; inline
   9 : letter? ( ch -- ? ) CHAR: a CHAR: z between? ; inline
  10 : LETTER? ( ch -- ? ) CHAR: A CHAR: Z between? ; inline
  11 : digit? ( ch -- ? ) CHAR: 0 CHAR: 9 between? ; inline
  12 : printable? ( ch -- ? ) CHAR: \s CHAR: ~ between? ; inline
  13 : control? ( ch -- ? ) { [ 0 0x1F between? ] [ 0x7F = ] } 1|| ; inline
  14 : quotable? ( ch -- ? ) { [ printable? ] [ "\"\\" member? not ] } 1&& ; inline
  15 : Letter? ( ch -- ? ) { [ letter? ] [ LETTER? ] } 1|| ; inline
  16 : alpha? ( ch -- ? ) { [ Letter? ] [ digit? ] } 1|| ; inline
  17 : ch>lower ( ch -- lower ) dup LETTER? [ 0x20 + ] when ; inline
  18 : >lower ( str -- lower ) [ ch>lower ] map ;
  19 : ch>upper ( ch -- upper ) dup letter? [ 0x20 - ] when ; inline
  20 : >upper ( str -- upper ) [ ch>upper ] map ;
  21 : >words ( str -- words )
  22     [ dup empty? not ] [
  23         dup [ blank? ] find drop
  24         [ [ 1 ] when-zero cut-slice swap ]
  25         [ f 0 rot [ length ] keep <slice> ] if*
  26     ] produce nip ;
  27 : capitalize ( str -- str' ) unclip [ >lower ] [ ch>upper ] bi* prefix ;
  28 : >title ( str -- title ) >words [ capitalize ] map concat ;
  29
  30 HINTS: >lower string ;
  31 HINTS: >upper string ;