basis/calendar/calendar.factor

   1 ! Copyright (C) 2007 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes.tuple combinators
   4 combinators.short-circuit kernel literals math math.functions
   5 math.intervals math.order math.parser math.statistics sequences
   6 slots.syntax splitting system vocabs vocabs.loader ;
   7 FROM: math.ranges => [a..b) ;
   8 IN: calendar
   9
  10 ERROR: not-in-interval value interval ;
  11
  12 : check-interval ( value interval -- value )
  13     2dup interval-contains? [ drop ] [ not-in-interval ] if ;
  14
  15 HOOK: gmt-offset os ( -- hours minutes seconds )
  16
  17 HOOK: now-gmt os ( -- timestamp )
  18
  19 TUPLE: duration
  20     { year real }
  21     { month real }
  22     { day real }
  23     { hour real }
  24     { minute real }
  25     { second real } ;
  26
  27 C: <duration> duration
  28
  29 : instant ( -- duration ) 0 0 0 0 0 0 <duration> ;
  30
  31 TUPLE: timestamp
  32     { year integer }
  33     { month integer }
  34     { day integer }
  35     { hour integer }
  36     { minute integer }
  37     { second real }
  38     { gmt-offset duration } ;
  39
  40 <PRIVATE
  41 <<
  42 CONSTANT: day-counts { 0 31 28 31 30 31 30 31 31 30 31 30 31 }
  43 >>
  44 CONSTANT: days-until $[ day-counts cum-sum0 ]
  45
  46 PRIVATE>
  47
  48 GENERIC: leap-year? ( obj -- ? )
  49
  50 M: integer leap-year?
  51     dup 100 divisor? 400 4 ? divisor? ;
  52
  53 M: timestamp leap-year?
  54     year>> leap-year? ;
  55
  56 : (days-in-month) ( year month -- n )
  57     dup 2 = [ drop leap-year? 29 28 ? ] [ nip day-counts nth ] if ;
  58
  59 :: <timestamp> ( year month day hour minute second gmt-offset -- timestamp )
  60     year
  61     month 1 12 [a,b] check-interval
  62     day 1 year month (days-in-month) [a,b] check-interval
  63     hour 0 23 [a,b] check-interval
  64     minute 0 59 [a,b] check-interval
  65     second 0 60 [a,b) check-interval
  66     gmt-offset timestamp boa ;
  67
  68 M: timestamp clone (clone) [ clone ] change-gmt-offset ;
  69
  70 : gmt-offset-duration ( -- duration )
  71     0 0 0 gmt-offset <duration> ; inline
  72
  73 : <date> ( year month day -- timestamp )
  74     0 0 0 gmt-offset-duration <timestamp> ; inline
  75
  76 : <date-gmt> ( year month day -- timestamp )
  77     0 0 0 instant <timestamp> ; inline
  78
  79 : <year> ( year -- timestamp )
  80     1 1 <date> ; inline
  81
  82 : <year-gmt> ( year -- timestamp )
  83     1 1 <date-gmt> ; inline
  84
  85 CONSTANT: average-month 30+5/12
  86 CONSTANT: months-per-year 12
  87 CONSTANT: days-per-year 3652425/10000
  88 CONSTANT: hours-per-year 876582/100
  89 CONSTANT: minutes-per-year 5259492/10
  90 CONSTANT: seconds-per-year 31556952
  91
  92 :: julian-day-number ( year month day -- n )
  93     ! Returns a composite date number
  94     ! Not valid before year -4800
  95     14 month - 12 /i :> a
  96     year 4800 + a - :> y
  97     month 12 a * + 3 - :> m
  98
  99     day 153 m * 2 + 5 /i + 365 y * +
 100     y 4 /i + y 100 /i - y 400 /i + 32045 - ;
 101
 102 :: julian-day-number>date ( n -- year month day )
 103     ! Inverse of julian-day-number
 104     n 32044 + :> a
 105     4 a * 3 + 146097 /i :> b
 106     a 146097 b * 4 /i - :> c
 107     4 c * 3 + 1461 /i :> d
 108     c 1461 d * 4 /i - :> e
 109     5 e * 2 + 153 /i :> m
 110
 111     100 b * d + 4800 -
 112     m 10 /i + m 3 +
 113     12 m 10 /i * -
 114     e 153 m * 2 + 5 /i - 1 + ;
 115
 116 GENERIC: easter ( obj -- obj' )
 117
 118 :: easter-month-day ( year -- month day )
 119     year 19 mod :> a
 120     year 100 /mod :> ( b c )
 121     b 4 /mod :> ( d e )
 122     b 8 + 25 /i :> f
 123     b f - 1 + 3 /i :> g
 124     19 a * b + d - g - 15 + 30 mod :> h
 125     c 4 /mod :> ( i k )
 126     32 2 e * + 2 i * + h - k - 7 mod :> l
 127     a 11 h * + 22 l * + 451 /i :> m
 128
 129     h l + 7 m * - 114 + 31 /mod 1 + ;
 130
 131 M: integer easter
 132     dup easter-month-day <date> ;
 133
 134 M: timestamp easter
 135     dup year>> easter-month-day
 136     swapd >>day swap >>month ;
 137
 138 : >date< ( timestamp -- year month day )
 139     [ year>> ] [ month>> ] [ day>> ] tri ;
 140
 141 : set-date ( timestamp year month day -- timestamp )
 142     [ >>year ] [ >>month ] [ >>day ] tri* ;
 143
 144 : >time< ( timestamp -- hour minute second )
 145     [ hour>> ] [ minute>> ] [ second>> ] tri ;
 146
 147 : set-time ( timestamp hour minute second -- timestamp )
 148     [ >>hour ] [ >>minute ] [ >>second ] tri* ;
 149
 150 : years ( x -- duration ) instant swap >>year ;
 151 : bienniums ( x -- duration ) instant swap 2 * >>year ;
 152 : trienniums ( x -- duration ) instant swap 3 * >>year ;
 153 : quadrenniums ( x -- duration ) instant swap 4 * >>year ;
 154 : quinquenniums ( x -- duration ) instant swap 5 * >>year ;
 155 : sexenniums ( x -- duration ) instant swap 6 * >>year ;
 156 : septenniums ( x -- duration ) instant swap 7 * >>year ;
 157 : octenniums ( x -- duration ) instant swap 8 * >>year ;
 158 : novenniums ( x -- duration ) instant swap 9 * >>year ;
 159 : lustrums ( x -- duration ) instant swap 5 * >>year ;
 160 : decades ( x -- duration ) instant swap 10 * >>year ;
 161 : indictions ( x -- duration ) instant swap 15 * >>year ;
 162 : score ( x -- duration ) instant swap 20 * >>year ;
 163 : jubilees ( x -- duration ) instant swap 50 * >>year ;
 164 : centuries ( x -- duration ) instant swap 100 * >>year ;
 165 : millennia ( x -- duration ) instant swap 1000 * >>year ;
 166 : millenniums ( x -- duration ) instant swap 1000 * >>year ;
 167 : kila-annum ( x -- duration ) instant swap 1000 * >>year ;
 168 : mega-annum ( x -- duration ) instant swap 1,000,000 * >>year ;
 169 : giga-annum ( x -- duration ) instant swap 1,000,000,000 * >>year ;
 170 : ages ( x -- duration ) instant swap 1,000,000 * >>year ;
 171 : epochs ( x -- duration ) instant swap 10,000,000 * >>year ;
 172 : eras ( x -- duration ) instant swap 100,000,000 * >>year ;
 173 : eons ( x -- duration ) instant swap 500,000,000 * >>year ;
 174 : months ( x -- duration ) instant swap >>month ;
 175 : days ( x -- duration ) instant swap >>day ;
 176 : weeks ( x -- duration ) 7 * days ;
 177 : fortnight ( x -- duration ) 14 * days ;
 178 : hours ( x -- duration ) instant swap >>hour ;
 179 : minutes ( x -- duration ) instant swap >>minute ;
 180 : seconds ( x -- duration ) instant swap >>second ;
 181 : milliseconds ( x -- duration ) 1000 / seconds ;
 182 : microseconds ( x -- duration ) 1000000 / seconds ;
 183 : nanoseconds ( x -- duration ) 1000000000 / seconds ;
 184
 185 <PRIVATE
 186
 187 GENERIC: +year ( timestamp x -- timestamp )
 188 GENERIC: +month ( timestamp x -- timestamp )
 189 GENERIC: +day ( timestamp x -- timestamp )
 190 GENERIC: +hour ( timestamp x -- timestamp )
 191 GENERIC: +minute ( timestamp x -- timestamp )
 192 GENERIC: +second ( timestamp x -- timestamp )
 193
 194 : /rem ( f n -- q r )
 195     ! q is positive or negative, r is positive from 0 <= r < n
 196     [ /mod ] keep over 0 < [ + [ -1 + ] dip ] [ drop ] if ; inline
 197
 198 : float>whole-part ( float -- int float )
 199     [ floor >integer ] keep over - ; inline
 200
 201 : adjust-leap-year ( timestamp -- timestamp )
 202     dup
 203     { [ day>> 29 = ] [ month>> 2 = ] [ leap-year? not ] } 1&&
 204     [ 3 >>month 1 >>day ] when ;
 205
 206 M: integer +year
 207     [ + ] curry change-year adjust-leap-year ;
 208
 209 M: real +year
 210     float>whole-part swapd days-per-year * +day swap +year ;
 211
 212 : months/years ( n -- months years )
 213     12 /rem [ 1 - 12 ] when-zero swap ; inline
 214
 215 M: integer +month
 216     [ over month>> + months/years [ >>month ] dip +year ] unless-zero ;
 217
 218 M: real +month
 219     float>whole-part swapd average-month * +day swap +month ;
 220
 221 M: integer +day
 222     [ over >date< julian-day-number + julian-day-number>date set-date ] unless-zero ;
 223
 224 M: real +day
 225     float>whole-part swapd 24 * +hour swap +day ;
 226
 227 : hours/days ( n -- hours days )
 228     24 /rem swap ; inline
 229
 230 M: integer +hour
 231     [ over hour>> + hours/days [ >>hour ] dip +day ] unless-zero ;
 232
 233 M: real +hour
 234     float>whole-part swapd 60 * +minute swap +hour ;
 235
 236 : minutes/hours ( n -- minutes hours )
 237     60 /rem swap ; inline
 238
 239 M: integer +minute
 240     [ over minute>> + minutes/hours [ >>minute ] dip +hour ] unless-zero ;
 241
 242 M: real +minute
 243     float>whole-part swapd 60 * +second swap +minute ;
 244
 245 : seconds/minutes ( n -- seconds minutes )
 246     60 /rem swap ; inline
 247
 248 M: number +second
 249     [ over second>> + seconds/minutes [ >>second ] dip +minute ] unless-zero ;
 250
 251 : (time+) ( timestamp duration -- timestamp )
 252     {
 253         [ second>> +second ]
 254         [ minute>> +minute ]
 255         [ hour>>   +hour   ]
 256         [ day>>    +day    ]
 257         [ month>>  +month  ]
 258         [ year>>   +year   ]
 259      } cleave ; inline
 260
 261 PRIVATE>
 262
 263 GENERIC#: time+ 1 ( time1 time2 -- time3 )
 264
 265 M: timestamp time+ [ clone ] dip (time+) ;
 266
 267 : duration+ ( duration1 duration2 -- duration3 )
 268     {
 269         [ [ year>> ] bi@ + ]
 270         [ [ month>> ] bi@ + ]
 271         [ [ day>> ] bi@ + ]
 272         [ [ hour>> ] bi@ + ]
 273         [ [ minute>> ] bi@ + ]
 274         [ [ second>> ] bi@ + ]
 275     } 2cleave <duration> ; inline
 276
 277 M: duration time+
 278     dup timestamp? [ swap time+ ] [ duration+ ] if ;
 279
 280 : duration>years ( duration -- x )
 281     ! Uses average month/year length since duration loses calendar data
 282     0 swap
 283     {
 284         [ year>> + ]
 285         [ month>> months-per-year / + ]
 286         [ day>> days-per-year / + ]
 287         [ hour>> hours-per-year / + ]
 288         [ minute>> minutes-per-year / + ]
 289         [ second>> seconds-per-year / + ]
 290     } cleave ;
 291
 292 M: duration <=> [ duration>years ] compare ;
 293
 294 : duration>months ( duration -- x ) duration>years months-per-year * ;
 295 : duration>days ( duration -- x ) duration>years days-per-year * ;
 296 : duration>hours ( duration -- x ) duration>years hours-per-year * ;
 297 : duration>minutes ( duration -- x ) duration>years minutes-per-year * ;
 298 : duration>seconds ( duration -- x ) duration>years seconds-per-year * ;
 299 : duration>milliseconds ( duration -- x ) duration>seconds 1000 * ;
 300 : duration>microseconds ( duration -- x ) duration>seconds 1000000 * ;
 301 : duration>nanoseconds ( duration -- x ) duration>seconds 1000000000 * ;
 302
 303 DEFER: time-
 304
 305 : gmt ( timestamp -- timestamp )
 306     instant >>gmt-offset ; inline
 307
 308 : local-time ( timestamp -- timestamp )
 309     gmt-offset-duration >>gmt-offset ; inline
 310
 311 : convert-timezone ( timestamp duration -- timestamp )
 312     [ over gmt-offset>> time- (time+) ] [ >>gmt-offset ] bi ;
 313
 314 : convert-local-time ( timestamp -- timestamp )
 315     gmt-offset-duration convert-timezone ;
 316
 317 : convert-gmt ( timestamp -- timestamp )
 318     instant convert-timezone ;
 319
 320 : >local-time ( timestamp -- timestamp' )
 321     clone convert-local-time ;
 322
 323 : >gmt ( timestamp -- timestamp' )
 324     clone convert-gmt ;
 325
 326 : >timezone ( timestamp duration -- timestamp' )
 327     [ clone ] [ convert-timezone ] bi* ;
 328
 329 ALIAS: utc gmt
 330 ALIAS: convert-utc convert-gmt
 331 ALIAS: >utc >gmt
 332
 333 M: timestamp <=> [ >gmt tuple-slots ] compare ;
 334
 335 : same-year? ( ts1 ts2 -- ? )
 336     [ >gmt slots{ year } ] same? ;
 337
 338 : quarter ( timestamp -- [1,4] )
 339     month>> 3 /i 1 + ; inline
 340
 341 : same-quarter? ( ts1 ts2 -- ? )
 342     [ >gmt [ year>> ] [ quarter ] bi 2array ] same? ;
 343
 344 : same-month? ( ts1 ts2 -- ? )
 345     [ >gmt slots{ year month } ] same? ;
 346
 347 :: (day-of-year) ( year month day -- n )
 348     month days-until nth day + {
 349         [ year leap-year? ]
 350         [ month 3 >= ]
 351     } 0&& [ 1 + ] when ;
 352
 353 : day-of-year ( timestamp -- n )
 354     >date< (day-of-year) ;
 355
 356 : same-day? ( ts1 ts2 -- ? )
 357     [ >gmt slots{ year month day } ] same? ;
 358
 359 : (day-of-week) ( year month day -- n )
 360     ! Zeller Congruence
 361     ! http://web.textfiles.com/computers/formulas.txt
 362     ! good for any date since October 15, 1582
 363     [
 364         dup 2 <= [ [ 1 - ] [ 12 + ] bi* ] when
 365         [ dup [ 4 /i + ] [ 100 /i - ] [ 400 /i + ] tri ] dip
 366         [ 1 + 3 * 5 /i + ] keep 2 * +
 367     ] dip 1 + + 7 mod ;
 368
 369 : day-of-week ( timestamp -- n )
 370     >date< (day-of-week) ;
 371
 372 : (week-number) ( timestamp -- [0,53] )
 373     [ day-of-year ] [ day-of-week [ 7 ] when-zero ] bi - 10 + 7 /i ;
 374
 375 DEFER: end-of-year
 376
 377 : week-number ( timestamp -- [1,53] )
 378     dup (week-number) {
 379         {  0 [ year>> 1 - end-of-year (week-number) ] }
 380         { 53 [ year>> 1 + <year> (week-number) 1 = 1 53 ? ] }
 381         [ nip ]
 382     } case ;
 383
 384 : same-week? ( ts1 ts2 -- ? )
 385     [ >gmt [ year>> ] [ week-number ] bi 2array ] same? ;
 386
 387 : same-hour? ( ts1 ts2 -- ? )
 388     [ >gmt slots{ year month day hour } ] same? ;
 389
 390 : same-minute? ( ts1 ts2 -- ? )
 391     [ >gmt slots{ year month day hour minute } ] same? ;
 392
 393 : same-second? ( ts1 ts2 -- ? )
 394     [ >gmt slots{ year month day hour minute second } ] same? ;
 395
 396 <PRIVATE
 397
 398 : (time-) ( timestamp timestamp -- n )
 399     [ [ >date< julian-day-number ] bi@ - 86400 * ]
 400     [ [ >time< [ 3600 * ] [ 60 * + ] [ + ] tri* ] bi@ - + ]
 401     [ [ gmt-offset>> duration>seconds ] bi@ swap - + ] 2tri ;
 402
 403 PRIVATE>
 404
 405 GENERIC: time- ( time1 time2 -- time3 )
 406
 407 M: timestamp time-
 408     ! Exact calendar-time difference
 409     (time-) seconds ;
 410
 411 : duration* ( obj1 obj2 -- obj3 )
 412     dup real? [ swap ] when
 413     dup real? [ * ] [
 414         {
 415             [   year>> * ]
 416             [  month>> * ]
 417             [    day>> * ]
 418             [   hour>> * ]
 419             [ minute>> * ]
 420             [ second>> * ]
 421         } 2cleave <duration>
 422     ] if ;
 423
 424 : before ( duration -- -duration )
 425     -1 duration* ;
 426
 427 : duration- ( duration1 duration2 -- duration3 )
 428     {
 429         [ [ year>> ] bi@ - ]
 430         [ [ month>> ] bi@ - ]
 431         [ [ day>> ] bi@ - ]
 432         [ [ hour>> ] bi@ - ]
 433         [ [ minute>> ] bi@ - ]
 434         [ [ second>> ] bi@ - ]
 435     } 2cleave <duration> ; inline
 436
 437 M: duration time-
 438     over timestamp? [ before time+ ] [ duration- ] if ;
 439
 440 : unix-1970 ( -- timestamp )
 441     1970 <year-gmt> ; inline
 442
 443 : millis>timestamp ( x -- timestamp )
 444     unix-1970 swap 1000 / +second ;
 445
 446 : timestamp>millis ( timestamp -- n )
 447     unix-1970 (time-) 1000 * >integer ;
 448
 449 : micros>timestamp ( x -- timestamp )
 450     unix-1970 swap 1000000 / +second ;
 451
 452 : timestamp>micros ( timestamp -- n )
 453     unix-1970 (time-) 1000000 * >integer ;
 454
 455 : now ( -- timestamp )
 456     now-gmt gmt-offset-duration [ (time+) ] [ >>gmt-offset ] bi ;
 457
 458 : hence ( duration -- timestamp ) now swap time+ ;
 459 : ago ( duration -- timestamp ) now swap time- ;
 460
 461 GENERIC: days-in-year ( obj -- n )
 462
 463 M: integer days-in-year leap-year? 366 365 ? ;
 464
 465 M: timestamp days-in-year year>> days-in-year ;
 466
 467 : days-in-month ( timestamp -- n )
 468     >date< drop (days-in-month) ;
 469
 470 : midnight ( timestamp -- timestamp ) 0 0 0 set-time ; inline
 471 : noon ( timestamp -- timestamp ) 12 0 0 set-time ; inline
 472
 473 : today ( -- timestamp ) now midnight ; inline
 474 : tomorrow ( -- timestamp ) 1 days hence midnight ; inline
 475 : overtomorrow ( -- timestamp ) 2 days hence midnight ; inline
 476 : yesterday ( -- timestamp ) 1 days ago midnight ; inline
 477 : ereyesterday ( -- timestamp ) 2 days ago midnight ; inline
 478
 479 ALIAS: start-of-day midnight
 480
 481 : end-of-day ( timestamp -- timestamp )
 482     23 >>hour 59 >>minute 59+999/1000 >>second ; inline
 483
 484 : start-of-month ( timestamp -- timestamp )
 485     midnight 1 >>day ; inline
 486
 487 : end-of-month ( timestamp -- timestamp )
 488     [ end-of-day ] [ days-in-month ] bi >>day ;
 489
 490 : start-of-quarter ( timestamp -- timestamp )
 491     [ start-of-day ] [ quarter 1 - 3 * ] bi >>month ; inline
 492
 493 : end-of-quarter ( timestamp -- timestamp )
 494     dup quarter 1 - 3 * 3 + >>month end-of-month ; inline
 495
 496 : first-day-of-month ( timestamp -- timestamp )
 497     1 >>day ;
 498
 499 : last-day-of-month ( timestamp -- timestamp )
 500     dup days-in-month >>day ; inline
 501
 502 GENERIC: first-day-of-year ( object -- timestamp )
 503 M: timestamp first-day-of-year first-day-of-month 1 >>month ;
 504 M: integer first-day-of-year <year> ;
 505
 506 GENERIC: last-day-of-year ( object -- timestamp )
 507 M: timestamp last-day-of-year 12 >>month 31 >>day ;
 508 M: integer last-day-of-year 12 31 <date> ;
 509
 510 : first-day-of-decade ( object -- timestamp )
 511     first-day-of-year [ dup 10 mod - ] change-year ;
 512
 513 : last-day-of-decade ( object -- timestamp )
 514     last-day-of-year [ dup 10 mod - 9 + ] change-year ;
 515
 516 : first-day-of-century ( object -- timestamp )
 517     first-day-of-year [ dup 100 mod - ] change-year ;
 518
 519 : last-day-of-century ( object -- timestamp )
 520     last-day-of-year [ dup 100 mod - 99 + ] change-year ;
 521
 522 : first-day-of-millennium ( object -- timestamp )
 523     first-day-of-year [ dup 1000 mod - ] change-year ;
 524
 525 : last-day-of-millennium ( object -- timestamp )
 526     last-day-of-year [ dup 1000 mod - 999 + ] change-year ;
 527
 528 : start-of-year ( object -- timestamp )
 529     first-day-of-year start-of-day ;
 530
 531 : end-of-year ( object -- timestamp )
 532     last-day-of-year end-of-day ;
 533
 534 : start-of-decade ( object -- timestamp )
 535     first-day-of-decade start-of-day ;
 536
 537 : end-of-decade ( object -- timestamp )
 538     last-day-of-decade end-of-day ;
 539
 540 : end-of-century ( object -- timestamp )
 541     last-day-of-century end-of-day ;
 542
 543 : start-of-millennium ( object -- timestamp )
 544     first-day-of-millennium start-of-day ;
 545
 546 : end-of-millennium ( object -- timestamp )
 547     last-day-of-millennium end-of-day ;
 548
 549 : start-of-hour ( timestamp -- timestamp ) 0 >>minute 0 >>second ;
 550 : end-of-hour ( timestamp -- timestamp ) 59 >>minute 59+999/1000 >>second ;
 551
 552 : start-of-minute ( timestamp -- timestamp ) 0 >>second ;
 553 : end-of-minute ( timestamp -- timestamp ) 59+999/1000 >>second ;
 554
 555 : start-of-second ( timestamp -- timestamp ) [ floor ] change-second ;
 556 : end-of-second ( timestamp -- timestamp ) [ floor 999/1000 + ] change-second ;
 557
 558 <PRIVATE
 559
 560 : day-offset ( timestamp m -- timestamp n )
 561     over day-of-week - ; inline
 562
 563 : day-this-week ( timestamp n -- timestamp )
 564     day-offset days (time+) ;
 565
 566 : closest-day ( timestamp n -- timestamp )
 567     [ dup day-of-week 7 swap - ] [ + 7 mod ] bi*
 568     { 0 1 2 3 -3 -2 -1 } nth days (time+) ;
 569
 570 :: nth-day-this-month ( timestamp n day -- timestamp )
 571     timestamp clone
 572     timestamp start-of-month day day-this-week
 573     [ [ month>> ] same? ] keep swap
 574     [ 1 weeks (time+) ] unless
 575     n [ weeks (time+) ] unless-zero ;
 576
 577 PRIVATE>
 578
 579 GENERIC: january ( obj -- timestamp )
 580 GENERIC: february ( obj -- timestamp )
 581 GENERIC: march ( obj -- timestamp )
 582 GENERIC: april ( obj -- timestamp )
 583 GENERIC: may ( obj -- timestamp )
 584 GENERIC: june ( obj -- timestamp )
 585 GENERIC: july ( obj -- timestamp )
 586 GENERIC: august ( obj -- timestamp )
 587 GENERIC: september ( obj -- timestamp )
 588 GENERIC: october ( obj -- timestamp )
 589 GENERIC: november ( obj -- timestamp )
 590 GENERIC: december ( obj -- timestamp )
 591
 592 M: integer january 1 1 <date> ;
 593 M: integer february 2 1 <date> ;
 594 M: integer march 3 1 <date> ;
 595 M: integer april 4 1 <date> ;
 596 M: integer may 5 1 <date> ;
 597 M: integer june 6 1 <date> ;
 598 M: integer july 7 1 <date> ;
 599 M: integer august 8 1 <date> ;
 600 M: integer september 9 1 <date> ;
 601 M: integer october 10 1 <date> ;
 602 M: integer november 11 1 <date> ;
 603 M: integer december 12 1 <date> ;
 604
 605 M: timestamp january 1 >>month ;
 606 M: timestamp february 2 >>month ;
 607 M: timestamp march 3 >>month ;
 608 M: timestamp april 4 >>month ;
 609 M: timestamp may 5 >>month ;
 610 M: timestamp june 6 >>month ;
 611 M: timestamp july 7 >>month ;
 612 M: timestamp august 8 >>month ;
 613 M: timestamp september 9 >>month ;
 614 M: timestamp october 10 >>month ;
 615 M: timestamp november 11 >>month ;
 616 M: timestamp december 12 >>month ;
 617
 618 : closest-sunday ( timestamp -- timestamp ) 0 closest-day ;
 619 : closest-monday ( timestamp -- timestamp ) 1 closest-day ;
 620 : closest-tuesday ( timestamp -- timestamp ) 2 closest-day ;
 621 : closest-wednesday ( timestamp -- timestamp ) 3 closest-day ;
 622 : closest-thursday ( timestamp -- timestamp ) 4 closest-day ;
 623 : closest-friday ( timestamp -- timestamp ) 5 closest-day ;
 624 : closest-saturday ( timestamp -- timestamp ) 6 closest-day ;
 625
 626 : sunday ( timestamp -- timestamp ) 0 day-this-week ;
 627 : monday ( timestamp -- timestamp ) 1 day-this-week ;
 628 : tuesday ( timestamp -- timestamp ) 2 day-this-week ;
 629 : wednesday ( timestamp -- timestamp ) 3 day-this-week ;
 630 : thursday ( timestamp -- timestamp ) 4 day-this-week ;
 631 : friday ( timestamp -- timestamp ) 5 day-this-week ;
 632 : saturday ( timestamp -- timestamp ) 6 day-this-week ;
 633
 634 ALIAS: first-day-of-week sunday
 635 ALIAS: last-day-of-week saturday
 636
 637 : day< ( timestamp quot -- timestamp )
 638     over clone [ call dup ] dip after=? [ -7 days (time+) ] when ; inline
 639 : day<= ( timestamp quot -- timestamp )
 640     over clone [ call dup ] dip after? [ -7 days (time+) ] when ; inline
 641 : day> ( timestamp quot -- timestamp )
 642     over clone [ call dup ] dip before=? [ 7 days (time+) ] when ; inline
 643 : day>= ( timestamp quot -- timestamp )
 644     over clone [ call dup ] dip before? [ 7 days (time+) ] when ; inline
 645
 646 : sunday< ( timestamp -- timestamp ) [ sunday ] day< ;
 647 : monday< ( timestamp -- timestamp ) [ monday ] day< ;
 648 : tuesday< ( timestamp -- timestamp ) [ tuesday ] day< ;
 649 : wednesday< ( timestamp -- timestamp ) [ wednesday ] day< ;
 650 : thursday< ( timestamp -- timestamp ) [ thursday ] day< ;
 651 : friday< ( timestamp -- timestamp ) [ friday ] day< ;
 652 : saturday< ( timestamp -- timestamp ) [ saturday ] day< ;
 653
 654 : sunday<= ( timestamp -- timestamp ) [ sunday ] day<= ;
 655 : monday<= ( timestamp -- timestamp ) [ monday ] day<= ;
 656 : tuesday<= ( timestamp -- timestamp ) [ tuesday ] day<= ;
 657 : wednesday<= ( timestamp -- timestamp ) [ wednesday ] day<= ;
 658 : thursday<= ( timestamp -- timestamp ) [ thursday ] day<= ;
 659 : friday<= ( timestamp -- timestamp ) [ friday ] day<= ;
 660 : saturday<= ( timestamp -- timestamp ) [ saturday ] day<= ;
 661
 662 : sunday> ( timestamp -- timestamp ) [ sunday ] day> ;
 663 : monday> ( timestamp -- timestamp ) [ monday ] day> ;
 664 : tuesday> ( timestamp -- timestamp ) [ tuesday ] day> ;
 665 : wednesday> ( timestamp -- timestamp ) [ wednesday ] day> ;
 666 : thursday> ( timestamp -- timestamp ) [ thursday ] day> ;
 667 : friday> ( timestamp -- timestamp ) [ friday ] day> ;
 668 : saturday> ( timestamp -- timestamp ) [ saturday ] day> ;
 669
 670 : sunday>= ( timestamp -- timestamp ) [ sunday ] day>= ;
 671 : monday>= ( timestamp -- timestamp ) [ monday ] day>= ;
 672 : tuesday>= ( timestamp -- timestamp ) [ tuesday ] day>= ;
 673 : wednesday>= ( timestamp -- timestamp ) [ wednesday ] day>= ;
 674 : thursday>= ( timestamp -- timestamp ) [ thursday ] day>= ;
 675 : friday>= ( timestamp -- timestamp ) [ friday ] day>= ;
 676 : saturday>= ( timestamp -- timestamp ) [ saturday ] day>= ;
 677
 678 : next-sunday ( timestamp -- timestamp ) closest-sunday sunday> ;
 679 : next-monday ( timestamp -- timestamp ) closest-monday monday> ;
 680 : next-tuesday ( timestamp -- timestamp ) closest-tuesday tuesday> ;
 681 : next-wednesday ( timestamp -- timestamp ) closest-wednesday wednesday> ;
 682 : next-thursday ( timestamp -- timestamp ) closest-thursday thursday> ;
 683 : next-friday ( timestamp -- timestamp ) closest-friday friday> ;
 684 : next-saturday ( timestamp -- timestamp ) closest-saturday saturday> ;
 685
 686 : last-sunday ( timestamp -- timestamp ) closest-sunday sunday< ;
 687 : last-monday ( timestamp -- timestamp ) closest-monday monday< ;
 688 : last-tuesday ( timestamp -- timestamp ) closest-tuesday tuesday< ;
 689 : last-wednesday ( timestamp -- timestamp ) closest-wednesday wednesday< ;
 690 : last-thursday ( timestamp -- timestamp ) closest-thursday thursday< ;
 691 : last-friday ( timestamp -- timestamp ) closest-friday friday< ;
 692 : last-saturday ( timestamp -- timestamp ) closest-saturday saturday< ;
 693
 694 : sunday? ( timestamp -- ? ) day-of-week 0 = ;
 695 : monday? ( timestamp -- ? ) day-of-week 1 = ;
 696 : tuesday? ( timestamp -- ? ) day-of-week 2 = ;
 697 : wednesday? ( timestamp -- ? ) day-of-week 3 = ;
 698 : thursday? ( timestamp -- ? ) day-of-week 4 = ;
 699 : friday? ( timestamp -- ? ) day-of-week 5 = ;
 700 : saturday? ( timestamp -- ? ) day-of-week 6 = ;
 701
 702 : january? ( timestamp -- ? ) month>> 1 = ;
 703 : february? ( timestamp -- ? ) month>> 2 = ;
 704 : march? ( timestamp -- ? ) month>> 3  = ;
 705 : april? ( timestamp -- ? ) month>> 4 = ;
 706 : may? ( timestamp -- ? ) month>> 5 = ;
 707 : june? ( timestamp -- ? ) month>> 6 = ;
 708 : july? ( timestamp -- ? ) month>> 7 = ;
 709 : august? ( timestamp -- ? ) month>> 8 = ;
 710 : september? ( timestamp -- ? ) month>> 9 = ;
 711 : october? ( timestamp -- ? ) month>> 10 = ;
 712 : november? ( timestamp -- ? ) month>> 11 = ;
 713 : december? ( timestamp -- ? ) month>> 12 = ;
 714
 715 : weekend? ( timestamp -- ? ) day-of-week { 0 6 } member? ;
 716 : weekday? ( timestamp -- ? ) day-of-week weekend? not ;
 717
 718 : same-or-next-business-day ( timestamp -- timestamp )
 719     dup day-of-week {
 720         { 0 [ monday ] }
 721         { 6 [ 2 days (time+) ] }
 722         [ drop ]
 723     } case ;
 724
 725 : same-or-previous-business-day ( timestamp -- timestamp )
 726     dup day-of-week {
 727         { 0 [ -2 days (time+) ] }
 728         { 6 [ friday ] }
 729         [ drop ]
 730     } case ;
 731
 732 : weekdays-between ( date1 date2 -- n )
 733     [
 734         [ swap time- duration>days 5 * ]
 735         [ [ day-of-week ] bi@ - 2 * ] 2bi - 7 /i 1 +
 736     ] 2keep
 737     day-of-week 6 = [ [ 1 - ] dip ] when
 738     day-of-week 0 = [ 1 - ] when ;
 739
 740 CONSTANT: weekday-offsets { 0 0 1 2 3 4 5 }
 741
 742 : weekdays-between2 ( date1 date2 -- n )
 743     [ swap time- duration>days 1 + ]
 744     [ [ day-of-week ] bi@ 6 swap - ] 2bi
 745
 746     [ + + 1.4 /i ]
 747     [ [ weekday-offsets nth ] bi@ + ] 2bi - ;
 748
 749 : sunday-of-month ( timestamp n -- timestamp ) 0 nth-day-this-month ;
 750 : monday-of-month ( timestamp n -- timestamp ) 1 nth-day-this-month ;
 751 : tuesday-of-month ( timestamp n -- timestamp ) 2 nth-day-this-month ;
 752 : wednesday-of-month ( timestamp n -- timestamp ) 3 nth-day-this-month ;
 753 : thursday-of-month ( timestamp n -- timestamp ) 4 nth-day-this-month ;
 754 : friday-of-month ( timestamp n -- timestamp ) 5 nth-day-this-month ;
 755 : saturday-of-month ( timestamp n -- timestamp ) 6 nth-day-this-month ;
 756
 757 : last-sunday-of-month ( timestamp -- timestamp ) last-day-of-month sunday<= ;
 758 : last-monday-of-month ( timestamp -- timestamp ) last-day-of-month monday<= ;
 759 : last-tuesday-of-month ( timestamp -- timestamp ) last-day-of-month tuesday<= ;
 760 : last-wednesday-of-month ( timestamp -- timestamp ) last-day-of-month wednesday<= ;
 761 : last-thursday-of-month ( timestamp -- timestamp ) last-day-of-month thursday<= ;
 762 : last-friday-of-month ( timestamp -- timestamp ) last-day-of-month friday<= ;
 763 : last-saturday-of-month ( timestamp -- timestamp ) last-day-of-month saturday<= ;
 764
 765 : start-of-week ( timestamp -- timestamp )
 766     sunday midnight ;
 767
 768 : end-of-week ( timestamp -- timestamp )
 769     saturday end-of-day ;
 770
 771 : o'clock ( timestamp n -- timestamp )
 772     [ midnight ] dip >>hour ;
 773
 774 : am ( timestamp n -- timestamp )
 775     1 12 [a,b] check-interval 12 mod o'clock ;
 776
 777 : pm ( timestamp n -- timestamp )
 778     1 12 [a,b] check-interval 12 mod 12 + o'clock ;
 779
 780 : time-since-midnight ( timestamp -- duration )
 781     instant swap >time< set-time ;
 782
 783 : since-1970 ( duration -- timestamp )
 784     unix-1970 swap (time+) ; inline
 785
 786 : timestamp>unix-time ( timestamp -- seconds )
 787     unix-1970 (time-) ; inline
 788
 789 : unix-time>timestamp ( seconds -- timestamp )
 790     unix-1970 swap +second ; inline
 791
 792 ! January and February need a fixup with this algorithm.
 793 ! Find a better algorithm.
 794 : ymd>ordinal ( year month day -- ordinal )
 795     [ leap-year? dup -2 -3 ? ]
 796     [ dup 3 < [ 12 + ] when [ 1 - 30 * ] [ 1 + .6 * floor ] bi + ]
 797     [ ] tri* + + >integer
 798     swap 367 366 ? mod ;
 799
 800 : timestamp>year-dates-gmt ( timestamp -- seq )
 801     [ year>> 1 1 julian-day-number ] [ days-in-year ] bi
 802     [ drop ] [ + ] 2bi
 803     [a..b) [ julian-day-number>date <date-gmt> ] map ;
 804
 805 : year-ordinal>timestamp ( year ordinal -- timestamp )
 806     [ 1 1 julian-day-number ] dip
 807     + 1 - julian-day-number>date <date> ;
 808
 809 GENERIC: weeks-in-week-year ( obj -- n )
 810
 811 M: integer weeks-in-week-year
 812     { [ 1 1 <date> thursday? ] [ 12 31 <date> thursday? ] } 1|| 53 52 ? ;
 813
 814 M: timestamp weeks-in-week-year
 815     { [ january 1 >>day thursday? ] [ december 31 >>day thursday? ] } 1|| 53 52 ? ;
 816
 817 {
 818     { [ os unix? ] [ "calendar.unix" ] }
 819     { [ os windows? ] [ "calendar.windows" ] }
 820 } cond require
 821
 822 { "threads" "calendar" } "calendar.threads" require-when