basis/bit-arrays/bit-arrays.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types accessors math alien.accessors kernel
   4 kernel.private locals sequences sequences.private byte-arrays
   5 parser prettyprint.custom fry ;
   6 IN: bit-arrays
   7
   8 TUPLE: bit-array
   9 { length array-capacity read-only }
  10 { underlying byte-array read-only } ;
  11
  12 <PRIVATE
  13
  14 : n>byte ( m -- n ) -3 shift ; inline
  15
  16 : byte/bit ( n alien -- byte bit )
  17     over n>byte alien-unsigned-1 swap 7 bitand ; inline
  18
  19 : set-bit ( ? byte bit -- byte )
  20     2^ rot [ bitor ] [ bitnot bitand ] if ; inline
  21
  22 : bits>cells ( m -- n ) 31 + -5 shift ; inline
  23
  24 : bits>bytes ( m -- n ) 7 + n>byte ; inline
  25
  26 : (set-bits) ( bit-array n -- )
  27     [ [ length bits>cells ] keep ] dip swap underlying>>
  28     '[ 2 shift [ _ _ ] dip set-alien-unsigned-4 ] each ; inline
  29
  30 PRIVATE>
  31
  32 : <bit-array> ( n -- bit-array )
  33     dup bits>bytes <byte-array> bit-array boa ; inline
  34
  35 M: bit-array length length>> ;
  36
  37 M: bit-array nth-unsafe
  38     [ >fixnum ] [ underlying>> ] bi* byte/bit bit? ;
  39
  40 M: bit-array set-nth-unsafe
  41     [ >fixnum ] [ underlying>> ] bi*
  42     [ byte/bit set-bit ] 2keep
  43     swap n>byte set-alien-unsigned-1 ;
  44
  45 : clear-bits ( bit-array -- ) 0 (set-bits) ;
  46
  47 : set-bits ( bit-array -- ) -1 (set-bits) ;
  48
  49 M: bit-array clone
  50     [ length>> ] [ underlying>> clone ] bi bit-array boa ;
  51
  52 : >bit-array ( seq -- bit-array )
  53     T{ bit-array f 0 B{ } } clone-like ; inline
  54
  55 M: bit-array like drop dup bit-array? [ >bit-array ] unless ;
  56
  57 M: bit-array new-sequence drop <bit-array> ;
  58
  59 M: bit-array equal?
  60     over bit-array? [ sequence= ] [ 2drop f ] if ;
  61
  62 M: bit-array resize
  63     [ drop ] [
  64         [ bits>bytes ] [ underlying>> ] bi*
  65         resize-byte-array
  66     ] 2bi
  67     bit-array boa ;
  68
  69 M: bit-array byte-length length 7 + -3 shift ;
  70
  71 : ?{ \ } [ >bit-array ] parse-literal ; parsing
  72
  73 :: integer>bit-array ( n -- bit-array )
  74     n zero? [ 0 <bit-array> ] [
  75         [let | out [ n log2 1+ <bit-array> ] i! [ 0 ] n'! [ n ] |
  76             [ n' zero? ] [
  77                 n' out underlying>> i set-alien-unsigned-1
  78                 n' -8 shift n'!
  79                 i 1+ i!
  80             ] [ ] until
  81             out
  82         ]
  83     ] if ;
  84
  85 : bit-array>integer ( bit-array -- n )
  86     0 swap underlying>> dup length <reversed> [
  87         alien-unsigned-1 swap 8 shift bitor
  88     ] with each ;
  89
  90 INSTANCE: bit-array sequence
  91
  92 M: bit-array pprint-delims drop \ ?{ \ } ;
  93 M: bit-array >pprint-sequence ;
  94 M: bit-array pprint* pprint-object ;