basis/checksums/sha/sha.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors checksums checksums.common checksums.stream
   4 combinators combinators.smart fry generalizations grouping
   5 io.binary kernel literals locals make math math.bitwise
   6 math.ranges multiline namespaces sbufs sequences
   7 sequences.generalizations sequences.private splitting strings ;
   8 IN: checksums.sha
   9
  10 SINGLETON: sha1
  11 INSTANCE: sha1 stream-checksum
  12
  13 SINGLETON: sha-224
  14 SINGLETON: sha-256
  15
  16 INSTANCE: sha-224 stream-checksum
  17 INSTANCE: sha-256 stream-checksum
  18
  19 TUPLE: sha1-state < checksum-state K H W word-size ;
  20
  21 CONSTANT: initial-H-sha1
  22     {
  23         0x67452301
  24         0xefcdab89
  25         0x98badcfe
  26         0x10325476
  27         0xc3d2e1f0
  28     }
  29
  30 CONSTANT: K-sha1
  31     $[
  32         20 0x5a827999 <repetition>
  33         20 0x6ed9eba1 <repetition>
  34         20 0x8f1bbcdc <repetition>
  35         20 0xca62c1d6 <repetition>
  36         4 { } nappend-as
  37     ]
  38
  39 TUPLE: sha2-state < checksum-state K H word-size ;
  40
  41 TUPLE: sha2-short < sha2-state ;
  42
  43 TUPLE: sha2-long < sha2-state ;
  44
  45 TUPLE: sha-224-state < sha2-short ;
  46
  47 TUPLE: sha-256-state < sha2-short ;
  48
  49 M: sha2-state clone
  50     call-next-method
  51     [ clone ] change-H
  52     [ clone ] change-K ;
  53
  54 <PRIVATE
  55
  56 CONSTANT: a 0
  57 CONSTANT: b 1
  58 CONSTANT: c 2
  59 CONSTANT: d 3
  60 CONSTANT: e 4
  61 CONSTANT: f 5
  62 CONSTANT: g 6
  63 CONSTANT: h 7
  64
  65 CONSTANT: initial-H-224
  66     {
  67         0xc1059ed8 0x367cd507 0x3070dd17 0xf70e5939
  68         0xffc00b31 0x68581511 0x64f98fa7 0xbefa4fa4
  69     }
  70
  71 CONSTANT: initial-H-256
  72     {
  73         0x6a09e667 0xbb67ae85 0x3c6ef372 0xa54ff53a
  74         0x510e527f 0x9b05688c 0x1f83d9ab 0x5be0cd19
  75     }
  76
  77 CONSTANT: initial-H-384
  78     {
  79         0xcbbb9d5dc1059ed8
  80         0x629a292a367cd507
  81         0x9159015a3070dd17
  82         0x152fecd8f70e5939
  83         0x67332667ffc00b31
  84         0x8eb44a8768581511
  85         0xdb0c2e0d64f98fa7
  86         0x47b5481dbefa4fa4
  87     }
  88
  89 CONSTANT: initial-H-512
  90     {
  91         0x6a09e667f3bcc908
  92         0xbb67ae8584caa73b
  93         0x3c6ef372fe94f82b
  94         0xa54ff53a5f1d36f1
  95         0x510e527fade682d1
  96         0x9b05688c2b3e6c1f
  97         0x1f83d9abfb41bd6b
  98         0x5be0cd19137e2179
  99     }
 100
 101 CONSTANT: K-256
 102     {
 103         0x428a2f98 0x71374491 0xb5c0fbcf 0xe9b5dba5
 104         0x3956c25b 0x59f111f1 0x923f82a4 0xab1c5ed5
 105         0xd807aa98 0x12835b01 0x243185be 0x550c7dc3
 106         0x72be5d74 0x80deb1fe 0x9bdc06a7 0xc19bf174
 107         0xe49b69c1 0xefbe4786 0x0fc19dc6 0x240ca1cc
 108         0x2de92c6f 0x4a7484aa 0x5cb0a9dc 0x76f988da
 109         0x983e5152 0xa831c66d 0xb00327c8 0xbf597fc7
 110         0xc6e00bf3 0xd5a79147 0x06ca6351 0x14292967
 111         0x27b70a85 0x2e1b2138 0x4d2c6dfc 0x53380d13
 112         0x650a7354 0x766a0abb 0x81c2c92e 0x92722c85
 113         0xa2bfe8a1 0xa81a664b 0xc24b8b70 0xc76c51a3
 114         0xd192e819 0xd6990624 0xf40e3585 0x106aa070
 115         0x19a4c116 0x1e376c08 0x2748774c 0x34b0bcb5
 116         0x391c0cb3 0x4ed8aa4a 0x5b9cca4f 0x682e6ff3
 117         0x748f82ee 0x78a5636f 0x84c87814 0x8cc70208
 118         0x90befffa 0xa4506ceb 0xbef9a3f7 0xc67178f2
 119     }
 120
 121 CONSTANT: K-384
 122     {
 123
 124         0x428a2f98d728ae22 0x7137449123ef65cd 0xb5c0fbcfec4d3b2f 0xe9b5dba58189dbbc
 125         0x3956c25bf348b538 0x59f111f1b605d019 0x923f82a4af194f9b 0xab1c5ed5da6d8118
 126         0xd807aa98a3030242 0x12835b0145706fbe 0x243185be4ee4b28c 0x550c7dc3d5ffb4e2
 127         0x72be5d74f27b896f 0x80deb1fe3b1696b1 0x9bdc06a725c71235 0xc19bf174cf692694
 128         0xe49b69c19ef14ad2 0xefbe4786384f25e3 0x0fc19dc68b8cd5b5 0x240ca1cc77ac9c65
 129         0x2de92c6f592b0275 0x4a7484aa6ea6e483 0x5cb0a9dcbd41fbd4 0x76f988da831153b5
 130         0x983e5152ee66dfab 0xa831c66d2db43210 0xb00327c898fb213f 0xbf597fc7beef0ee4
 131         0xc6e00bf33da88fc2 0xd5a79147930aa725 0x06ca6351e003826f 0x142929670a0e6e70
 132         0x27b70a8546d22ffc 0x2e1b21385c26c926 0x4d2c6dfc5ac42aed 0x53380d139d95b3df
 133         0x650a73548baf63de 0x766a0abb3c77b2a8 0x81c2c92e47edaee6 0x92722c851482353b
 134         0xa2bfe8a14cf10364 0xa81a664bbc423001 0xc24b8b70d0f89791 0xc76c51a30654be30
 135         0xd192e819d6ef5218 0xd69906245565a910 0xf40e35855771202a 0x106aa07032bbd1b8
 136         0x19a4c116b8d2d0c8 0x1e376c085141ab53 0x2748774cdf8eeb99 0x34b0bcb5e19b48a8
 137         0x391c0cb3c5c95a63 0x4ed8aa4ae3418acb 0x5b9cca4f7763e373 0x682e6ff3d6b2b8a3
 138         0x748f82ee5defb2fc 0x78a5636f43172f60 0x84c87814a1f0ab72 0x8cc702081a6439ec
 139         0x90befffa23631e28 0xa4506cebde82bde9 0xbef9a3f7b2c67915 0xc67178f2e372532b
 140         0xca273eceea26619c 0xd186b8c721c0c207 0xeada7dd6cde0eb1e 0xf57d4f7fee6ed178
 141         0x06f067aa72176fba 0x0a637dc5a2c898a6 0x113f9804bef90dae 0x1b710b35131c471b
 142         0x28db77f523047d84 0x32caab7b40c72493 0x3c9ebe0a15c9bebc 0x431d67c49c100d4c
 143         0x4cc5d4becb3e42b6 0x597f299cfc657e2a 0x5fcb6fab3ad6faec 0x6c44198c4a475817
 144     }
 145
 146 ALIAS: K-512 K-384
 147
 148 : <sha1-state> ( -- sha1-state )
 149     sha1-state new-checksum-state
 150         64 >>block-size
 151         K-sha1 >>K
 152         initial-H-sha1 >>H
 153         4 >>word-size ;
 154
 155 : <sha-224-state> ( -- sha2-state )
 156     sha-224-state new-checksum-state
 157         64 >>block-size
 158         K-256 >>K
 159         initial-H-224 >>H
 160         4 >>word-size ;
 161
 162 : <sha-256-state> ( -- sha2-state )
 163     sha-256-state new-checksum-state
 164         64 >>block-size
 165         K-256 >>K
 166         initial-H-256 >>H
 167         4 >>word-size ;
 168
 169 M: sha1 initialize-checksum-state drop <sha1-state> ;
 170
 171 M: sha-224 initialize-checksum-state drop <sha-224-state> ;
 172
 173 M: sha-256 initialize-checksum-state drop <sha-256-state> ;
 174
 175 : s0-256 ( x -- x' )
 176     [
 177         [ -7 bitroll-32 ]
 178         [ -18 bitroll-32 ]
 179         [ -3 shift ] tri
 180     ] [ bitxor ] reduce-outputs ; inline
 181
 182 : s1-256 ( x -- x' )
 183     [
 184         [ -17 bitroll-32 ]
 185         [ -19 bitroll-32 ]
 186         [ -10 shift ] tri
 187     ] [ bitxor ] reduce-outputs ; inline
 188
 189 : S0-256 ( x -- x' )
 190     [
 191         [ -2 bitroll-32 ]
 192         [ -13 bitroll-32 ]
 193         [ -22 bitroll-32 ] tri
 194     ] [ bitxor ] reduce-outputs ; inline
 195
 196 : S1-256 ( x -- x' )
 197     [
 198         [ -6 bitroll-32 ]
 199         [ -11 bitroll-32 ]
 200         [ -25 bitroll-32 ] tri
 201     ] [ bitxor ] reduce-outputs ; inline
 202
 203 : s0-512 ( x -- x' )
 204     [
 205         [ -1 bitroll-64 ]
 206         [ -8 bitroll-64 ]
 207         [ -7 shift ] tri
 208     ] [ bitxor ] reduce-outputs ; inline
 209
 210 : s1-512 ( x -- x' )
 211     [
 212         [ -19 bitroll-64 ]
 213         [ -61 bitroll-64 ]
 214         [ -6 shift ] tri
 215     ] [ bitxor ] reduce-outputs ; inline
 216
 217 : S0-512 ( x -- x' )
 218     [
 219         [ -28 bitroll-64 ]
 220         [ -34 bitroll-64 ]
 221         [ -39 bitroll-64 ] tri
 222     ] [ bitxor ] reduce-outputs ; inline
 223
 224 : S1-512 ( x -- x' )
 225     [
 226         [ -14 bitroll-64 ]
 227         [ -18 bitroll-64 ]
 228         [ -41 bitroll-64 ] tri
 229     ] [ bitxor ] reduce-outputs ; inline
 230
 231 : prepare-M-256 ( n seq -- )
 232     {
 233         [ [ 16 - ] dip nth-unsafe ]
 234         [ [ 15 - ] dip nth-unsafe s0-256 ]
 235         [ [ 7 - ] dip nth-unsafe ]
 236         [ [ 2 - ] dip nth-unsafe s1-256 w+ w+ w+ ]
 237         [ ]
 238     } 2cleave set-nth-unsafe ; inline
 239
 240 : prepare-M-512 ( n seq -- )
 241     {
 242         [ [ 16 - ] dip nth-unsafe ]
 243         [ [ 15 - ] dip nth-unsafe s0-512 ]
 244         [ [ 7 - ] dip nth-unsafe ]
 245         [ [ 2 - ] dip nth-unsafe s1-512 w+ w+ w+ ]
 246         [ ]
 247     } 2cleave set-nth-unsafe ; inline
 248
 249 : ch ( x y z -- x' )
 250     [ bitxor bitand ] keep bitxor ; inline
 251
 252 : maj ( x y z -- x' )
 253     [ [ bitand ] [ bitor ] 2bi ] dip bitand bitor ; inline
 254
 255 : slice3 ( n seq -- a b c )
 256     [ dup 3 + ] dip <slice> first3 ; inline
 257
 258 GENERIC: pad-initial-bytes ( string sha2 -- padded-string )
 259
 260 :: T1-256 ( n M H sha2 -- T1 )
 261     n M nth-unsafe
 262     n sha2 K>> nth-unsafe +
 263     e H slice3 ch w+
 264     e H nth-unsafe S1-256 w+
 265     h H nth-unsafe w+ ; inline
 266
 267 : T2-256 ( H -- T2 )
 268     [ a swap nth-unsafe S0-256 ]
 269     [ a swap slice3 maj w+ ] bi ; inline
 270
 271 :: T1-512 ( n M H sha2 -- T1 )
 272     n M nth-unsafe
 273     n sha2 K>> nth-unsafe +
 274     e H slice3 ch w+
 275     e H nth-unsafe S1-512 w+
 276     h H nth-unsafe w+ ; inline
 277
 278 : T2-512 ( H -- T2 )
 279     [ a swap nth-unsafe S0-512 ]
 280     [ a swap slice3 maj w+ ] bi ; inline
 281
 282 : update-H ( T1 T2 H -- )
 283     h g pick exchange-unsafe
 284     g f pick exchange-unsafe
 285     f e pick exchange-unsafe
 286     pick d pick nth-unsafe w+ e pick set-nth-unsafe
 287     d c pick exchange-unsafe
 288     c b pick exchange-unsafe
 289     b a pick exchange-unsafe
 290     [ w+ a ] dip set-nth-unsafe ; inline
 291
 292 : prepare-message-schedule ( seq sha2 -- w-seq )
 293     [ word-size>> <sliced-groups> [ be> ] map ]
 294     [
 295         block-size>> [ 0 pad-tail 16 ] keep [a,b) over
 296         '[ _ prepare-M-256 ] each
 297     ] bi ; inline
 298
 299 :: process-chunk ( M block-size cloned-H sha2 -- )
 300     block-size [
 301         M cloned-H sha2 T1-256
 302         cloned-H T2-256
 303         cloned-H update-H
 304     ] each-integer
 305     sha2 [ cloned-H [ w+ ] 2map ] change-H drop ; inline
 306
 307 M: sha2-short checksum-block
 308     [ prepare-message-schedule ]
 309     [ [ block-size>> ] [ H>> clone ] [ ] tri process-chunk ] bi ;
 310
 311 : seq>byte-array ( seq n -- string )
 312     '[ _ >be ] map B{ } concat-as ;
 313
 314 : sha1>checksum ( sha2 -- bytes )
 315     H>> 4 seq>byte-array ;
 316
 317 : sha-224>checksum ( sha2 -- bytes )
 318     H>> 7 head 4 seq>byte-array ;
 319
 320 : sha-256>checksum ( sha2 -- bytes )
 321     H>> 4 seq>byte-array ;
 322
 323 : pad-last-short-block ( state -- )
 324     [ bytes>> t ] [ bytes-read>> pad-last-block ] [ ] tri
 325     [ checksum-block ] curry each ;
 326
 327 PRIVATE>
 328
 329 M: sha-224-state get-checksum
 330     clone
 331     [ pad-last-short-block ] [ sha-224>checksum ] bi ;
 332
 333 M: sha-256-state get-checksum
 334     clone
 335     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 336
 337 M: sha-224 checksum-stream ( stream checksum -- byte-array )
 338     drop
 339     [ <sha-224-state> ] dip add-checksum-stream get-checksum ;
 340
 341 M: sha-256 checksum-stream ( stream checksum -- byte-array )
 342     drop
 343     [ <sha-256-state> ] dip add-checksum-stream get-checksum ;
 344
 345 : sha1-W ( t seq -- )
 346     {
 347         [ [ 3 - ] dip nth-unsafe ]
 348         [ [ 8 - ] dip nth-unsafe bitxor ]
 349         [ [ 14 - ] dip nth-unsafe bitxor ]
 350         [ [ 16 - ] dip nth-unsafe bitxor 1 bitroll-32 ]
 351         [ ]
 352     } 2cleave set-nth-unsafe ;
 353
 354 : prepare-sha1-message-schedule ( seq -- w-seq )
 355     4 <sliced-groups> [ be> ] map
 356     80 0 pad-tail 16 80 [a,b) over
 357     '[ _ sha1-W ] each ; inline
 358
 359 : sha1-f ( B C D n -- f_nbcd )
 360     20 /i
 361     {
 362         { 0 [ [ over bitnot ] dip bitand [ bitand ] dip bitor ] }
 363         { 1 [ bitxor bitxor ] }
 364         { 2 [ 2dup bitand [ pick bitand [ bitand ] dip ] dip bitor bitor ] }
 365         { 3 [ bitxor bitxor ] }
 366     } case ;
 367
 368 :: inner-loop ( n H W K -- temp )
 369     a H nth-unsafe :> A
 370     b H nth-unsafe :> B
 371     c H nth-unsafe :> C
 372     d H nth-unsafe :> D
 373     e H nth-unsafe :> E
 374     [
 375         A 5 bitroll-32
 376
 377         B C D n sha1-f
 378
 379         E
 380
 381         n K nth-unsafe
 382
 383         n W nth-unsafe
 384     ] sum-outputs 32 bits ;
 385
 386 :: process-sha1-chunk ( bytes H W K state -- )
 387     80 [
 388         H W K inner-loop
 389         d H nth-unsafe e H set-nth-unsafe
 390         c H nth-unsafe d H set-nth-unsafe
 391         b H nth-unsafe 30 bitroll-32 c H set-nth-unsafe
 392         a H nth-unsafe b H set-nth-unsafe
 393         a H set-nth-unsafe
 394     ] each-integer
 395     state [ H [ w+ ] 2map ] change-H drop ; inline
 396
 397 M:: sha1-state checksum-block ( bytes state -- )
 398     bytes prepare-sha1-message-schedule state W<<
 399
 400     bytes
 401     state [ H>> clone ] [ W>> ] [ K>> ] tri state process-sha1-chunk ;
 402
 403 M: sha1-state get-checksum
 404     clone
 405     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 406
 407 M: sha1 checksum-stream ( stream checksum -- byte-array )
 408     drop
 409     [ <sha1-state> ] dip add-checksum-stream get-checksum ;