basis/base64/base64.factor

   1 ! Copyright (C) 2008 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators io io.binary io.encodings.binary
   4 io.streams.byte-array kernel math namespaces
   5 sequences strings io.crlf ;
   6 IN: base64
   7
   8 ERROR: malformed-base64 ;
   9
  10 <PRIVATE
  11
  12 : read1-ignoring ( ignoring -- ch )
  13     read1 2dup swap member? [ drop read1-ignoring ] [ nip ] if ;
  14
  15 : read-ignoring ( ignoring n -- str )
  16     [ drop read1-ignoring ] with map harvest
  17     [ f ] [ >string ] if-empty ;
  18
  19 : ch>base64 ( ch -- ch )
  20     "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
  21     nth ; inline
  22
  23 : base64>ch ( ch -- ch )
  24     {
  25         f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f
  26         f f f f f f f f f f 62 f f f 63 52 53 54 55 56 57 58 59 60 61 f f
  27         f 0 f f f 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21
  28         22 23 24 25 f f f f f f 26 27 28 29 30 31 32 33 34 35 36 37 38 39
  29         40 41 42 43 44 45 46 47 48 49 50 51
  30     } nth [ malformed-base64 ] unless* ; inline
  31
  32 SYMBOL: column
  33
  34 : write1-lines ( ch -- )
  35     write1
  36     column get [
  37         1 + [ 76 = [ crlf ] when ]
  38         [ 76 mod column set ] bi
  39     ] when* ;
  40
  41 : write-lines ( str -- )
  42     [ write1-lines ] each ;
  43
  44 : encode3 ( seq -- )
  45     be> 4 <reversed> [
  46         -6 * shift HEX: 3f bitand ch>base64 write1-lines
  47     ] with each ; inline
  48
  49 : encode-pad ( seq n -- )
  50     [ 3 0 pad-tail binary [ encode3 ] with-byte-writer ]
  51     [ 1 + ] bi* head-slice 4 CHAR: = pad-tail write-lines ; inline
  52
  53 : decode4 ( seq -- )
  54     [ 0 [ base64>ch swap 6 shift bitor ] reduce 3 >be ]
  55     [ [ CHAR: = = ] count ] bi head-slice*
  56     [ write1 ] each ; inline
  57
  58 PRIVATE>
  59
  60 : encode-base64 ( -- )
  61     3 read dup length {
  62         { 0 [ drop ] }
  63         { 3 [ encode3 encode-base64 ] }
  64         [ encode-pad encode-base64 ]
  65     } case ;
  66
  67 : encode-base64-lines ( -- )
  68     0 column [ encode-base64 ] with-variable ;
  69
  70 : decode-base64 ( -- )
  71     "\n\r" 4 read-ignoring dup length {
  72         { 0 [ drop ] }
  73         { 4 [ decode4 decode-base64 ] }
  74         [ malformed-base64 ]
  75     } case ;
  76
  77 : >base64 ( seq -- base64 )
  78     binary [ binary [ encode-base64 ] with-byte-reader ] with-byte-writer ;
  79
  80 : base64> ( base64 -- seq )
  81     binary [ binary [ decode-base64 ] with-byte-reader ] with-byte-writer ;
  82
  83 : >base64-lines ( seq -- base64 )
  84     binary [ binary [ encode-base64-lines ] with-byte-reader ] with-byte-writer ;