basis/checksums/md5/md5.factor

   1 ! Copyright (C) 2006, 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel io io.binary io.files io.streams.byte-array math
   4 math.functions math.parser namespaces splitting grouping strings
   5 sequences byte-arrays locals sequences.private macros fry
   6 io.encodings.binary math.bitwise checksums accessors
   7 checksums.common checksums.stream combinators combinators.smart ;
   8 IN: checksums.md5
   9
  10 SINGLETON: md5
  11
  12 INSTANCE: md5 stream-checksum
  13
  14 TUPLE: md5-state < checksum-state state old-state ;
  15
  16 : <md5-state> ( -- md5 )
  17     64 md5-state new-checksum-state
  18         { HEX: 67452301 HEX: efcdab89 HEX: 98badcfe HEX: 10325476 }
  19         [ clone >>state ] [ >>old-state ] bi ;
  20
  21 <PRIVATE
  22
  23 : v-w+ ( v1 v2 -- v3 ) [ w+ ] 2map ;
  24
  25 : update-md5 ( md5 -- )
  26     [ state>> ] [ old-state>> v-w+ dup clone ] [ ] tri
  27     [ (>>old-state) ] [ (>>state) ] bi ; inline
  28
  29 : T ( N -- Y )
  30     sin abs 32 2^ * >integer ; inline
  31
  32 :: F ( X Y Z -- FXYZ )
  33     #! F(X,Y,Z) = XY v not(X) Z
  34     X Y bitand X bitnot Z bitand bitor ; inline
  35
  36 :: G ( X Y Z -- GXYZ )
  37     #! G(X,Y,Z) = XZ v Y not(Z)
  38     X Z bitand Y Z bitnot bitand bitor ; inline
  39
  40 : H ( X Y Z -- HXYZ )
  41     #! H(X,Y,Z) = X xor Y xor Z
  42     bitxor bitxor ; inline
  43
  44 :: I ( X Y Z -- IXYZ )
  45     #! I(X,Y,Z) = Y xor (X v not(Z))
  46     Z bitnot X bitor Y bitxor ; inline
  47
  48 CONSTANT: S11 7
  49 CONSTANT: S12 12
  50 CONSTANT: S13 17
  51 CONSTANT: S14 22
  52 CONSTANT: S21 5
  53 CONSTANT: S22 9
  54 CONSTANT: S23 14
  55 CONSTANT: S24 20
  56 CONSTANT: S31 4
  57 CONSTANT: S32 11
  58 CONSTANT: S33 16
  59 CONSTANT: S34 23
  60 CONSTANT: S41 6
  61 CONSTANT: S42 10
  62 CONSTANT: S43 15
  63 CONSTANT: S44 21
  64
  65 CONSTANT: a 0
  66 CONSTANT: b 1
  67 CONSTANT: c 2
  68 CONSTANT: d 3
  69
  70 :: (ABCD) ( x V a b c d k s i quot -- )
  71     #! a = b + ((a + F(b,c,d) + X[k] + T[i]) <<< s)
  72     a V [
  73         b V nth
  74         c V nth
  75         d V nth quot call w+
  76         k x nth w+
  77         i T w+
  78         s bitroll-32
  79         b V nth w+
  80     ] change-nth ; inline
  81
  82 MACRO: with-md5-round ( ops quot -- )
  83     '[ [ _ (ABCD) ] compose ] map '[ _ 2cleave ] ;
  84
  85 : (process-md5-block-F) ( block v -- )
  86     {
  87         [ a b c d 0  S11 1  ]
  88         [ d a b c 1  S12 2  ]
  89         [ c d a b 2  S13 3  ]
  90         [ b c d a 3  S14 4  ]
  91         [ a b c d 4  S11 5  ]
  92         [ d a b c 5  S12 6  ]
  93         [ c d a b 6  S13 7  ]
  94         [ b c d a 7  S14 8  ]
  95         [ a b c d 8  S11 9  ]
  96         [ d a b c 9  S12 10 ]
  97         [ c d a b 10 S13 11 ]
  98         [ b c d a 11 S14 12 ]
  99         [ a b c d 12 S11 13 ]
 100         [ d a b c 13 S12 14 ]
 101         [ c d a b 14 S13 15 ]
 102         [ b c d a 15 S14 16 ]
 103     } [ F ] with-md5-round ; inline
 104
 105 : (process-md5-block-G) ( block v -- )
 106     {
 107         [ a b c d 1  S21 17 ]
 108         [ d a b c 6  S22 18 ]
 109         [ c d a b 11 S23 19 ]
 110         [ b c d a 0  S24 20 ]
 111         [ a b c d 5  S21 21 ]
 112         [ d a b c 10 S22 22 ]
 113         [ c d a b 15 S23 23 ]
 114         [ b c d a 4  S24 24 ]
 115         [ a b c d 9  S21 25 ]
 116         [ d a b c 14 S22 26 ]
 117         [ c d a b 3  S23 27 ]
 118         [ b c d a 8  S24 28 ]
 119         [ a b c d 13 S21 29 ]
 120         [ d a b c 2  S22 30 ]
 121         [ c d a b 7  S23 31 ]
 122         [ b c d a 12 S24 32 ]
 123     } [ G ] with-md5-round ; inline
 124
 125 : (process-md5-block-H) ( block v -- )
 126     {
 127         [ a b c d 5  S31 33 ]
 128         [ d a b c 8  S32 34 ]
 129         [ c d a b 11 S33 35 ]
 130         [ b c d a 14 S34 36 ]
 131         [ a b c d 1  S31 37 ]
 132         [ d a b c 4  S32 38 ]
 133         [ c d a b 7  S33 39 ]
 134         [ b c d a 10 S34 40 ]
 135         [ a b c d 13 S31 41 ]
 136         [ d a b c 0  S32 42 ]
 137         [ c d a b 3  S33 43 ]
 138         [ b c d a 6  S34 44 ]
 139         [ a b c d 9  S31 45 ]
 140         [ d a b c 12 S32 46 ]
 141         [ c d a b 15 S33 47 ]
 142         [ b c d a 2  S34 48 ]
 143     } [ H ] with-md5-round ; inline
 144
 145 : (process-md5-block-I) ( block v -- )
 146     {
 147         [ a b c d 0  S41 49 ]
 148         [ d a b c 7  S42 50 ]
 149         [ c d a b 14 S43 51 ]
 150         [ b c d a 5  S44 52 ]
 151         [ a b c d 12 S41 53 ]
 152         [ d a b c 3  S42 54 ]
 153         [ c d a b 10 S43 55 ]
 154         [ b c d a 1  S44 56 ]
 155         [ a b c d 8  S41 57 ]
 156         [ d a b c 15 S42 58 ]
 157         [ c d a b 6  S43 59 ]
 158         [ b c d a 13 S44 60 ]
 159         [ a b c d 4  S41 61 ]
 160         [ d a b c 11 S42 62 ]
 161         [ c d a b 2  S43 63 ]
 162         [ b c d a 9  S44 64 ]
 163     } [ I ] with-md5-round ; inline
 164
 165 M: md5-state checksum-block ( block state -- )
 166     [
 167         [ 4 <groups> [ le> ] map ] [ state>> ] bi* {
 168             [ (process-md5-block-F) ]
 169             [ (process-md5-block-G) ]
 170             [ (process-md5-block-H) ]
 171             [ (process-md5-block-I) ]
 172         } 2cleave
 173     ] [
 174         nip update-md5
 175     ] 2bi ;
 176
 177 : md5>checksum ( md5 -- bytes )
 178     state>> [ 4 >le ] map B{ } concat-as ;
 179
 180 M: md5-state clone ( md5 -- new-md5 )
 181     call-next-method
 182     [ clone ] change-state
 183     [ clone ] change-old-state ;
 184
 185 M: md5-state get-checksum ( md5 -- bytes )
 186     clone [ bytes>> f ] [ bytes-read>> pad-last-block ] [ ] tri
 187     [ [ checksum-block ] curry each ] [ md5>checksum ] bi ;
 188
 189 M: md5 checksum-stream ( stream checksum -- byte-array )
 190     drop
 191     [ <md5-state> ] dip add-checksum-stream get-checksum ;
 192
 193 PRIVATE>