basis/base64/base64.factor

   1 ! Copyright (C) 2008 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators io io.binary io.encodings.binary
   4 io.streams.byte-array kernel math namespaces
   5 sequences strings ;
   6 IN: base64
   7
   8 ERROR: malformed-base64 ;
   9
  10 <PRIVATE
  11
  12 : read1-ignoring ( ignoring -- ch )
  13     read1 2dup swap member? [ drop read1-ignoring ] [ nip ] if ;
  14
  15 : read-ignoring ( ignoring n -- str )
  16     [ drop read1-ignoring ] with { } map-integers
  17     [ { f 0 } member? not ] filter
  18     [ f ] [ >string ] if-empty ;
  19
  20 : ch>base64 ( ch -- ch )
  21     "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
  22     nth ; inline
  23
  24 : base64>ch ( ch -- ch )
  25     {
  26         f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f
  27         f f f f f f f f f f 62 f f f 63 52 53 54 55 56 57 58 59 60 61 f f
  28         f 0 f f f 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21
  29         22 23 24 25 f f f f f f 26 27 28 29 30 31 32 33 34 35 36 37 38 39
  30         40 41 42 43 44 45 46 47 48 49 50 51
  31     } nth [ malformed-base64 ] unless* ; inline
  32
  33 SYMBOL: column
  34
  35 : write1-lines ( ch -- )
  36     write1
  37     column get [
  38         1 + [ 76 = [ B{ CHAR: \r CHAR: \n } write ] when ]
  39         [ 76 mod column set ] bi
  40     ] when* ;
  41
  42 : write-lines ( str -- )
  43     [ write1-lines ] each ;
  44
  45 : encode3 ( seq -- )
  46     be> 4 iota <reversed> [
  47         -6 * shift 0x3f bitand ch>base64 write1-lines
  48     ] with each ; inline
  49
  50 : encode-pad ( seq n -- )
  51     [ 3 0 pad-tail binary [ encode3 ] with-byte-writer ]
  52     [ 1 + ] bi* head-slice 4 CHAR: = pad-tail write-lines ; inline
  53
  54 : decode4 ( seq -- )
  55     [ 0 [ base64>ch swap 6 shift bitor ] reduce 3 >be ]
  56     [ [ CHAR: = = ] count ] bi head-slice*
  57     [ write1 ] each ; inline
  58
  59 PRIVATE>
  60
  61 : encode-base64 ( -- )
  62     3 read dup length {
  63         { 0 [ drop ] }
  64         { 3 [ encode3 encode-base64 ] }
  65         [ encode-pad encode-base64 ]
  66     } case ;
  67
  68 : encode-base64-lines ( -- )
  69     0 column [ encode-base64 ] with-variable ;
  70
  71 : decode-base64 ( -- )
  72     "\n\r" 4 read-ignoring dup length {
  73         { 0 [ drop ] }
  74         { 4 [ decode4 decode-base64 ] }
  75         [ malformed-base64 ]
  76     } case ;
  77
  78 : >base64 ( seq -- base64 )
  79     binary [ binary [ encode-base64 ] with-byte-reader ] with-byte-writer ;
  80
  81 : base64> ( base64 -- seq )
  82     binary [ binary [ decode-base64 ] with-byte-reader ] with-byte-writer ;
  83
  84 : >base64-lines ( seq -- base64 )
  85     binary [ binary [ encode-base64-lines ] with-byte-reader ] with-byte-writer ;