basis/base64/base64.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math sequences io.binary splitting grouping ;
   4 IN: base64
   5
   6 <PRIVATE
   7
   8 : count-end ( seq quot -- count )
   9     >r [ length ] keep r> find-last drop dup [ - 1- ] [ 2drop 0 ] if ; inline
  10
  11 : ch>base64 ( ch -- ch )
  12     "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/" nth ;
  13
  14 : base64>ch ( ch -- ch )
  15     {
  16         f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f
  17         f f f f f f f f f f 62 f f f 63 52 53 54 55 56 57 58 59 60 61 f f
  18         f 0 f f f 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21
  19         22 23 24 25 f f f f f f 26 27 28 29 30 31 32 33 34 35 36 37 38 39
  20         40 41 42 43 44 45 46 47 48 49 50 51
  21     } nth ;
  22
  23 : encode3 ( seq -- seq )
  24     be> 4 <reversed> [ -6 * shift HEX: 3f bitand ch>base64 ] with B{ } map-as ;
  25
  26 : decode4 ( str -- str )
  27     0 [ base64>ch swap 6 shift bitor ] reduce 3 >be ;
  28
  29 : >base64-rem ( str -- str )
  30     [ 3 0 pad-right encode3 ] [ length 1+ ] bi head 4 CHAR: = pad-right ;
  31
  32 PRIVATE>
  33
  34 : >base64 ( seq -- base64 )
  35     #! cut string into two pieces, convert 3 bytes at a time
  36     #! pad string with = when not enough bits
  37     dup length dup 3 mod - cut
  38     [ 3 <groups> [ encode3 ] map concat ]
  39     [ [ "" ] [ >base64-rem ] if-empty ]
  40     bi* append ;
  41
  42 : base64> ( base64 -- str )
  43     #! input length must be a multiple of 4
  44     [ 4 <groups> [ decode4 ] map concat ]
  45     [ [ CHAR: = = not ] count-end ]
  46     bi head* ;