basis/classes/struct/struct-docs.factor

   1 ! (c)Joe Groff bsd license
   2 USING: alien classes help.markup help.syntax kernel libc
   3 quotations slots ;
   4 IN: classes.struct
   5
   6 HELP: <struct-boa>
   7 { $values
   8     { "class" class }
   9 }
  10 { $description "This macro implements " { $link boa } " for " { $link struct } " classes. A struct of the given class is constructed, and its slots are initialized using values off the top of the datastack." } ;
  11
  12 HELP: (struct)
  13 { $values
  14     { "class" class }
  15     { "struct" struct }
  16 }
  17 { $description "Allocates garbage-collected heap memory for a new " { $link struct } " of the specified " { $snippet "class" } ". The new struct's slots are left uninitialized; in most cases, the " { $link <struct> } " word, which initializes the struct's slots with their initial values, should be used instead." } ;
  18
  19 { (struct) (malloc-struct) } related-words
  20
  21 HELP: <struct>
  22 { $values
  23     { "class" class }
  24     { "struct" struct }
  25 }
  26 { $description "Allocates garbage-collected heap memory for a new " { $link struct } " of the specified " { $snippet "class" } ". The new struct's slots are initialized with the initial values specified in the struct definition." } ;
  27
  28 { <struct> <struct-boa> malloc-struct memory>struct } related-words
  29
  30 HELP: STRUCT:
  31 { $syntax "STRUCT: class { slot type } { slot type } ... ;" }
  32 { $values { "class" "a new " { $link struct } " class to define" } { "slots" "a list of slot specifiers" } }
  33 { $description "Defines a new " { $link struct } " type. The syntax is nearly identical to " { $link POSTPONE: TUPLE: } "; however, there are some additional restrictions on struct types:"
  34 { $list
  35 { "Struct classes cannot have a superclass defined." }
  36 { "The slots of a struct must all have a type declared. The type must be a C type." }
  37 { { $link read-only } " slots on structs are not enforced, though they may be declared." }
  38 }
  39 "Additionally, structs may use bit fields. A slot specifier may use the syntax " { $snippet "bits: n" } " to specify that the bit width of the slot is " { $snippet "n" } ". Bit width may be specified on signed or unsigned integer slots. The layout of bit fields is not guaranteed to match that of any particular C compiler." } ;
  40
  41 HELP: S{
  42 { $syntax "S{ class slots... }" }
  43 { $values { "class" "a " { $link struct } " class word" } { "slots" "slot values" } }
  44 { $description "Marks the beginning of a literal struct. The syntax is identical to tuple literal syntax with " { $link POSTPONE: T{ } { $snippet " }" } "; either the assoc syntax (that is, " { $snippet "S{ class { slot value } { slot value } ... }" } ") or the simple syntax (" { $snippet "S{ class f value value ... }" } ") can be used." } ;
  45
  46 HELP: S@
  47 { $syntax "S@ class alien" }
  48 { $values { "class" "a " { $link struct } " class word" } { "alien" "a literal alien" } }
  49 { $description "Marks the beginning of a literal struct at a specific C address. The prettyprinter uses this syntax when the memory backing a struct object is invalid. This syntax should not generally be used in source code." } ;
  50
  51 { POSTPONE: S{ POSTPONE: S@ } related-words
  52
  53 HELP: UNION-STRUCT:
  54 { $syntax "UNION-STRUCT: class { slot type } { slot type } ... ;" }
  55 { $values { "class" "a new " { $link struct } " class to define" } { "slots" "a list of slot specifiers" } }
  56 { $description "Defines a new " { $link struct } " type where all of the slots share the same storage. See " { $link POSTPONE: STRUCT: } " for details on the syntax." } ;
  57
  58 HELP: PACKED-STRUCT:
  59 { $syntax "PACKED-STRUCT: class { slot type } { slot type } ... ;" }
  60 { $values { "class" "a new " { $link struct } " class to define" } { "slots" "a list of slot specifiers" } }
  61 { $description "Defines a new " { $link struct } " type with no alignment padding between slots or at the end. In all other respects, behaves like " { $link POSTPONE: STRUCT: } "." } ;
  62
  63 HELP: define-struct-class
  64 { $values
  65     { "class" class } { "slots" "a sequence of " { $link struct-slot-spec } "s" }
  66 }
  67 { $description "Defines a new " { $link struct } " class. This is the runtime equivalent of the " { $link POSTPONE: STRUCT: } " syntax." } ;
  68
  69 HELP: define-packed-struct-class
  70 { $values
  71     { "class" class } { "slots" "a sequence of " { $link struct-slot-spec } "s" }
  72 }
  73 { $description "Defines a new " { $link struct } " class. This is the runtime equivalent of the " { $link POSTPONE: PACKED-STRUCT: } " syntax." } ;
  74
  75 HELP: define-union-struct-class
  76 { $values
  77     { "class" class } { "slots" "a sequence of " { $link struct-slot-spec } "s" }
  78 }
  79 { $description "Defines a new " { $link struct } " class where all of the slots share the same storage. This is the runtime equivalent of the " { $link POSTPONE: UNION-STRUCT: } " syntax." } ;
  80
  81 HELP: malloc-struct
  82 { $values
  83     { "class" class }
  84     { "struct" struct }
  85 }
  86 { $description "Allocates unmanaged C heap memory for a new " { $link struct } " of the specified " { $snippet "class" } ". The new struct's slots are initialized to their initial values. The struct should be " { $link free } "d when it is no longer needed." } ;
  87
  88 HELP: (malloc-struct)
  89 { $values
  90     { "class" class }
  91     { "struct" struct }
  92 }
  93 { $description "Allocates unmanaged C heap memory for a new " { $link struct } " of the specified " { $snippet "class" } ". The new struct's slots are left uninitialized; to initialize the allocated memory with the slots' initial values, use " { $link malloc-struct } ". The struct should be " { $link free } "d when it is no longer needed." } ;
  94
  95 HELP: memory>struct
  96 { $values
  97     { "ptr" c-ptr } { "class" class }
  98     { "struct" struct }
  99 }
 100 { $description "Constructs a new " { $link struct } " of the specified " { $snippet "class" } " at the memory location referenced by " { $snippet "ptr" } ". The referenced memory is unchanged." } ;
 101
 102 HELP: struct
 103 { $class-description "The parent class of all struct types." } ;
 104
 105 { struct POSTPONE: STRUCT: POSTPONE: UNION-STRUCT: } related-words
 106
 107 HELP: struct-class
 108 { $class-description "The metaclass of all " { $link struct } " classes." } ;
 109
 110 ARTICLE: "classes.struct.examples" "Struct class examples"
 111 "A struct with a variety of fields:"
 112 { $code
 113     "USING: alien.c-types classes.struct ;"
 114     ""
 115     "STRUCT: test-struct"
 116     "    { i int }"
 117     "    { chicken char[16] }"
 118     "    { data void* } ;"
 119 }
 120 "Creating a new instance of this struct, and printing out:"
 121 { $code "test-struct <struct> ." }
 122 "Creating a new instance with slots initialized from the stack:"
 123 { $code
 124     "USING: libc specialized-arrays ;"
 125     "SPECIALIZED-ARRAY: char"
 126     ""
 127     "42"
 128     "\"Hello, chicken.\" >char-array"
 129     "1024 malloc"
 130     "test-struct <struct-boa> ."
 131 } ;
 132
 133 ARTICLE: "classes.struct.define" "Defining struct classes"
 134 "Struct classes are defined using a syntax similar to the " { $link POSTPONE: TUPLE: } " syntax for defining tuple classes:"
 135 { $subsections POSTPONE: STRUCT: POSTPONE: PACKED-STRUCT: }
 136 "Union structs are also supported, which behave like structs but share the same memory for all the slots."
 137 { $subsections POSTPONE: UNION-STRUCT: } ;
 138
 139 ARTICLE: "classes.struct.create" "Creating instances of structs"
 140 "Structs can be allocated with " { $link new } "- and " { $link boa } "-like constructor words. Additional words are provided for building structs from C memory and from existing buffers:"
 141 { $subsections
 142     <struct>
 143     <struct-boa>
 144     malloc-struct
 145     memory>struct
 146 }
 147 "When the contents of a struct will be immediately reset, faster primitive words are available that will create a struct without initializing its contents:"
 148 { $subsections
 149     (struct)
 150     (malloc-struct)
 151 }
 152 "Structs have literal syntax, similar to " { $link POSTPONE: T{ } " for tuples:"
 153 { $subsections POSTPONE: S{ } ;
 154
 155 ARTICLE: "classes.struct.c" "Passing structs to C functions"
 156 "Structs can be passed and returned by value, or by reference."
 157 $nl
 158 "If a parameter is declared with a struct type, the parameter is passed by value. To pass a struct by reference, declare a parameter with a pointer to struct type."
 159 $nl
 160 "If a C function is declared as returning a struct type, the struct is returned by value, and wrapped in an instance of the correct struct class automatically. If a C function is declared as returning a pointer to a struct, it will return an " { $link alien } " instance. This is because there is no way to distinguish between a pointer to a single struct and a pointer to an array of zero or more structs. It is up to the caller to wrap it in a struct, or a specialized array of structs, respectively."
 161 $nl
 162 "An example of a struct declaration:"
 163 { $code
 164     "USING: alien.c-types classes.struct ;"
 165     ""
 166     "STRUCT: Point"
 167     "    { x int }"
 168     "    { y int }"
 169     "    { z int } ;"
 170 }
 171 "A C function which returns a struct by value:"
 172 { $code
 173     "USING: alien.syntax ;"
 174     "FUNCTION: Point give_me_a_point ( c-string description ) ;"
 175 }
 176 "A C function which takes a struct parameter by reference:"
 177 { $code
 178     "FUNCTION: void print_point ( Point* p ) ;"
 179 } ;
 180
 181 ARTICLE: "classes.struct" "Struct classes"
 182 "The " { $vocab-link "classes.struct" } " vocabulary implements " { $link struct } " classes. They are similar to " { $link tuple } " classes, but their slots exhibit value semantics, and they are backed by a contiguous structured block of memory. Structs can be used for space-efficient storage of data in the Factor heap, as well as for passing data to and from C libraries using the " { $link "alien" } "."
 183 { $subsections
 184     "classes.struct.examples"
 185     "classes.struct.define"
 186     "classes.struct.create"
 187     "classes.struct.c"
 188 } ;
 189
 190 ABOUT: "classes.struct"