basis/bit-arrays/bit-arrays.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types accessors math alien.accessors kernel
   4 kernel.private sequences sequences.private byte-arrays
   5 parser prettyprint.custom fry ;
   6 IN: bit-arrays
   7
   8 TUPLE: bit-array
   9 { length array-capacity read-only }
  10 { underlying byte-array read-only } ;
  11
  12 <PRIVATE
  13
  14 : n>byte ( m -- n ) -3 shift ; inline
  15
  16 : byte/bit ( n alien -- byte bit )
  17     over n>byte alien-unsigned-1 swap 7 bitand ; inline
  18
  19 : set-bit ( ? byte bit -- byte )
  20     2^ rot [ bitor ] [ bitnot bitand ] if ; inline
  21
  22 : bits>cells ( m -- n ) 31 + -5 shift ; inline
  23
  24 : bits>bytes ( m -- n ) 7 + n>byte ; inline
  25
  26 : (set-bits) ( bit-array n -- )
  27     [ [ length bits>cells ] keep ] dip swap underlying>>
  28     '[ 2 shift [ _ _ ] dip set-alien-unsigned-4 ] each ; inline
  29
  30 PRIVATE>
  31
  32 : <bit-array> ( n -- bit-array )
  33     dup bits>bytes <byte-array> bit-array boa ; inline
  34
  35 M: bit-array length length>> ;
  36
  37 M: bit-array nth-unsafe
  38     [ >fixnum ] [ underlying>> ] bi* byte/bit bit? ;
  39
  40 M: bit-array set-nth-unsafe
  41     [ >fixnum ] [ underlying>> ] bi*
  42     [ byte/bit set-bit ] 2keep
  43     swap n>byte set-alien-unsigned-1 ;
  44
  45 GENERIC: clear-bits ( bit-array -- )
  46
  47 M: bit-array clear-bits 0 (set-bits) ;
  48
  49 GENERIC: set-bits ( bit-array -- )
  50
  51 M: bit-array set-bits -1 (set-bits) ;
  52
  53 M: bit-array clone
  54     [ length>> ] [ underlying>> clone ] bi bit-array boa ;
  55
  56 : >bit-array ( seq -- bit-array )
  57     T{ bit-array f 0 B{ } } clone-like ; inline
  58
  59 M: bit-array like drop dup bit-array? [ >bit-array ] unless ;
  60
  61 M: bit-array new-sequence drop <bit-array> ;
  62
  63 M: bit-array equal?
  64     over bit-array? [ [ underlying>> ] bi@ sequence= ] [ 2drop f ] if ;
  65
  66 M: bit-array resize
  67     [ drop ] [
  68         [ bits>bytes ] [ underlying>> ] bi*
  69         resize-byte-array
  70     ] 2bi
  71     bit-array boa ;
  72
  73 M: bit-array byte-length length 7 + -3 shift ;
  74
  75 SYNTAX: ?{ \ } [ >bit-array ] parse-literal ;
  76
  77 : integer>bit-array ( n -- bit-array )
  78     dup 0 = [
  79         <bit-array>
  80     ] [
  81         [ log2 1+ <bit-array> 0 ] keep
  82         [ dup 0 = ] [
  83             [ pick underlying>> pick set-alien-unsigned-1 ] keep
  84             [ 1+ ] [ -8 shift ] bi*
  85         ] until 2drop
  86     ] if ;
  87
  88 : bit-array>integer ( bit-array -- n )
  89     0 swap underlying>> dup length <reversed> [
  90         alien-unsigned-1 swap 8 shift bitor
  91     ] with each ;
  92
  93 INSTANCE: bit-array sequence
  94
  95 M: bit-array pprint-delims drop \ ?{ \ } ;
  96 M: bit-array >pprint-sequence ;
  97 M: bit-array pprint* pprint-object ;