basis/base64/base64.factor

   1 ! Copyright (C) 2008 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays combinators fry io io.binary io.encodings.binary
   4 io.streams.byte-array kernel literals math namespaces sbufs
   5 sequences ;
   6 IN: base64
   7
   8 ERROR: malformed-base64 ;
   9
  10 <PRIVATE
  11
  12 : read1-ignoring ( ignoring stream -- ch )
  13     dup stream-read1 pick dupd member?
  14     [ drop read1-ignoring ] [ 2nip ] if ; inline recursive
  15
  16 : push-ignoring ( accum ch -- accum )
  17     dup { f 0 } member-eq? [ drop ] [ suffix! ] if ; inline
  18
  19 : read-ignoring ( n ignoring stream -- str/f )
  20     [ [ <sbuf> ] keep ] 2dip
  21     '[ _ _ read1-ignoring push-ignoring ] times
  22     [ f ] [ "" like ] if-empty ; inline
  23
  24 <<
  25 CONSTANT: alphabet
  26     "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
  27 >>
  28
  29 : alphabet-inverse ( alphabet -- seq )
  30     dup supremum 1 + f <array> [
  31         '[ swap _ set-nth ] each-index
  32     ] keep ;
  33
  34 : ch>base64 ( ch -- ch )
  35     alphabet nth ; inline
  36
  37 : base64>ch ( ch -- ch )
  38     $[ alphabet alphabet-inverse 0 CHAR: = pick set-nth ] nth
  39     [ malformed-base64 ] unless* ; inline
  40
  41 SYMBOL: column
  42
  43 : write1-lines ( column/f ch stream -- column' )
  44     [ stream-write1 ] keep swap [
  45         1 + swap
  46         '[ 76 = [ B{ CHAR: \r CHAR: \n } _ stream-write ] when ]
  47         [ 76 mod ] bi
  48     ] [ drop f ] if* ;
  49
  50 : write-lines ( str -- )
  51     column output-stream get '[
  52         swap [ _ write1-lines ] each
  53     ] change ;
  54
  55 : encode3 ( seq -- )
  56     column output-stream get '[
  57         swap be> { -18 -12 -6 0 } [
  58             shift 0x3f bitand ch>base64 _ write1-lines
  59         ] with each
  60     ] change ; inline
  61
  62 : encode-pad ( seq n -- )
  63     [ 3 0 pad-tail binary [ encode3 ] with-byte-writer ]
  64     [ 1 + ] bi* head-slice 4 CHAR: = pad-tail write-lines ; inline
  65
  66 : decode4 ( seq -- )
  67     [ 0 [ base64>ch swap 6 shift bitor ] reduce 3 >be ]
  68     [ [ CHAR: = = ] count ] bi head-slice*
  69     output-stream get '[ _ stream-write1 ] each ; inline
  70
  71 : (encode-base64) ( stream -- )
  72     3 over stream-read dup length {
  73         { 0 [ 2drop ] }
  74         { 3 [ encode3 (encode-base64) ] }
  75         [ encode-pad (encode-base64) ]
  76     } case ;
  77
  78 PRIVATE>
  79
  80 : encode-base64 ( -- )
  81     input-stream get (encode-base64) ;
  82
  83 : encode-base64-lines ( -- )
  84     0 column [ encode-base64 ] with-variable ;
  85
  86 <PRIVATE
  87
  88 : (decode-base64) ( stream -- )
  89     4 "\n\r" pick read-ignoring dup length {
  90         { 0 [ 2drop ] }
  91         { 4 [ decode4 (decode-base64) ] }
  92         [ malformed-base64 ]
  93     } case ;
  94
  95 PRIVATE>
  96
  97 : decode-base64 ( -- )
  98     input-stream get (decode-base64) ;
  99
 100 : >base64 ( seq -- base64 )
 101     binary [ binary [ encode-base64 ] with-byte-reader ] with-byte-writer ;
 102
 103 : base64> ( base64 -- seq )
 104     binary [ binary [ decode-base64 ] with-byte-reader ] with-byte-writer ;
 105
 106 : >base64-lines ( seq -- base64 )
 107     binary [ binary [ encode-base64-lines ] with-byte-reader ] with-byte-writer ;