]> gitweb.factorcode.org Git - factor.git/blob - basis/calendar/calendar.factor
calendar: Clone by default and add tests.
[factor.git] / basis / calendar / calendar.factor
1 ! Copyright (C) 2007 Doug Coleman.
2 ! See http://factorcode.org/license.txt for BSD license.
3 USING: accessors arrays classes.tuple combinators
4 combinators.short-circuit kernel literals math math.functions
5 math.intervals math.order math.statistics sequences slots.syntax
6 system vocabs vocabs.loader ;
7 FROM: math.ranges => [a..b) ;
8 IN: calendar
9
10 ERROR: not-in-interval value interval ;
11
12 : check-interval ( value interval -- value )
13     2dup interval-contains? [ drop ] [ not-in-interval ] if ;
14
15 HOOK: gmt-offset os ( -- hours minutes seconds )
16
17 HOOK: now-gmt os ( -- timestamp )
18
19 TUPLE: duration
20     { year real }
21     { month real }
22     { day real }
23     { hour real }
24     { minute real }
25     { second real } ;
26
27 C: <duration> duration
28
29 : instant ( -- duration ) 0 0 0 0 0 0 <duration> ;
30
31 TUPLE: timestamp
32     { year integer }
33     { month integer }
34     { day integer }
35     { hour integer }
36     { minute integer }
37     { second real }
38     { gmt-offset duration } ;
39
40 <PRIVATE
41 <<
42 CONSTANT: day-counts { 0 31 28 31 30 31 30 31 31 30 31 30 31 }
43 >>
44 CONSTANT: days-until $[ day-counts cum-sum0 ]
45
46 PRIVATE>
47
48 GENERIC: leap-year? ( obj -- ? )
49
50 M: integer leap-year?
51     dup 100 divisor? 400 4 ? divisor? ;
52
53 M: timestamp leap-year?
54     year>> leap-year? ;
55
56 : (days-in-month) ( year month -- n )
57     dup 2 = [ drop leap-year? 29 28 ? ] [ nip day-counts nth ] if ;
58
59 :: <timestamp> ( year month day hour minute second gmt-offset -- timestamp )
60     year
61     month 1 12 [a,b] check-interval
62     day 1 year month (days-in-month) [a,b] check-interval
63     hour 0 23 [a,b] check-interval
64     minute 0 59 [a,b] check-interval
65     second 0 60 [a,b) check-interval
66     gmt-offset timestamp boa ;
67
68 M: timestamp clone (clone) [ clone ] change-gmt-offset ;
69
70 : gmt-offset-duration ( -- duration )
71     0 0 0 gmt-offset <duration> ; inline
72
73 : <date> ( year month day -- timestamp )
74     0 0 0 gmt-offset-duration <timestamp> ; inline
75
76 : <date-gmt> ( year month day -- timestamp )
77     0 0 0 instant <timestamp> ; inline
78
79 : <year> ( year -- timestamp )
80     1 1 <date> ; inline
81
82 : <year-gmt> ( year -- timestamp )
83     1 1 <date-gmt> ; inline
84
85 CONSTANT: average-month 30+5/12
86 CONSTANT: months-per-year 12
87 CONSTANT: days-per-year 3652425/10000
88 CONSTANT: hours-per-year 876582/100
89 CONSTANT: minutes-per-year 5259492/10
90 CONSTANT: seconds-per-year 31556952
91
92 :: julian-day-number ( year month day -- n )
93     ! Returns a composite date number
94     ! Not valid before year -4800
95     14 month - 12 /i :> a
96     year 4800 + a - :> y
97     month 12 a * + 3 - :> m
98
99     day 153 m * 2 + 5 /i + 365 y * +
100     y 4 /i + y 100 /i - y 400 /i + 32045 - ;
101
102 :: julian-day-number>date ( n -- year month day )
103     ! Inverse of julian-day-number
104     n 32044 + :> a
105     4 a * 3 + 146097 /i :> b
106     a 146097 b * 4 /i - :> c
107     4 c * 3 + 1461 /i :> d
108     c 1461 d * 4 /i - :> e
109     5 e * 2 + 153 /i :> m
110
111     100 b * d + 4800 -
112     m 10 /i + m 3 +
113     12 m 10 /i * -
114     e 153 m * 2 + 5 /i - 1 + ;
115
116 GENERIC: easter ( obj -- obj' )
117
118 :: easter-month-day ( year -- month day )
119     year 19 mod :> a
120     year 100 /mod :> ( b c )
121     b 4 /mod :> ( d e )
122     b 8 + 25 /i :> f
123     b f - 1 + 3 /i :> g
124     19 a * b + d - g - 15 + 30 mod :> h
125     c 4 /mod :> ( i k )
126     32 2 e * + 2 i * + h - k - 7 mod :> l
127     a 11 h * + 22 l * + 451 /i :> m
128
129     h l + 7 m * - 114 + 31 /mod 1 + ;
130
131 M: integer easter
132     dup easter-month-day <date> ;
133
134 M: timestamp easter
135     dup year>> easter-month-day
136     swapd >>day swap >>month ;
137
138 : >date< ( timestamp -- year month day )
139     [ year>> ] [ month>> ] [ day>> ] tri ;
140
141 : set-date ( timestamp year month day -- timestamp )
142     [ >>year ] [ >>month ] [ >>day ] tri* ;
143
144 : >time< ( timestamp -- hour minute second )
145     [ hour>> ] [ minute>> ] [ second>> ] tri ;
146
147 : set-time ( timestamp hour minute second -- timestamp )
148     [ >>hour ] [ >>minute ] [ >>second ] tri* ;
149
150 : years ( x -- duration ) instant swap >>year ;
151 : bienniums ( x -- duration ) instant swap 2 * >>year ;
152 : trienniums ( x -- duration ) instant swap 3 * >>year ;
153 : quadrenniums ( x -- duration ) instant swap 4 * >>year ;
154 : quinquenniums ( x -- duration ) instant swap 5 * >>year ;
155 : sexenniums ( x -- duration ) instant swap 6 * >>year ;
156 : septenniums ( x -- duration ) instant swap 7 * >>year ;
157 : octenniums ( x -- duration ) instant swap 8 * >>year ;
158 : novenniums ( x -- duration ) instant swap 9 * >>year ;
159 : lustrums ( x -- duration ) instant swap 5 * >>year ;
160 : decades ( x -- duration ) instant swap 10 * >>year ;
161 : indictions ( x -- duration ) instant swap 15 * >>year ;
162 : score ( x -- duration ) instant swap 20 * >>year ;
163 : jubilees ( x -- duration ) instant swap 50 * >>year ;
164 : centuries ( x -- duration ) instant swap 100 * >>year ;
165 : millennia ( x -- duration ) instant swap 1000 * >>year ;
166 : millenniums ( x -- duration ) instant swap 1000 * >>year ;
167 : kila-annum ( x -- duration ) instant swap 1000 * >>year ;
168 : mega-annum ( x -- duration ) instant swap 1,000,000 * >>year ;
169 : giga-annum ( x -- duration ) instant swap 1,000,000,000 * >>year ;
170 : ages ( x -- duration ) instant swap 1,000,000 * >>year ;
171 : epochs ( x -- duration ) instant swap 10,000,000 * >>year ;
172 : eras ( x -- duration ) instant swap 100,000,000 * >>year ;
173 : eons ( x -- duration ) instant swap 500,000,000 * >>year ;
174 : months ( x -- duration ) instant swap >>month ;
175 : days ( x -- duration ) instant swap >>day ;
176 : weeks ( x -- duration ) 7 * days ;
177 : fortnight ( x -- duration ) 14 * days ;
178 : hours ( x -- duration ) instant swap >>hour ;
179 : minutes ( x -- duration ) instant swap >>minute ;
180 : seconds ( x -- duration ) instant swap >>second ;
181 : milliseconds ( x -- duration ) 1000 / seconds ;
182 : microseconds ( x -- duration ) 1000000 / seconds ;
183 : nanoseconds ( x -- duration ) 1000000000 / seconds ;
184
185 <PRIVATE
186
187 GENERIC: +year ( timestamp x -- timestamp )
188 GENERIC: +month ( timestamp x -- timestamp )
189 GENERIC: +day ( timestamp x -- timestamp )
190 GENERIC: +hour ( timestamp x -- timestamp )
191 GENERIC: +minute ( timestamp x -- timestamp )
192 GENERIC: +second ( timestamp x -- timestamp )
193
194 : /rem ( f n -- q r )
195     ! q is positive or negative, r is positive from 0 <= r < n
196     [ /mod ] keep over 0 < [ + [ -1 + ] dip ] [ drop ] if ; inline
197
198 : float>whole-part ( float -- int float )
199     [ floor >integer ] keep over - ; inline
200
201 : adjust-leap-year ( timestamp -- timestamp )
202     dup
203     { [ day>> 29 = ] [ month>> 2 = ] [ leap-year? not ] } 1&&
204     [ 3 >>month 1 >>day ] when ;
205
206 M: integer +year
207     [ + ] curry change-year adjust-leap-year ;
208
209 M: real +year
210     float>whole-part swapd days-per-year * +day swap +year ;
211
212 : months/years ( n -- months years )
213     12 /rem [ 1 - 12 ] when-zero swap ; inline
214
215 M: integer +month
216     [ over month>> + months/years [ >>month ] dip +year ] unless-zero ;
217
218 M: real +month
219     float>whole-part swapd average-month * +day swap +month ;
220
221 M: integer +day
222     [ over >date< julian-day-number + julian-day-number>date set-date ] unless-zero ;
223
224 M: real +day
225     float>whole-part swapd 24 * +hour swap +day ;
226
227 : hours/days ( n -- hours days )
228     24 /rem swap ; inline
229
230 M: integer +hour
231     [ over hour>> + hours/days [ >>hour ] dip +day ] unless-zero ;
232
233 M: real +hour
234     float>whole-part swapd 60 * +minute swap +hour ;
235
236 : minutes/hours ( n -- minutes hours )
237     60 /rem swap ; inline
238
239 M: integer +minute
240     [ over minute>> + minutes/hours [ >>minute ] dip +hour ] unless-zero ;
241
242 M: real +minute
243     float>whole-part swapd 60 * +second swap +minute ;
244
245 : seconds/minutes ( n -- seconds minutes )
246     60 /rem swap ; inline
247
248 M: number +second
249     [ over second>> + seconds/minutes [ >>second ] dip +minute ] unless-zero ;
250
251 : (time+) ( timestamp duration -- timestamp )
252     {
253         [ second>> +second ]
254         [ minute>> +minute ]
255         [ hour>>   +hour   ]
256         [ day>>    +day    ]
257         [ month>>  +month  ]
258         [ year>>   +year   ]
259      } cleave ; inline
260
261 PRIVATE>
262
263 GENERIC#: time+ 1 ( time1 time2 -- time3 )
264
265 M: timestamp time+ [ clone ] dip (time+) ;
266
267 : duration+ ( duration1 duration2 -- duration3 )
268     {
269         [ [ year>> ] bi@ + ]
270         [ [ month>> ] bi@ + ]
271         [ [ day>> ] bi@ + ]
272         [ [ hour>> ] bi@ + ]
273         [ [ minute>> ] bi@ + ]
274         [ [ second>> ] bi@ + ]
275     } 2cleave <duration> ; inline
276
277 M: duration time+
278     dup timestamp? [ swap time+ ] [ duration+ ] if ;
279
280 : duration>years ( duration -- x )
281     ! Uses average month/year length since duration loses calendar data
282     0 swap
283     {
284         [ year>> + ]
285         [ month>> months-per-year / + ]
286         [ day>> days-per-year / + ]
287         [ hour>> hours-per-year / + ]
288         [ minute>> minutes-per-year / + ]
289         [ second>> seconds-per-year / + ]
290     } cleave ;
291
292 M: duration <=> [ duration>years ] compare ;
293
294 : duration>months ( duration -- x ) duration>years months-per-year * ;
295 : duration>days ( duration -- x ) duration>years days-per-year * ;
296 : duration>hours ( duration -- x ) duration>years hours-per-year * ;
297 : duration>minutes ( duration -- x ) duration>years minutes-per-year * ;
298 : duration>seconds ( duration -- x ) duration>years seconds-per-year * ;
299 : duration>milliseconds ( duration -- x ) duration>seconds 1000 * ;
300 : duration>microseconds ( duration -- x ) duration>seconds 1000000 * ;
301 : duration>nanoseconds ( duration -- x ) duration>seconds 1000000000 * ;
302
303 DEFER: time-
304
305 : gmt ( timestamp -- timestamp )
306     instant >>gmt-offset ; inline
307
308 : local-time ( timestamp -- timestamp )
309     gmt-offset-duration >>gmt-offset ; inline
310
311 : convert-timezone ( timestamp duration -- timestamp )
312     [ over gmt-offset>> time- (time+) ] [ >>gmt-offset ] bi ;
313
314 : convert-local-time ( timestamp -- timestamp )
315     gmt-offset-duration convert-timezone ;
316
317 : convert-gmt ( timestamp -- timestamp )
318     instant convert-timezone ;
319
320 : >local-time ( timestamp -- timestamp' )
321     clone convert-local-time ;
322
323 : >gmt ( timestamp -- timestamp' )
324     clone convert-gmt ;
325
326 : >timezone ( timestamp duration -- timestamp' )
327     [ clone ] [ convert-timezone ] bi* ;
328
329 ALIAS: utc gmt
330 ALIAS: convert-utc convert-gmt
331 ALIAS: >utc >gmt
332
333 M: timestamp <=> [ >gmt tuple-slots ] compare ;
334
335 : same-year? ( ts1 ts2 -- ? )
336     [ year>> ] bi@ = ; inline
337
338 : quarter ( timestamp -- [1,4] )
339     month>> 3 /mod [ drop 1 + ] unless-zero ; inline
340
341 : same-quarter? ( ts1 ts2 -- ? )
342     [ [ year>> ] [ quarter ] bi 2array ] same? ;
343
344 : same-month? ( ts1 ts2 -- ? )
345     [ slots{ year month } ] same? ;
346
347 :: (day-of-year) ( year month day -- n )
348     month days-until nth day + {
349         [ year leap-year? ]
350         [ month 3 >= ]
351     } 0&& [ 1 + ] when ;
352
353 : day-of-year ( timestamp -- n )
354     >date< (day-of-year) ;
355
356 : same-day? ( ts1 ts2 -- ? )
357     [ slots{ year month day } ] same? ;
358
359 : same-day-of-year? ( ts1 ts2 -- ? )
360     [ slots{ month day } ] same? ;
361
362 : (day-of-week) ( year month day -- n )
363     ! Zeller Congruence
364     ! http://web.textfiles.com/computers/formulas.txt
365     ! good for any date since October 15, 1582
366     [
367         dup 2 <= [ [ 1 - ] [ 12 + ] bi* ] when
368         [ dup [ 4 /i + ] [ 100 /i - ] [ 400 /i + ] tri ] dip
369         [ 1 + 3 * 5 /i + ] keep 2 * +
370     ] dip 1 + + 7 mod ;
371
372 : day-of-week ( timestamp -- n )
373     >date< (day-of-week) ;
374
375 : (week-number) ( timestamp -- [0,53] )
376     [ day-of-year ] [ day-of-week [ 7 ] when-zero ] bi - 10 + 7 /i ;
377
378 DEFER: end-of-year
379
380 : week-number ( timestamp -- [1,53] )
381     dup (week-number) {
382         {  0 [ year>> 1 - end-of-year (week-number) ] }
383         { 53 [ year>> 1 + <year> (week-number) 1 = 1 53 ? ] }
384         [ nip ]
385     } case ;
386
387 : same-week? ( ts1 ts2 -- ? )
388     [ [ year>> ] [ week-number ] bi 2array ] same? ;
389
390 : same-hour? ( ts1 ts2 -- ? )
391     [ >gmt slots{ year month day hour } ] same? ;
392
393 : same-minute? ( ts1 ts2 -- ? )
394     [ >gmt slots{ year month day hour minute } ] same? ;
395
396 : same-second? ( ts1 ts2 -- ? )
397     [ >gmt ] bi@
398     {
399         [ [ second>> floor ] bi@ = ]
400         [ [ slots{ year month day hour minute } ] same? ]
401     } 2&& ;
402
403 <PRIVATE
404
405 : (time-) ( timestamp timestamp -- n )
406     [ [ >date< julian-day-number ] bi@ - 86400 * ]
407     [ [ >time< [ 3600 * ] [ 60 * + ] [ + ] tri* ] bi@ - + ]
408     [ [ gmt-offset>> duration>seconds ] bi@ swap - + ] 2tri ;
409
410 PRIVATE>
411
412 GENERIC: time- ( time1 time2 -- time3 )
413
414 M: timestamp time-
415     ! Exact calendar-time difference
416     (time-) seconds ;
417
418 : duration* ( obj1 obj2 -- obj3 )
419     dup real? [ swap ] when
420     dup real? [ * ] [
421         {
422             [   year>> * ]
423             [  month>> * ]
424             [    day>> * ]
425             [   hour>> * ]
426             [ minute>> * ]
427             [ second>> * ]
428         } 2cleave <duration>
429     ] if ;
430
431 : before ( duration -- -duration )
432     -1 duration* ;
433
434 : duration- ( duration1 duration2 -- duration3 )
435     {
436         [ [ year>> ] bi@ - ]
437         [ [ month>> ] bi@ - ]
438         [ [ day>> ] bi@ - ]
439         [ [ hour>> ] bi@ - ]
440         [ [ minute>> ] bi@ - ]
441         [ [ second>> ] bi@ - ]
442     } 2cleave <duration> ; inline
443
444 M: duration time-
445     over timestamp? [ before time+ ] [ duration- ] if ;
446
447 : unix-1970 ( -- timestamp )
448     1970 <year-gmt> ; inline
449
450 : millis>timestamp ( x -- timestamp )
451     unix-1970 swap 1000 / +second ;
452
453 : timestamp>millis ( timestamp -- n )
454     unix-1970 (time-) 1000 * >integer ;
455
456 : micros>timestamp ( x -- timestamp )
457     unix-1970 swap 1000000 / +second ;
458
459 : timestamp>micros ( timestamp -- n )
460     unix-1970 (time-) 1000000 * >integer ;
461
462 : now ( -- timestamp )
463     now-gmt gmt-offset-duration [ (time+) ] [ >>gmt-offset ] bi ;
464
465 : hence ( duration -- timestamp ) now swap time+ ;
466 : ago ( duration -- timestamp ) now swap time- ;
467
468 GENERIC: days-in-year ( obj -- n )
469
470 M: integer days-in-year leap-year? 366 365 ? ;
471
472 M: timestamp days-in-year year>> days-in-year ;
473
474 : days-in-month ( timestamp -- n )
475     >date< drop (days-in-month) ;
476
477 : midnight! ( timestamp -- timestamp ) 0 0 0 set-time ; inline
478 : noon! ( timestamp -- timestamp ) 12 0 0 set-time ; inline
479
480 : midnight ( timestamp -- timestamp ) clone midnight! ; inline
481 : noon ( timestamp -- timestamp ) clone noon! ; inline
482
483 : today ( -- timestamp ) now midnight ; inline
484 : tomorrow ( -- timestamp ) 1 days hence midnight ; inline
485 : yesterday ( -- timestamp ) 1 days ago midnight ; inline
486 : overtomorrow ( -- timestamp ) 2 days hence midnight ; inline
487 : ereyesterday ( -- timestamp ) 2 days ago midnight ; inline
488
489 : today? ( timestamp -- ? ) now same-day? ; inline
490 : tomorrow? ( timestamp -- ? ) 1 days hence same-day? ; inline
491 : yesterday? ( timestamp -- ? ) 1 days ago same-day? ; inline
492
493 ALIAS: start-of-day midnight
494
495 : end-of-day! ( timestamp -- timestamp )
496     23 >>hour 59 >>minute 59+999/1000 >>second ; inline
497
498 : end-of-day ( timestamp -- timestamp )
499     clone end-of-day! ; inline
500
501 : start-of-month ( timestamp -- timestamp )
502     midnight 1 >>day ; inline
503
504 : end-of-month ( timestamp -- timestamp )
505     [ end-of-day ] [ days-in-month ] bi >>day ;
506
507 : start-of-quarter ( timestamp -- timestamp )
508     [ start-of-day ] [ quarter 1 - 3 * ] bi >>month ; inline
509
510 : end-of-quarter ( timestamp -- timestamp )
511     dup quarter 1 - 3 * 3 + >>month end-of-month ; inline
512
513 : first-day-of-month! ( timestamp -- timestamp )
514     1 >>day ;
515
516 : first-day-of-month ( timestamp -- timestamp )
517     clone first-day-of-month! ;
518
519 : last-day-of-month! ( timestamp -- timestamp )
520     dup days-in-month >>day ; inline
521
522 : last-day-of-month ( timestamp -- timestamp )
523     clone last-day-of-month! ; inline
524
525 : first-day-of-year! ( timestamp -- timestamp )
526     first-day-of-month! 1 >>month ; inline
527
528 GENERIC: first-day-of-year ( object -- timestamp )
529 M: timestamp first-day-of-year clone first-day-of-year! ;
530 M: integer first-day-of-year <year> ;
531
532 : last-day-of-year! ( timestamp -- timestamp )
533     12 >>month 31 >>day ; inline
534
535 GENERIC: last-day-of-year ( object -- timestamp )
536 M: timestamp last-day-of-year clone last-day-of-year! ;
537 M: integer last-day-of-year 12 31 <date> ;
538
539 : first-day-of-decade ( object -- timestamp )
540     first-day-of-year [ dup 10 mod - ] change-year ;
541
542 : last-day-of-decade ( object -- timestamp )
543     last-day-of-year [ dup 10 mod - 9 + ] change-year ;
544
545 : first-day-of-century ( object -- timestamp )
546     first-day-of-year [ dup 100 mod - ] change-year ;
547
548 : last-day-of-century ( object -- timestamp )
549     last-day-of-year [ dup 100 mod - 99 + ] change-year ;
550
551 : first-day-of-millennium ( object -- timestamp )
552     first-day-of-year [ dup 1000 mod - ] change-year ;
553
554 : last-day-of-millennium ( object -- timestamp )
555     last-day-of-year [ dup 1000 mod - 999 + ] change-year ;
556
557 : start-of-year ( object -- timestamp )
558     first-day-of-year start-of-day ;
559
560 : end-of-year ( object -- timestamp )
561     last-day-of-year end-of-day ;
562
563 : start-of-decade ( object -- timestamp )
564     first-day-of-decade start-of-day ;
565
566 : end-of-decade ( object -- timestamp )
567     last-day-of-decade end-of-day ;
568
569 : end-of-century ( object -- timestamp )
570     last-day-of-century end-of-day ;
571
572 : start-of-millennium ( object -- timestamp )
573     first-day-of-millennium start-of-day ;
574
575 : end-of-millennium ( object -- timestamp )
576     last-day-of-millennium end-of-day ;
577
578 : start-of-hour! ( timestamp -- timestamp ) 0 >>minute 0 >>second ;
579 : end-of-hour! ( timestamp -- timestamp ) 59 >>minute 59+999/1000 >>second ;
580 : start-of-hour ( timestamp -- timestamp ) clone start-of-hour! ;
581 : end-of-hour ( timestamp -- timestamp ) clone end-of-hour! ;
582
583 : start-of-minute! ( timestamp -- timestamp ) 0 >>second ;
584 : end-of-minute! ( timestamp -- timestamp ) 59+999/1000 >>second ;
585 : start-of-minute ( timestamp -- timestamp ) clone start-of-minute! ;
586 : end-of-minute ( timestamp -- timestamp ) clone end-of-minute! ;
587
588 : start-of-second! ( timestamp -- timestamp ) [ floor ] change-second ;
589 : end-of-second! ( timestamp -- timestamp ) [ floor 999/1000 + ] change-second ;
590 : start-of-second ( timestamp -- timestamp ) clone start-of-second! ;
591 : end-of-second ( timestamp -- timestamp ) clone end-of-second! ;
592
593 <PRIVATE
594
595 : day-offset ( timestamp m -- timestamp n )
596     over day-of-week - ; inline
597
598 : day-this-week ( timestamp n -- timestamp )
599     day-offset days (time+) ;
600
601 : closest-day ( timestamp n -- timestamp )
602     [ dup day-of-week 7 swap - ] [ + 7 mod ] bi*
603     { 0 1 2 3 -3 -2 -1 } nth days (time+) ;
604
605 :: nth-day-this-month ( timestamp n day -- timestamp )
606     timestamp clone
607     timestamp start-of-month day day-this-week
608     [ [ month>> ] same? ] keep swap
609     [ 1 weeks (time+) ] unless
610     n [ weeks (time+) ] unless-zero ;
611
612 PRIVATE>
613
614 GENERIC: january ( obj -- timestamp )
615 GENERIC: february ( obj -- timestamp )
616 GENERIC: march ( obj -- timestamp )
617 GENERIC: april ( obj -- timestamp )
618 GENERIC: may ( obj -- timestamp )
619 GENERIC: june ( obj -- timestamp )
620 GENERIC: july ( obj -- timestamp )
621 GENERIC: august ( obj -- timestamp )
622 GENERIC: september ( obj -- timestamp )
623 GENERIC: october ( obj -- timestamp )
624 GENERIC: november ( obj -- timestamp )
625 GENERIC: december ( obj -- timestamp )
626
627 M: integer january 1 1 <date> ;
628 M: integer february 2 1 <date> ;
629 M: integer march 3 1 <date> ;
630 M: integer april 4 1 <date> ;
631 M: integer may 5 1 <date> ;
632 M: integer june 6 1 <date> ;
633 M: integer july 7 1 <date> ;
634 M: integer august 8 1 <date> ;
635 M: integer september 9 1 <date> ;
636 M: integer october 10 1 <date> ;
637 M: integer november 11 1 <date> ;
638 M: integer december 12 1 <date> ;
639
640 M: timestamp january 1 >>month ;
641 M: timestamp february 2 >>month ;
642 M: timestamp march 3 >>month ;
643 M: timestamp april 4 >>month ;
644 M: timestamp may 5 >>month ;
645 M: timestamp june 6 >>month ;
646 M: timestamp july 7 >>month ;
647 M: timestamp august 8 >>month ;
648 M: timestamp september 9 >>month ;
649 M: timestamp october 10 >>month ;
650 M: timestamp november 11 >>month ;
651 M: timestamp december 12 >>month ;
652
653 : closest-sunday ( timestamp -- timestamp ) 0 closest-day ;
654 : closest-monday ( timestamp -- timestamp ) 1 closest-day ;
655 : closest-tuesday ( timestamp -- timestamp ) 2 closest-day ;
656 : closest-wednesday ( timestamp -- timestamp ) 3 closest-day ;
657 : closest-thursday ( timestamp -- timestamp ) 4 closest-day ;
658 : closest-friday ( timestamp -- timestamp ) 5 closest-day ;
659 : closest-saturday ( timestamp -- timestamp ) 6 closest-day ;
660
661 : sunday ( timestamp -- timestamp ) 0 day-this-week ;
662 : monday ( timestamp -- timestamp ) 1 day-this-week ;
663 : tuesday ( timestamp -- timestamp ) 2 day-this-week ;
664 : wednesday ( timestamp -- timestamp ) 3 day-this-week ;
665 : thursday ( timestamp -- timestamp ) 4 day-this-week ;
666 : friday ( timestamp -- timestamp ) 5 day-this-week ;
667 : saturday ( timestamp -- timestamp ) 6 day-this-week ;
668
669 ALIAS: first-day-of-week sunday
670 ALIAS: last-day-of-week saturday
671
672 : day< ( timestamp quot -- timestamp )
673     over clone [ call dup ] dip after=? [ -7 days (time+) ] when ; inline
674 : day<= ( timestamp quot -- timestamp )
675     over clone [ call dup ] dip after? [ -7 days (time+) ] when ; inline
676 : day> ( timestamp quot -- timestamp )
677     over clone [ call dup ] dip before=? [ 7 days (time+) ] when ; inline
678 : day>= ( timestamp quot -- timestamp )
679     over clone [ call dup ] dip before? [ 7 days (time+) ] when ; inline
680
681 : sunday< ( timestamp -- timestamp ) [ sunday ] day< ;
682 : monday< ( timestamp -- timestamp ) [ monday ] day< ;
683 : tuesday< ( timestamp -- timestamp ) [ tuesday ] day< ;
684 : wednesday< ( timestamp -- timestamp ) [ wednesday ] day< ;
685 : thursday< ( timestamp -- timestamp ) [ thursday ] day< ;
686 : friday< ( timestamp -- timestamp ) [ friday ] day< ;
687 : saturday< ( timestamp -- timestamp ) [ saturday ] day< ;
688
689 : sunday<= ( timestamp -- timestamp ) [ sunday ] day<= ;
690 : monday<= ( timestamp -- timestamp ) [ monday ] day<= ;
691 : tuesday<= ( timestamp -- timestamp ) [ tuesday ] day<= ;
692 : wednesday<= ( timestamp -- timestamp ) [ wednesday ] day<= ;
693 : thursday<= ( timestamp -- timestamp ) [ thursday ] day<= ;
694 : friday<= ( timestamp -- timestamp ) [ friday ] day<= ;
695 : saturday<= ( timestamp -- timestamp ) [ saturday ] day<= ;
696
697 : sunday> ( timestamp -- timestamp ) [ sunday ] day> ;
698 : monday> ( timestamp -- timestamp ) [ monday ] day> ;
699 : tuesday> ( timestamp -- timestamp ) [ tuesday ] day> ;
700 : wednesday> ( timestamp -- timestamp ) [ wednesday ] day> ;
701 : thursday> ( timestamp -- timestamp ) [ thursday ] day> ;
702 : friday> ( timestamp -- timestamp ) [ friday ] day> ;
703 : saturday> ( timestamp -- timestamp ) [ saturday ] day> ;
704
705 : sunday>= ( timestamp -- timestamp ) [ sunday ] day>= ;
706 : monday>= ( timestamp -- timestamp ) [ monday ] day>= ;
707 : tuesday>= ( timestamp -- timestamp ) [ tuesday ] day>= ;
708 : wednesday>= ( timestamp -- timestamp ) [ wednesday ] day>= ;
709 : thursday>= ( timestamp -- timestamp ) [ thursday ] day>= ;
710 : friday>= ( timestamp -- timestamp ) [ friday ] day>= ;
711 : saturday>= ( timestamp -- timestamp ) [ saturday ] day>= ;
712
713 : next-sunday ( timestamp -- timestamp ) closest-sunday sunday> ;
714 : next-monday ( timestamp -- timestamp ) closest-monday monday> ;
715 : next-tuesday ( timestamp -- timestamp ) closest-tuesday tuesday> ;
716 : next-wednesday ( timestamp -- timestamp ) closest-wednesday wednesday> ;
717 : next-thursday ( timestamp -- timestamp ) closest-thursday thursday> ;
718 : next-friday ( timestamp -- timestamp ) closest-friday friday> ;
719 : next-saturday ( timestamp -- timestamp ) closest-saturday saturday> ;
720
721 : last-sunday ( timestamp -- timestamp ) closest-sunday sunday< ;
722 : last-monday ( timestamp -- timestamp ) closest-monday monday< ;
723 : last-tuesday ( timestamp -- timestamp ) closest-tuesday tuesday< ;
724 : last-wednesday ( timestamp -- timestamp ) closest-wednesday wednesday< ;
725 : last-thursday ( timestamp -- timestamp ) closest-thursday thursday< ;
726 : last-friday ( timestamp -- timestamp ) closest-friday friday< ;
727 : last-saturday ( timestamp -- timestamp ) closest-saturday saturday< ;
728
729 : sunday? ( timestamp -- ? ) day-of-week 0 = ;
730 : monday? ( timestamp -- ? ) day-of-week 1 = ;
731 : tuesday? ( timestamp -- ? ) day-of-week 2 = ;
732 : wednesday? ( timestamp -- ? ) day-of-week 3 = ;
733 : thursday? ( timestamp -- ? ) day-of-week 4 = ;
734 : friday? ( timestamp -- ? ) day-of-week 5 = ;
735 : saturday? ( timestamp -- ? ) day-of-week 6 = ;
736
737 : january? ( timestamp -- ? ) month>> 1 = ;
738 : february? ( timestamp -- ? ) month>> 2 = ;
739 : march? ( timestamp -- ? ) month>> 3  = ;
740 : april? ( timestamp -- ? ) month>> 4 = ;
741 : may? ( timestamp -- ? ) month>> 5 = ;
742 : june? ( timestamp -- ? ) month>> 6 = ;
743 : july? ( timestamp -- ? ) month>> 7 = ;
744 : august? ( timestamp -- ? ) month>> 8 = ;
745 : september? ( timestamp -- ? ) month>> 9 = ;
746 : october? ( timestamp -- ? ) month>> 10 = ;
747 : november? ( timestamp -- ? ) month>> 11 = ;
748 : december? ( timestamp -- ? ) month>> 12 = ;
749
750 : weekend? ( timestamp -- ? ) day-of-week { 0 6 } member? ;
751 : weekday? ( timestamp -- ? ) day-of-week weekend? not ;
752
753 : same-or-next-business-day ( timestamp -- timestamp )
754     dup day-of-week {
755         { 0 [ monday ] }
756         { 6 [ 2 days (time+) ] }
757         [ drop ]
758     } case ;
759
760 : same-or-previous-business-day ( timestamp -- timestamp )
761     dup day-of-week {
762         { 0 [ -2 days (time+) ] }
763         { 6 [ friday ] }
764         [ drop ]
765     } case ;
766
767 : weekdays-between ( date1 date2 -- n )
768     [
769         [ swap time- duration>days 5 * ]
770         [ [ day-of-week ] bi@ - 2 * ] 2bi - 7 /i 1 +
771     ] 2keep
772     day-of-week 6 = [ [ 1 - ] dip ] when
773     day-of-week 0 = [ 1 - ] when ;
774
775 CONSTANT: weekday-offsets { 0 0 1 2 3 4 5 }
776
777 : weekdays-between2 ( date1 date2 -- n )
778     [ swap time- duration>days 1 + ]
779     [ [ day-of-week ] bi@ 6 swap - ] 2bi
780
781     [ + + 1.4 /i ]
782     [ [ weekday-offsets nth ] bi@ + ] 2bi - ;
783
784 : sunday-of-month ( timestamp n -- timestamp ) 0 nth-day-this-month ;
785 : monday-of-month ( timestamp n -- timestamp ) 1 nth-day-this-month ;
786 : tuesday-of-month ( timestamp n -- timestamp ) 2 nth-day-this-month ;
787 : wednesday-of-month ( timestamp n -- timestamp ) 3 nth-day-this-month ;
788 : thursday-of-month ( timestamp n -- timestamp ) 4 nth-day-this-month ;
789 : friday-of-month ( timestamp n -- timestamp ) 5 nth-day-this-month ;
790 : saturday-of-month ( timestamp n -- timestamp ) 6 nth-day-this-month ;
791
792 : last-sunday-of-month ( timestamp -- timestamp ) last-day-of-month sunday<= ;
793 : last-monday-of-month ( timestamp -- timestamp ) last-day-of-month monday<= ;
794 : last-tuesday-of-month ( timestamp -- timestamp ) last-day-of-month tuesday<= ;
795 : last-wednesday-of-month ( timestamp -- timestamp ) last-day-of-month wednesday<= ;
796 : last-thursday-of-month ( timestamp -- timestamp ) last-day-of-month thursday<= ;
797 : last-friday-of-month ( timestamp -- timestamp ) last-day-of-month friday<= ;
798 : last-saturday-of-month ( timestamp -- timestamp ) last-day-of-month saturday<= ;
799
800 : start-of-week ( timestamp -- timestamp )
801     sunday midnight ;
802
803 : end-of-week ( timestamp -- timestamp )
804     saturday end-of-day ;
805
806 : o'clock ( timestamp n -- timestamp )
807     [ midnight ] dip >>hour ;
808
809 : am ( timestamp n -- timestamp )
810     1 12 [a,b] check-interval 12 mod o'clock ;
811
812 : pm ( timestamp n -- timestamp )
813     1 12 [a,b] check-interval 12 mod 12 + o'clock ;
814
815 : time-since-midnight ( timestamp -- duration )
816     instant swap >time< set-time ;
817
818 : since-1970 ( duration -- timestamp )
819     unix-1970 swap (time+) ; inline
820
821 : timestamp>unix-time ( timestamp -- seconds )
822     unix-1970 (time-) ; inline
823
824 : unix-time>timestamp ( seconds -- timestamp )
825     unix-1970 swap +second ; inline
826
827 ! January and February need a fixup with this algorithm.
828 ! Find a better algorithm.
829 : ymd>ordinal ( year month day -- ordinal )
830     [ leap-year? dup -2 -3 ? ]
831     [ dup 3 < [ 12 + ] when [ 1 - 30 * ] [ 1 + .6 * floor ] bi + ]
832     [ ] tri* + + >integer
833     swap 367 366 ? mod ;
834
835 : timestamp>year-dates-gmt ( timestamp -- seq )
836     [ year>> 1 1 julian-day-number ] [ days-in-year ] bi
837     [ drop ] [ + ] 2bi
838     [a..b) [ julian-day-number>date <date-gmt> ] map ;
839
840 : year-ordinal>timestamp ( year ordinal -- timestamp )
841     [ 1 1 julian-day-number ] dip
842     + 1 - julian-day-number>date <date> ;
843
844 GENERIC: weeks-in-week-year ( obj -- n )
845
846 M: integer weeks-in-week-year
847     { [ 1 1 <date> thursday? ] [ 12 31 <date> thursday? ] } 1|| 53 52 ? ;
848
849 M: timestamp weeks-in-week-year
850     { [ january 1 >>day thursday? ] [ december 31 >>day thursday? ] } 1|| 53 52 ? ;
851
852 {
853     { [ os unix? ] [ "calendar.unix" ] }
854     { [ os windows? ] [ "calendar.windows" ] }
855 } cond require
856
857 { "threads" "calendar" } "calendar.threads" require-when