basis/checksums/sha/sha.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays checksums checksums.common
   4 checksums.stream combinators combinators.smart fry grouping
   5 io.binary kernel literals locals math math.bitwise math.ranges
   6 sequences sequences.generalizations sequences.private ;
   7 IN: checksums.sha
   8
   9 SINGLETON: sha1
  10 INSTANCE: sha1 stream-checksum
  11
  12 SINGLETON: sha-224
  13 SINGLETON: sha-256
  14
  15 INSTANCE: sha-224 stream-checksum
  16 INSTANCE: sha-256 stream-checksum
  17
  18 TUPLE: sha1-state < checksum-state
  19 { K array }
  20 { H array }
  21 { W array }
  22 { word-size fixnum } ;
  23
  24 CONSTANT: initial-H-sha1
  25     {
  26         0x67452301
  27         0xefcdab89
  28         0x98badcfe
  29         0x10325476
  30         0xc3d2e1f0
  31     }
  32
  33 CONSTANT: K-sha1
  34     $[
  35         20 0x5a827999 <repetition>
  36         20 0x6ed9eba1 <repetition>
  37         20 0x8f1bbcdc <repetition>
  38         20 0xca62c1d6 <repetition>
  39         4 { } nappend-as
  40     ]
  41
  42 TUPLE: sha2-state < checksum-state
  43 { K array }
  44 { H array }
  45 { word-size fixnum } ;
  46
  47 TUPLE: sha2-short < sha2-state ;
  48
  49 TUPLE: sha2-long < sha2-state ;
  50
  51 TUPLE: sha-224-state < sha2-short ;
  52
  53 TUPLE: sha-256-state < sha2-short ;
  54
  55 M: sha2-state clone
  56     call-next-method
  57     [ clone ] change-H
  58     [ clone ] change-K ;
  59
  60 <PRIVATE
  61
  62 CONSTANT: a 0
  63 CONSTANT: b 1
  64 CONSTANT: c 2
  65 CONSTANT: d 3
  66 CONSTANT: e 4
  67 CONSTANT: f 5
  68 CONSTANT: g 6
  69 CONSTANT: h 7
  70
  71 CONSTANT: initial-H-224
  72     {
  73         0xc1059ed8 0x367cd507 0x3070dd17 0xf70e5939
  74         0xffc00b31 0x68581511 0x64f98fa7 0xbefa4fa4
  75     }
  76
  77 CONSTANT: initial-H-256
  78     {
  79         0x6a09e667 0xbb67ae85 0x3c6ef372 0xa54ff53a
  80         0x510e527f 0x9b05688c 0x1f83d9ab 0x5be0cd19
  81     }
  82
  83 CONSTANT: initial-H-384
  84     {
  85         0xcbbb9d5dc1059ed8
  86         0x629a292a367cd507
  87         0x9159015a3070dd17
  88         0x152fecd8f70e5939
  89         0x67332667ffc00b31
  90         0x8eb44a8768581511
  91         0xdb0c2e0d64f98fa7
  92         0x47b5481dbefa4fa4
  93     }
  94
  95 CONSTANT: initial-H-512
  96     {
  97         0x6a09e667f3bcc908
  98         0xbb67ae8584caa73b
  99         0x3c6ef372fe94f82b
 100         0xa54ff53a5f1d36f1
 101         0x510e527fade682d1
 102         0x9b05688c2b3e6c1f
 103         0x1f83d9abfb41bd6b
 104         0x5be0cd19137e2179
 105     }
 106
 107 CONSTANT: K-256
 108     {
 109         0x428a2f98 0x71374491 0xb5c0fbcf 0xe9b5dba5
 110         0x3956c25b 0x59f111f1 0x923f82a4 0xab1c5ed5
 111         0xd807aa98 0x12835b01 0x243185be 0x550c7dc3
 112         0x72be5d74 0x80deb1fe 0x9bdc06a7 0xc19bf174
 113         0xe49b69c1 0xefbe4786 0x0fc19dc6 0x240ca1cc
 114         0x2de92c6f 0x4a7484aa 0x5cb0a9dc 0x76f988da
 115         0x983e5152 0xa831c66d 0xb00327c8 0xbf597fc7
 116         0xc6e00bf3 0xd5a79147 0x06ca6351 0x14292967
 117         0x27b70a85 0x2e1b2138 0x4d2c6dfc 0x53380d13
 118         0x650a7354 0x766a0abb 0x81c2c92e 0x92722c85
 119         0xa2bfe8a1 0xa81a664b 0xc24b8b70 0xc76c51a3
 120         0xd192e819 0xd6990624 0xf40e3585 0x106aa070
 121         0x19a4c116 0x1e376c08 0x2748774c 0x34b0bcb5
 122         0x391c0cb3 0x4ed8aa4a 0x5b9cca4f 0x682e6ff3
 123         0x748f82ee 0x78a5636f 0x84c87814 0x8cc70208
 124         0x90befffa 0xa4506ceb 0xbef9a3f7 0xc67178f2
 125     }
 126
 127 CONSTANT: K-384
 128     {
 129
 130         0x428a2f98d728ae22 0x7137449123ef65cd 0xb5c0fbcfec4d3b2f 0xe9b5dba58189dbbc
 131         0x3956c25bf348b538 0x59f111f1b605d019 0x923f82a4af194f9b 0xab1c5ed5da6d8118
 132         0xd807aa98a3030242 0x12835b0145706fbe 0x243185be4ee4b28c 0x550c7dc3d5ffb4e2
 133         0x72be5d74f27b896f 0x80deb1fe3b1696b1 0x9bdc06a725c71235 0xc19bf174cf692694
 134         0xe49b69c19ef14ad2 0xefbe4786384f25e3 0x0fc19dc68b8cd5b5 0x240ca1cc77ac9c65
 135         0x2de92c6f592b0275 0x4a7484aa6ea6e483 0x5cb0a9dcbd41fbd4 0x76f988da831153b5
 136         0x983e5152ee66dfab 0xa831c66d2db43210 0xb00327c898fb213f 0xbf597fc7beef0ee4
 137         0xc6e00bf33da88fc2 0xd5a79147930aa725 0x06ca6351e003826f 0x142929670a0e6e70
 138         0x27b70a8546d22ffc 0x2e1b21385c26c926 0x4d2c6dfc5ac42aed 0x53380d139d95b3df
 139         0x650a73548baf63de 0x766a0abb3c77b2a8 0x81c2c92e47edaee6 0x92722c851482353b
 140         0xa2bfe8a14cf10364 0xa81a664bbc423001 0xc24b8b70d0f89791 0xc76c51a30654be30
 141         0xd192e819d6ef5218 0xd69906245565a910 0xf40e35855771202a 0x106aa07032bbd1b8
 142         0x19a4c116b8d2d0c8 0x1e376c085141ab53 0x2748774cdf8eeb99 0x34b0bcb5e19b48a8
 143         0x391c0cb3c5c95a63 0x4ed8aa4ae3418acb 0x5b9cca4f7763e373 0x682e6ff3d6b2b8a3
 144         0x748f82ee5defb2fc 0x78a5636f43172f60 0x84c87814a1f0ab72 0x8cc702081a6439ec
 145         0x90befffa23631e28 0xa4506cebde82bde9 0xbef9a3f7b2c67915 0xc67178f2e372532b
 146         0xca273eceea26619c 0xd186b8c721c0c207 0xeada7dd6cde0eb1e 0xf57d4f7fee6ed178
 147         0x06f067aa72176fba 0x0a637dc5a2c898a6 0x113f9804bef90dae 0x1b710b35131c471b
 148         0x28db77f523047d84 0x32caab7b40c72493 0x3c9ebe0a15c9bebc 0x431d67c49c100d4c
 149         0x4cc5d4becb3e42b6 0x597f299cfc657e2a 0x5fcb6fab3ad6faec 0x6c44198c4a475817
 150     }
 151
 152 ALIAS: K-512 K-384
 153
 154 : <sha1-state> ( -- sha1-state )
 155     sha1-state new-checksum-state
 156         64 >>block-size
 157         K-sha1 >>K
 158         initial-H-sha1 >>H
 159         4 >>word-size ;
 160
 161 : <sha-224-state> ( -- sha2-state )
 162     sha-224-state new-checksum-state
 163         64 >>block-size
 164         K-256 >>K
 165         initial-H-224 >>H
 166         4 >>word-size ;
 167
 168 : <sha-256-state> ( -- sha2-state )
 169     sha-256-state new-checksum-state
 170         64 >>block-size
 171         K-256 >>K
 172         initial-H-256 >>H
 173         4 >>word-size ;
 174
 175 M: sha1 initialize-checksum-state drop <sha1-state> ;
 176
 177 M: sha-224 initialize-checksum-state drop <sha-224-state> ;
 178
 179 M: sha-256 initialize-checksum-state drop <sha-256-state> ;
 180
 181 : s0-256 ( x -- x' )
 182     [
 183         [ -7 bitroll-32 ]
 184         [ -18 bitroll-32 ]
 185         [ -3 shift ] tri
 186     ] [ bitxor ] reduce-outputs ; inline
 187
 188 : s1-256 ( x -- x' )
 189     [
 190         [ -17 bitroll-32 ]
 191         [ -19 bitroll-32 ]
 192         [ -10 shift ] tri
 193     ] [ bitxor ] reduce-outputs ; inline
 194
 195 : S0-256 ( x -- x' )
 196     [
 197         [ -2 bitroll-32 ]
 198         [ -13 bitroll-32 ]
 199         [ -22 bitroll-32 ] tri
 200     ] [ bitxor ] reduce-outputs ; inline
 201
 202 : S1-256 ( x -- x' )
 203     [
 204         [ -6 bitroll-32 ]
 205         [ -11 bitroll-32 ]
 206         [ -25 bitroll-32 ] tri
 207     ] [ bitxor ] reduce-outputs ; inline
 208
 209 : s0-512 ( x -- x' )
 210     [
 211         [ -1 bitroll-64 ]
 212         [ -8 bitroll-64 ]
 213         [ -7 shift ] tri
 214     ] [ bitxor ] reduce-outputs ; inline
 215
 216 : s1-512 ( x -- x' )
 217     [
 218         [ -19 bitroll-64 ]
 219         [ -61 bitroll-64 ]
 220         [ -6 shift ] tri
 221     ] [ bitxor ] reduce-outputs ; inline
 222
 223 : S0-512 ( x -- x' )
 224     [
 225         [ -28 bitroll-64 ]
 226         [ -34 bitroll-64 ]
 227         [ -39 bitroll-64 ] tri
 228     ] [ bitxor ] reduce-outputs ; inline
 229
 230 : S1-512 ( x -- x' )
 231     [
 232         [ -14 bitroll-64 ]
 233         [ -18 bitroll-64 ]
 234         [ -41 bitroll-64 ] tri
 235     ] [ bitxor ] reduce-outputs ; inline
 236
 237 : prepare-M-256 ( n seq -- )
 238     {
 239         [ [ 16 - ] dip nth-unsafe ]
 240         [ [ 15 - ] dip nth-unsafe s0-256 ]
 241         [ [ 7 - ] dip nth-unsafe ]
 242         [ [ 2 - ] dip nth-unsafe s1-256 w+ w+ w+ ]
 243         [ ]
 244     } 2cleave set-nth-unsafe ; inline
 245
 246 : prepare-M-512 ( n seq -- )
 247     {
 248         [ [ 16 - ] dip nth-unsafe ]
 249         [ [ 15 - ] dip nth-unsafe s0-512 ]
 250         [ [ 7 - ] dip nth-unsafe ]
 251         [ [ 2 - ] dip nth-unsafe s1-512 w+ w+ w+ ]
 252         [ ]
 253     } 2cleave set-nth-unsafe ; inline
 254
 255 : ch ( x y z -- x' )
 256     [ bitxor bitand ] keep bitxor ; inline
 257
 258 : maj ( x y z -- x' )
 259     [ [ bitand ] [ bitor ] 2bi ] dip bitand bitor ; inline
 260
 261 : slice3 ( n seq -- a b c )
 262     [ dup 3 + ] dip <slice> first3 ; inline
 263
 264 GENERIC: pad-initial-bytes ( string sha2 -- padded-string )
 265
 266 :: T1-256 ( n M H sha2 -- T1 )
 267     n M nth-unsafe
 268     n sha2 K>> nth-unsafe +
 269     e H slice3 ch w+
 270     e H nth-unsafe S1-256 w+
 271     h H nth-unsafe w+ ; inline
 272
 273 : T2-256 ( H -- T2 )
 274     [ a swap nth-unsafe S0-256 ]
 275     [ a swap slice3 maj w+ ] bi ; inline
 276
 277 :: T1-512 ( n M H sha2 -- T1 )
 278     n M nth-unsafe
 279     n sha2 K>> nth-unsafe +
 280     e H slice3 ch w+
 281     e H nth-unsafe S1-512 w+
 282     h H nth-unsafe w+ ; inline
 283
 284 : T2-512 ( H -- T2 )
 285     [ a swap nth-unsafe S0-512 ]
 286     [ a swap slice3 maj w+ ] bi ; inline
 287
 288 : update-H ( T1 T2 H -- )
 289     h g pick exchange-unsafe
 290     g f pick exchange-unsafe
 291     f e pick exchange-unsafe
 292     pick d pick nth-unsafe w+ e pick set-nth-unsafe
 293     d c pick exchange-unsafe
 294     c b pick exchange-unsafe
 295     b a pick exchange-unsafe
 296     [ w+ a ] dip set-nth-unsafe ; inline
 297
 298 : prepare-message-schedule ( seq sha2 -- w-seq )
 299     [ word-size>> <groups> [ be> ] map ]
 300     [
 301         block-size>> [ 0 pad-tail 16 ] keep [a,b) over
 302         '[ _ prepare-M-256 ] each
 303     ] bi ; inline
 304
 305 :: process-chunk ( M block-size cloned-H sha2 -- )
 306     block-size [
 307         M cloned-H sha2 T1-256
 308         cloned-H T2-256
 309         cloned-H update-H
 310     ] each-integer
 311     sha2 [ cloned-H [ w+ ] 2map ] change-H drop ; inline
 312
 313 M: sha2-short checksum-block
 314     [ prepare-message-schedule ]
 315     [ [ block-size>> ] [ H>> clone ] [ ] tri process-chunk ] bi ;
 316
 317 : sequence>byte-array ( seq n -- bytes )
 318     '[ _ >be ] map B{ } concat-as ; inline
 319
 320 : sha1>checksum ( sha2 -- bytes )
 321     H>> 4 sequence>byte-array ; inline
 322
 323 : sha-224>checksum ( sha2 -- bytes )
 324     H>> 7 head 4 sequence>byte-array ; inline
 325
 326 : sha-256>checksum ( sha2 -- bytes )
 327     H>> 4 sequence>byte-array ; inline
 328
 329 : pad-last-short-block ( state -- )
 330     [ bytes>> t ] [ bytes-read>> pad-last-block ] [ ] tri
 331     [ checksum-block ] curry each ; inline
 332
 333 PRIVATE>
 334
 335 M: sha-224-state get-checksum
 336     clone
 337     [ pad-last-short-block ] [ sha-224>checksum ] bi ;
 338
 339 M: sha-256-state get-checksum
 340     clone
 341     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 342
 343 M: sha-224 checksum-stream ( stream checksum -- byte-array )
 344     drop
 345     [ <sha-224-state> ] dip add-checksum-stream get-checksum ;
 346
 347 M: sha-256 checksum-stream ( stream checksum -- byte-array )
 348     drop
 349     [ <sha-256-state> ] dip add-checksum-stream get-checksum ;
 350
 351 : sha1-W ( t seq -- )
 352     {
 353         [ [ 3 - ] dip nth-unsafe ]
 354         [ [ 8 - ] dip nth-unsafe bitxor ]
 355         [ [ 14 - ] dip nth-unsafe bitxor ]
 356         [ [ 16 - ] dip nth-unsafe bitxor 1 bitroll-32 ]
 357         [ ]
 358     } 2cleave set-nth-unsafe ; inline
 359
 360 : prepare-sha1-message-schedule ( seq -- w-seq )
 361     4 <groups> [ be> ] map
 362     80 0 pad-tail 16 80 [a,b) over
 363     '[ _ sha1-W ] each ; inline
 364
 365 : sha1-f ( B C D n -- f_nbcd )
 366     20 /i
 367     {
 368         { 0 [ [ over bitnot ] dip bitand [ bitand ] dip bitor ] }
 369         { 1 [ bitxor bitxor ] }
 370         { 2 [ 2dup bitand [ pick bitand [ bitand ] dip ] dip bitor bitor ] }
 371         { 3 [ bitxor bitxor ] }
 372     } case ; inline
 373
 374 :: inner-loop ( n H W K -- temp )
 375     a H nth-unsafe :> A
 376     b H nth-unsafe :> B
 377     c H nth-unsafe :> C
 378     d H nth-unsafe :> D
 379     e H nth-unsafe :> E
 380     [
 381         A 5 bitroll-32
 382
 383         B C D n sha1-f
 384
 385         E
 386
 387         n K nth-unsafe
 388
 389         n W nth-unsafe
 390     ] sum-outputs 32 bits ; inline
 391
 392 :: process-sha1-chunk ( H W K state -- )
 393     80 [
 394         H W K inner-loop
 395         d H nth-unsafe e H set-nth-unsafe
 396         c H nth-unsafe d H set-nth-unsafe
 397         b H nth-unsafe 30 bitroll-32 c H set-nth-unsafe
 398         a H nth-unsafe b H set-nth-unsafe
 399         a H set-nth-unsafe
 400     ] each-integer
 401     state [ H [ w+ ] 2map ] change-H drop ; inline
 402
 403 M:: sha1-state checksum-block ( bytes state -- )
 404     bytes prepare-sha1-message-schedule state W<<
 405
 406     state [ H>> clone ] [ W>> ] [ K>> ] tri state process-sha1-chunk ;
 407
 408 M: sha1-state get-checksum
 409     clone
 410     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 411
 412 M: sha1 checksum-stream ( stream checksum -- byte-array )
 413     drop
 414     [ <sha1-state> ] dip add-checksum-stream get-checksum ;