basis/checksums/sha/sha.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays checksums checksums.common combinators
   4 combinators.smart fry grouping io.binary kernel kernel.private
   5 literals locals math math.bitwise math.ranges sequences
   6 sequences.generalizations sequences.private ;
   7 IN: checksums.sha
   8
   9 MIXIN: sha
  10 INSTANCE: sha checksum
  11
  12 SINGLETON: sha1
  13 INSTANCE: sha1 sha
  14
  15 SINGLETON: sha-224
  16 SINGLETON: sha-256
  17
  18 INSTANCE: sha-224 sha
  19 INSTANCE: sha-256 sha
  20
  21 <PRIVATE
  22
  23 TUPLE: sha1-state < checksum-state
  24 { K array }
  25 { H array }
  26 { W array }
  27 { word-size fixnum } ;
  28
  29 CONSTANT: initial-H-sha1
  30     {
  31         0x67452301
  32         0xefcdab89
  33         0x98badcfe
  34         0x10325476
  35         0xc3d2e1f0
  36     }
  37
  38 CONSTANT: K-sha1
  39     $[
  40         20 0x5a827999 <repetition>
  41         20 0x6ed9eba1 <repetition>
  42         20 0x8f1bbcdc <repetition>
  43         20 0xca62c1d6 <repetition>
  44         4 { } nappend-as
  45     ]
  46
  47 TUPLE: sha2-state < checksum-state
  48 { K array }
  49 { H array }
  50 { word-size fixnum } ;
  51
  52 TUPLE: sha2-short < sha2-state ;
  53
  54 TUPLE: sha2-long < sha2-state ;
  55
  56 TUPLE: sha-224-state < sha2-short ;
  57
  58 TUPLE: sha-256-state < sha2-short ;
  59
  60 M: sha2-state clone
  61     call-next-method
  62     [ clone ] change-H
  63     [ clone ] change-K ;
  64
  65 CONSTANT: a 0
  66 CONSTANT: b 1
  67 CONSTANT: c 2
  68 CONSTANT: d 3
  69 CONSTANT: e 4
  70 CONSTANT: f 5
  71 CONSTANT: g 6
  72 CONSTANT: h 7
  73
  74 CONSTANT: initial-H-224
  75     {
  76         0xc1059ed8 0x367cd507 0x3070dd17 0xf70e5939
  77         0xffc00b31 0x68581511 0x64f98fa7 0xbefa4fa4
  78     }
  79
  80 CONSTANT: initial-H-256
  81     {
  82         0x6a09e667 0xbb67ae85 0x3c6ef372 0xa54ff53a
  83         0x510e527f 0x9b05688c 0x1f83d9ab 0x5be0cd19
  84     }
  85
  86 CONSTANT: initial-H-384
  87     {
  88         0xcbbb9d5dc1059ed8
  89         0x629a292a367cd507
  90         0x9159015a3070dd17
  91         0x152fecd8f70e5939
  92         0x67332667ffc00b31
  93         0x8eb44a8768581511
  94         0xdb0c2e0d64f98fa7
  95         0x47b5481dbefa4fa4
  96     }
  97
  98 CONSTANT: initial-H-512
  99     {
 100         0x6a09e667f3bcc908
 101         0xbb67ae8584caa73b
 102         0x3c6ef372fe94f82b
 103         0xa54ff53a5f1d36f1
 104         0x510e527fade682d1
 105         0x9b05688c2b3e6c1f
 106         0x1f83d9abfb41bd6b
 107         0x5be0cd19137e2179
 108     }
 109
 110 CONSTANT: K-256
 111     {
 112         0x428a2f98 0x71374491 0xb5c0fbcf 0xe9b5dba5
 113         0x3956c25b 0x59f111f1 0x923f82a4 0xab1c5ed5
 114         0xd807aa98 0x12835b01 0x243185be 0x550c7dc3
 115         0x72be5d74 0x80deb1fe 0x9bdc06a7 0xc19bf174
 116         0xe49b69c1 0xefbe4786 0x0fc19dc6 0x240ca1cc
 117         0x2de92c6f 0x4a7484aa 0x5cb0a9dc 0x76f988da
 118         0x983e5152 0xa831c66d 0xb00327c8 0xbf597fc7
 119         0xc6e00bf3 0xd5a79147 0x06ca6351 0x14292967
 120         0x27b70a85 0x2e1b2138 0x4d2c6dfc 0x53380d13
 121         0x650a7354 0x766a0abb 0x81c2c92e 0x92722c85
 122         0xa2bfe8a1 0xa81a664b 0xc24b8b70 0xc76c51a3
 123         0xd192e819 0xd6990624 0xf40e3585 0x106aa070
 124         0x19a4c116 0x1e376c08 0x2748774c 0x34b0bcb5
 125         0x391c0cb3 0x4ed8aa4a 0x5b9cca4f 0x682e6ff3
 126         0x748f82ee 0x78a5636f 0x84c87814 0x8cc70208
 127         0x90befffa 0xa4506ceb 0xbef9a3f7 0xc67178f2
 128     }
 129
 130 CONSTANT: K-384
 131     {
 132
 133         0x428a2f98d728ae22 0x7137449123ef65cd 0xb5c0fbcfec4d3b2f 0xe9b5dba58189dbbc
 134         0x3956c25bf348b538 0x59f111f1b605d019 0x923f82a4af194f9b 0xab1c5ed5da6d8118
 135         0xd807aa98a3030242 0x12835b0145706fbe 0x243185be4ee4b28c 0x550c7dc3d5ffb4e2
 136         0x72be5d74f27b896f 0x80deb1fe3b1696b1 0x9bdc06a725c71235 0xc19bf174cf692694
 137         0xe49b69c19ef14ad2 0xefbe4786384f25e3 0x0fc19dc68b8cd5b5 0x240ca1cc77ac9c65
 138         0x2de92c6f592b0275 0x4a7484aa6ea6e483 0x5cb0a9dcbd41fbd4 0x76f988da831153b5
 139         0x983e5152ee66dfab 0xa831c66d2db43210 0xb00327c898fb213f 0xbf597fc7beef0ee4
 140         0xc6e00bf33da88fc2 0xd5a79147930aa725 0x06ca6351e003826f 0x142929670a0e6e70
 141         0x27b70a8546d22ffc 0x2e1b21385c26c926 0x4d2c6dfc5ac42aed 0x53380d139d95b3df
 142         0x650a73548baf63de 0x766a0abb3c77b2a8 0x81c2c92e47edaee6 0x92722c851482353b
 143         0xa2bfe8a14cf10364 0xa81a664bbc423001 0xc24b8b70d0f89791 0xc76c51a30654be30
 144         0xd192e819d6ef5218 0xd69906245565a910 0xf40e35855771202a 0x106aa07032bbd1b8
 145         0x19a4c116b8d2d0c8 0x1e376c085141ab53 0x2748774cdf8eeb99 0x34b0bcb5e19b48a8
 146         0x391c0cb3c5c95a63 0x4ed8aa4ae3418acb 0x5b9cca4f7763e373 0x682e6ff3d6b2b8a3
 147         0x748f82ee5defb2fc 0x78a5636f43172f60 0x84c87814a1f0ab72 0x8cc702081a6439ec
 148         0x90befffa23631e28 0xa4506cebde82bde9 0xbef9a3f7b2c67915 0xc67178f2e372532b
 149         0xca273eceea26619c 0xd186b8c721c0c207 0xeada7dd6cde0eb1e 0xf57d4f7fee6ed178
 150         0x06f067aa72176fba 0x0a637dc5a2c898a6 0x113f9804bef90dae 0x1b710b35131c471b
 151         0x28db77f523047d84 0x32caab7b40c72493 0x3c9ebe0a15c9bebc 0x431d67c49c100d4c
 152         0x4cc5d4becb3e42b6 0x597f299cfc657e2a 0x5fcb6fab3ad6faec 0x6c44198c4a475817
 153     }
 154
 155 ALIAS: K-512 K-384
 156
 157 : <sha1-state> ( -- sha1-state )
 158     sha1-state new-checksum-state
 159         64 >>block-size
 160         K-sha1 >>K
 161         initial-H-sha1 >>H
 162         4 >>word-size ;
 163
 164 : <sha-224-state> ( -- sha2-state )
 165     sha-224-state new-checksum-state
 166         64 >>block-size
 167         K-256 >>K
 168         initial-H-224 >>H
 169         4 >>word-size ;
 170
 171 : <sha-256-state> ( -- sha2-state )
 172     sha-256-state new-checksum-state
 173         64 >>block-size
 174         K-256 >>K
 175         initial-H-256 >>H
 176         4 >>word-size ;
 177
 178 M: sha1 initialize-checksum-state drop <sha1-state> ;
 179
 180 M: sha-224 initialize-checksum-state drop <sha-224-state> ;
 181
 182 M: sha-256 initialize-checksum-state drop <sha-256-state> ;
 183
 184 : s0-256 ( x -- x' )
 185     [
 186         [ -7 bitroll-32 ]
 187         [ -18 bitroll-32 ]
 188         [ -3 shift ] tri
 189     ] [ bitxor ] reduce-outputs ; inline
 190
 191 : s1-256 ( x -- x' )
 192     [
 193         [ -17 bitroll-32 ]
 194         [ -19 bitroll-32 ]
 195         [ -10 shift ] tri
 196     ] [ bitxor ] reduce-outputs ; inline
 197
 198 : S0-256 ( x -- x' )
 199     [
 200         [ -2 bitroll-32 ]
 201         [ -13 bitroll-32 ]
 202         [ -22 bitroll-32 ] tri
 203     ] [ bitxor ] reduce-outputs ; inline
 204
 205 : S1-256 ( x -- x' )
 206     [
 207         [ -6 bitroll-32 ]
 208         [ -11 bitroll-32 ]
 209         [ -25 bitroll-32 ] tri
 210     ] [ bitxor ] reduce-outputs ; inline
 211
 212 : s0-512 ( x -- x' )
 213     [
 214         [ -1 bitroll-64 ]
 215         [ -8 bitroll-64 ]
 216         [ -7 shift ] tri
 217     ] [ bitxor ] reduce-outputs ; inline
 218
 219 : s1-512 ( x -- x' )
 220     [
 221         [ -19 bitroll-64 ]
 222         [ -61 bitroll-64 ]
 223         [ -6 shift ] tri
 224     ] [ bitxor ] reduce-outputs ; inline
 225
 226 : S0-512 ( x -- x' )
 227     [
 228         [ -28 bitroll-64 ]
 229         [ -34 bitroll-64 ]
 230         [ -39 bitroll-64 ] tri
 231     ] [ bitxor ] reduce-outputs ; inline
 232
 233 : S1-512 ( x -- x' )
 234     [
 235         [ -14 bitroll-64 ]
 236         [ -18 bitroll-64 ]
 237         [ -41 bitroll-64 ] tri
 238     ] [ bitxor ] reduce-outputs ; inline
 239
 240 : prepare-M-256 ( n seq -- )
 241     { array } declare
 242     {
 243         [ [ 16 - ] dip nth-unsafe ]
 244         [ [ 15 - ] dip nth-unsafe s0-256 ]
 245         [ [ 7 - ] dip nth-unsafe ]
 246         [ [ 2 - ] dip nth-unsafe s1-256 w+ w+ w+ ]
 247         [ ]
 248     } 2cleave set-nth-unsafe ; inline
 249
 250 : prepare-M-512 ( n seq -- )
 251     { array } declare
 252     {
 253         [ [ 16 - ] dip nth-unsafe ]
 254         [ [ 15 - ] dip nth-unsafe s0-512 ]
 255         [ [ 7 - ] dip nth-unsafe ]
 256         [ [ 2 - ] dip nth-unsafe s1-512 w+ w+ w+ ]
 257         [ ]
 258     } 2cleave set-nth-unsafe ; inline
 259
 260 : ch ( x y z -- x' )
 261     [ bitxor bitand ] keep bitxor ; inline
 262
 263 : maj ( x y z -- x' )
 264     [ [ bitand ] [ bitor ] 2bi ] dip bitand bitor ; inline
 265
 266 : slice3 ( n seq -- a b c )
 267     [ dup 3 + ] dip <slice> first3 ; inline
 268
 269 GENERIC: pad-initial-bytes ( string sha2 -- padded-string )
 270
 271 :: T1-256 ( n M H sha2 -- T1 )
 272     n M nth-unsafe
 273     n sha2 K>> nth-unsafe +
 274     e H slice3 ch w+
 275     e H nth-unsafe S1-256 w+
 276     h H nth-unsafe w+ ; inline
 277
 278 :: T2-256 ( H -- T2 )
 279     a H nth-unsafe S0-256
 280     a H slice3 maj w+ ; inline
 281
 282 :: T1-512 ( n M H sha2 -- T1 )
 283     n M nth-unsafe
 284     n sha2 K>> nth-unsafe +
 285     e H slice3 ch w+
 286     e H nth-unsafe S1-512 w+
 287     h H nth-unsafe w+ ; inline
 288
 289 :: T2-512 ( H -- T2 )
 290     a H nth-unsafe S0-512
 291     a H slice3 maj w+ ; inline
 292
 293 :: update-H ( T1 T2 H -- )
 294     h g H exchange-unsafe
 295     g f H exchange-unsafe
 296     f e H exchange-unsafe
 297     T1 d H nth-unsafe w+ e H set-nth-unsafe
 298     d c H exchange-unsafe
 299     c b H exchange-unsafe
 300     b a H exchange-unsafe
 301     T1 T2 w+ a H set-nth-unsafe ; inline
 302
 303 : prepare-message-schedule ( seq sha2 -- w-seq )
 304     [ word-size>> <groups> [ be> ] map ]
 305     [
 306         block-size>> [ 0 pad-tail 16 ] keep [a,b) over
 307         '[ _ prepare-M-256 ] each
 308     ] bi ; inline
 309
 310 :: process-chunk ( M block-size cloned-H sha2 -- )
 311     block-size [
 312         M cloned-H sha2 T1-256
 313         cloned-H T2-256
 314         cloned-H update-H
 315     ] each-integer
 316     sha2 [ cloned-H [ w+ ] 2map ] change-H drop ; inline
 317
 318 M: sha2-short checksum-block
 319     [ prepare-message-schedule ]
 320     [ [ block-size>> ] [ H>> clone ] [ ] tri process-chunk ] bi ;
 321
 322 : sequence>byte-array ( seq n -- bytes )
 323     '[ _ >be ] map B{ } concat-as ; inline
 324
 325 : sha1>checksum ( sha2 -- bytes )
 326     H>> 4 sequence>byte-array ; inline
 327
 328 : sha-224>checksum ( sha2 -- bytes )
 329     H>> 7 head 4 sequence>byte-array ; inline
 330
 331 : sha-256>checksum ( sha2 -- bytes )
 332     H>> 4 sequence>byte-array ; inline
 333
 334 : pad-last-short-block ( state -- )
 335     [ bytes>> t ] [ bytes-read>> pad-last-block ] [ ] tri
 336     [ checksum-block ] curry each ; inline
 337
 338 M: sha-224-state get-checksum
 339     clone
 340     [ pad-last-short-block ] [ sha-224>checksum ] bi ;
 341
 342 M: sha-256-state get-checksum
 343     clone
 344     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 345
 346 : sha1-W ( t seq -- )
 347     { array } declare
 348     {
 349         [ [ 3 - ] dip nth-unsafe ]
 350         [ [ 8 - ] dip nth-unsafe bitxor ]
 351         [ [ 14 - ] dip nth-unsafe bitxor ]
 352         [ [ 16 - ] dip nth-unsafe bitxor 1 bitroll-32 ]
 353         [ ]
 354     } 2cleave set-nth-unsafe ; inline
 355
 356 : prepare-sha1-message-schedule ( seq -- w-seq )
 357     4 <groups> [ be> ] map
 358     80 0 pad-tail 16 80 [a,b) over
 359     '[ _ sha1-W ] each ; inline
 360
 361 : sha1-f ( B C D n -- f_nbcd )
 362     20 /i
 363     {
 364         { 0 [ [ over bitnot ] dip bitand [ bitand ] dip bitor ] }
 365         { 1 [ bitxor bitxor ] }
 366         { 2 [ 2dup bitand [ pick bitand [ bitand ] dip ] dip bitor bitor ] }
 367         { 3 [ bitxor bitxor ] }
 368     } case ; inline
 369
 370 :: inner-loop ( n H W K -- temp )
 371     a H nth-unsafe :> A
 372     b H nth-unsafe :> B
 373     c H nth-unsafe :> C
 374     d H nth-unsafe :> D
 375     e H nth-unsafe :> E
 376     [
 377         A 5 bitroll-32
 378
 379         B C D n sha1-f
 380
 381         E
 382
 383         n K nth-unsafe
 384
 385         n W nth-unsafe
 386     ] sum-outputs 32 bits ; inline
 387
 388 :: process-sha1-chunk ( H W K state -- )
 389     80 [
 390         H W K inner-loop
 391         d H nth-unsafe e H set-nth-unsafe
 392         c H nth-unsafe d H set-nth-unsafe
 393         b H nth-unsafe 30 bitroll-32 c H set-nth-unsafe
 394         a H nth-unsafe b H set-nth-unsafe
 395         a H set-nth-unsafe
 396     ] each-integer
 397     state [ H [ w+ ] 2map ] change-H drop ; inline
 398
 399 M:: sha1-state checksum-block ( bytes state -- )
 400     bytes prepare-sha1-message-schedule state W<<
 401
 402     state [ H>> clone ] [ W>> ] [ K>> ] tri state process-sha1-chunk ;
 403
 404 M: sha1-state get-checksum
 405     clone
 406     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 407
 408 M: sha checksum-stream
 409     initialize-checksum-state swap add-checksum-stream
 410     get-checksum ;
 411
 412 M: sha checksum-bytes
 413     initialize-checksum-state swap add-checksum-bytes
 414     get-checksum ;
 415
 416 PRIVATE>