basis/classes/struct/struct.factor

   1 ! (c)Joe Groff, Daniel Ehrenberg bsd license
   2 USING: accessors alien alien.c-types alien.data alien.parser
   3 arrays byte-arrays classes classes.private classes.parser
   4 classes.tuple classes.tuple.parser classes.tuple.private
   5 combinators combinators.short-circuit combinators.smart
   6 cpu.architecture definitions functors.backend fry
   7 generalizations generic.parser kernel kernel.private lexer libc
   8 locals macros make math math.order parser quotations sequences
   9 slots slots.private specialized-arrays vectors words summary
  10 namespaces assocs vocabs.parser math.functions
  11 classes.struct.bit-accessors bit-arrays
  12 stack-checker.dependencies system layouts ;
  13 QUALIFIED: math
  14 IN: classes.struct
  15
  16 SPECIALIZED-ARRAY: uchar
  17
  18 ERROR: struct-must-have-slots ;
  19
  20 M: struct-must-have-slots summary
  21     drop "Struct definitions must have slots" ;
  22
  23 TUPLE: struct
  24     { (underlying) c-ptr read-only } ;
  25
  26 TUPLE: struct-slot-spec < slot-spec
  27     type ;
  28
  29 ! For a struct-bit-slot-spec, offset is in bits, not bytes
  30 TUPLE: struct-bit-slot-spec < struct-slot-spec
  31     bits signed? ;
  32
  33 PREDICATE: struct-class < tuple-class
  34     superclass \ struct eq? ;
  35
  36 SLOT: fields
  37
  38 : struct-slots ( struct-class -- slots )
  39     "c-type" word-prop fields>> ;
  40
  41 ! struct allocation
  42
  43 M: struct >c-ptr
  44     2 slot { c-ptr } declare ; inline
  45
  46 M: struct equal?
  47     {
  48         [ [ class ] bi@ = ]
  49         [ [ >c-ptr ] [ binary-object ] bi* memory= ]
  50     } 2&& ; inline
  51
  52 M: struct hashcode*
  53     binary-object <direct-uchar-array> hashcode* ; inline
  54
  55 : struct-prototype ( class -- prototype ) "prototype" word-prop ; foldable
  56
  57 : memory>struct ( ptr class -- struct )
  58     ! This is sub-optimal if the class is not literal, but gets
  59     ! optimized down to efficient code if it is.
  60     '[ _ boa ] call( ptr -- struct ) ; inline
  61
  62 <PRIVATE
  63 : (init-struct) ( class with-prototype: ( prototype -- alien ) sans-prototype: ( class -- alien ) -- alien )
  64     '[ dup struct-prototype _ _ ?if ] keep memory>struct ; inline
  65 PRIVATE>
  66
  67 : (malloc-struct) ( class -- struct )
  68     [ heap-size malloc ] keep memory>struct ; inline
  69
  70 : malloc-struct ( class -- struct )
  71     [ >c-ptr malloc-byte-array ] [ 1 swap heap-size calloc ] (init-struct) ; inline
  72
  73 : (struct) ( class -- struct )
  74     [ heap-size (byte-array) ] keep memory>struct ; inline
  75
  76 : <struct> ( class -- struct )
  77     [ >c-ptr clone ] [ heap-size <byte-array> ] (init-struct) ; inline
  78
  79 MACRO: <struct-boa> ( class -- quot: ( ... -- struct ) )
  80     [
  81         [ <wrapper> \ (struct) [ ] 2sequence ]
  82         [
  83             struct-slots
  84             [ length \ ndip ]
  85             [ [ name>> setter-word 1quotation ] map \ spread ] bi
  86         ] bi
  87     ] [ ] output>sequence ;
  88
  89 <PRIVATE
  90 : pad-struct-slots ( values class -- values' class )
  91     [ struct-slots [ initial>> ] map over length tail append ] keep ;
  92
  93 : sign-extend ( n bits -- n' )
  94     ! formula from:
  95     ! http://guru.multimedia.cx/fast-sign-extension/
  96     1 - -1 swap shift [ + ] keep bitxor ; inline
  97
  98 : sign-extender ( signed? bits -- quot )
  99     '[ _ [ _ sign-extend ] when ] ;
 100
 101 GENERIC: (reader-quot) ( slot -- quot )
 102
 103 M: struct-slot-spec (reader-quot)
 104     [ type>> c-getter ]
 105     [ offset>> [ >c-ptr ] swap suffix ] bi prepend ;
 106
 107 M: struct-bit-slot-spec (reader-quot)
 108     [ [ offset>> ] [ bits>> ] bi bit-reader ]
 109     [ [ signed?>> ] [ bits>> ] bi sign-extender ]
 110     bi compose
 111     [ >c-ptr ] prepose ;
 112
 113 GENERIC: (writer-quot) ( slot -- quot )
 114
 115 M: struct-slot-spec (writer-quot)
 116     [ type>> c-setter ]
 117     [ offset>> [ >c-ptr ] swap suffix ] bi prepend ;
 118
 119 M: struct-bit-slot-spec (writer-quot)
 120     [ offset>> ] [ bits>> ] bi bit-writer
 121     [ >c-ptr ] prepose ;
 122
 123 : (boxer-quot) ( class -- quot )
 124     '[ _ memory>struct ] ;
 125
 126 : (unboxer-quot) ( class -- quot )
 127     drop [ >c-ptr ] ;
 128
 129 MACRO: read-struct-slot ( slot -- )
 130     dup type>> depends-on-c-type
 131     (reader-quot) ;
 132
 133 MACRO: write-struct-slot ( slot -- )
 134     dup type>> depends-on-c-type
 135     (writer-quot) ;
 136 PRIVATE>
 137
 138 M: struct-class boa>object
 139     swap pad-struct-slots
 140     [ <struct> ] [ struct-slots ] bi
 141     [ [ (writer-quot) call( value struct -- ) ] with 2each ] curry keep ;
 142
 143 M: struct-class initial-value* <struct> ; inline
 144
 145 ! Struct slot accessors
 146
 147 GENERIC: struct-slot-values ( struct -- sequence )
 148
 149 M: struct-class reader-quot
 150     dup type>> array? [ dup type>> first define-array-vocab drop ] when
 151     nip '[ _ read-struct-slot ] ;
 152
 153 M: struct-class writer-quot
 154     nip '[ _ write-struct-slot ] ;
 155
 156 : offset-of ( field struct -- offset )
 157     struct-slots slot-named offset>> ; inline
 158
 159 ! c-types
 160
 161 TUPLE: struct-c-type < abstract-c-type
 162     fields
 163     return-in-registers? ;
 164
 165 INSTANCE: struct-c-type value-type
 166
 167 M: struct-c-type c-type ;
 168
 169 M: struct-c-type base-type ;
 170
 171 : large-struct? ( type -- ? )
 172     {
 173         { [ dup void? ] [ drop f ] }
 174         { [ dup base-type struct-c-type? not ] [ drop f ] }
 175         [ return-struct-in-registers? not ]
 176     } cond ;
 177
 178 <PRIVATE
 179 : struct-slot-values-quot ( class -- quot )
 180     struct-slots
 181     [ name>> reader-word 1quotation ] map
 182     \ cleave [ ] 2sequence
 183     \ output>array [ ] 2sequence ;
 184
 185 : (define-struct-slot-values-method) ( class -- )
 186     [ \ struct-slot-values ] [ struct-slot-values-quot ] bi
 187     define-inline-method ;
 188
 189 : clone-underlying ( struct -- byte-array )
 190     binary-object memory>byte-array ; inline
 191
 192 : (define-clone-method) ( class -- )
 193     [ \ clone ]
 194     [ \ clone-underlying swap literalize \ memory>struct [ ] 3sequence ] bi
 195     define-inline-method ;
 196
 197 :: c-type-for-class ( class slots size align -- c-type )
 198     struct-c-type new
 199         byte-array >>class
 200         class >>boxed-class
 201         slots >>fields
 202         size >>size
 203         align >>align
 204         align >>align-first
 205         class (unboxer-quot) >>unboxer-quot
 206         class (boxer-quot) >>boxer-quot ;
 207
 208 GENERIC: compute-slot-offset ( offset class -- offset' )
 209
 210 : c-type-align-at ( class offset -- n )
 211     0 = [ c-type-align-first ] [ c-type-align ] if ;
 212
 213 M: struct-slot-spec compute-slot-offset
 214     [ type>> over c-type-align-at 8 * align ] keep
 215     [ [ 8 /i ] dip offset<< ] [ type>> heap-size 8 * + ] 2bi ;
 216
 217 M: struct-bit-slot-spec compute-slot-offset
 218     [ offset<< ] [ bits>> + ] 2bi ;
 219
 220 : compute-struct-offsets ( slots -- size )
 221     0 [ compute-slot-offset ] reduce 8 align 8 /i ;
 222
 223 : compute-union-offsets ( slots -- size )
 224     1 [ 0 >>offset type>> heap-size max ] reduce ;
 225
 226 : struct-alignment ( slots -- align )
 227     [ struct-bit-slot-spec? not ] filter
 228     1 [ [ type>> ] [ offset>> ] bi c-type-align-at max ] reduce ;
 229
 230 PRIVATE>
 231
 232 M: struct byte-length class "struct-size" word-prop ; foldable
 233
 234 ! class definition
 235
 236 <PRIVATE
 237 GENERIC: binary-zero? ( value -- ? )
 238
 239 M: object binary-zero? drop f ;
 240 M: f binary-zero? drop t ;
 241 M: number binary-zero? 0 = ;
 242 M: struct binary-zero? >c-ptr [ 0 = ] all? ;
 243
 244 : struct-needs-prototype? ( class -- ? )
 245     struct-slots [ initial>> binary-zero? ] all? not ;
 246
 247 : make-struct-prototype ( class -- prototype )
 248     dup struct-needs-prototype? [
 249         [ "c-type" word-prop size>> <byte-array> ]
 250         [ memory>struct ]
 251         [ struct-slots ] tri
 252         [
 253             [ initial>> ]
 254             [ (writer-quot) ] bi
 255             over [ swapd [ call( value struct -- ) ] curry keep ] [ 2drop ] if
 256         ] each
 257     ] [ drop f ] if ;
 258
 259 : (struct-methods) ( class -- )
 260     [ (define-struct-slot-values-method) ]
 261     [ (define-clone-method) ]
 262     bi ;
 263
 264 : check-struct-slots ( slots -- )
 265     [ type>> c-type drop ] each ;
 266
 267 : redefine-struct-tuple-class ( class -- )
 268     [ struct f define-tuple-class ] [ make-final ] bi ;
 269
 270 :: (define-struct-class) ( class slots offsets-quot -- )
 271     slots empty? [ struct-must-have-slots ] when
 272     class redefine-struct-tuple-class
 273     slots make-slots dup check-struct-slots :> slot-specs
 274     slot-specs offsets-quot call :> unaligned-size
 275     slot-specs struct-alignment :> alignment
 276     unaligned-size alignment align :> size
 277
 278     class  slot-specs  size  alignment  c-type-for-class :> c-type
 279
 280     c-type class typedef
 281     class slot-specs define-accessors
 282     class size "struct-size" set-word-prop
 283     class dup make-struct-prototype "prototype" set-word-prop
 284     class (struct-methods) ; inline
 285 PRIVATE>
 286
 287 : define-struct-class ( class slots -- )
 288     [ compute-struct-offsets ] (define-struct-class) ;
 289
 290 : define-union-struct-class ( class slots -- )
 291     [ compute-union-offsets ] (define-struct-class) ;
 292
 293 ERROR: invalid-struct-slot token ;
 294
 295 : struct-slot-class ( c-type -- class' )
 296     c-type c-type-boxed-class
 297     dup \ byte-array = [ drop \ c-ptr ] when ;
 298
 299 SYMBOL: bits:
 300
 301 <PRIVATE
 302
 303 ERROR: bad-type-for-bits type ;
 304
 305 :: set-bits ( slot-spec n -- slot-spec )
 306     struct-bit-slot-spec new
 307         n >>bits
 308         slot-spec type>> {
 309             { int [ t ] }
 310             { uint [ f ] }
 311             [ bad-type-for-bits ]
 312         } case >>signed?
 313         slot-spec name>> >>name
 314         slot-spec class>> >>class
 315         slot-spec type>> >>type
 316         slot-spec read-only>> >>read-only
 317         slot-spec initial>> >>initial ;
 318
 319 : peel-off-struct-attributes ( slot-spec array -- slot-spec array )
 320     dup empty? [
 321         unclip {
 322             { initial: [ [ first >>initial ] [ rest ] bi ] }
 323             { read-only [ [ t >>read-only ] dip ] }
 324             { bits: [ [ first set-bits ] [ rest ] bi ] }
 325             [ bad-slot-attribute ]
 326         } case
 327     ] unless ;
 328
 329 PRIVATE>
 330
 331 : <struct-slot-spec> ( name c-type attributes -- slot-spec )
 332     [ struct-slot-spec new ] 3dip
 333     [ >>name ]
 334     [ [ >>type ] [ struct-slot-class >>class ] bi ]
 335     [ [ dup empty? ] [ peel-off-struct-attributes ] until drop ] tri* ;
 336
 337 <PRIVATE
 338 : parse-struct-slot ( -- slot )
 339     scan scan-c-type \ } parse-until <struct-slot-spec> ;
 340
 341 : parse-struct-slots ( slots -- slots' more? )
 342     scan {
 343         { ";" [ f ] }
 344         { "{" [ parse-struct-slot suffix! t ] }
 345         { f [ unexpected-eof ] }
 346         [ invalid-struct-slot ]
 347     } case ;
 348
 349 : parse-struct-definition ( -- class slots )
 350     CREATE-CLASS 8 <vector> [ parse-struct-slots ] [ ] while >array
 351     dup [ name>> ] map check-duplicate-slots ;
 352 PRIVATE>
 353
 354 SYNTAX: STRUCT:
 355     parse-struct-definition define-struct-class ;
 356 SYNTAX: UNION-STRUCT:
 357     parse-struct-definition define-union-struct-class ;
 358
 359 SYNTAX: S{
 360     scan-word dup struct-slots parse-tuple-literal-slots suffix! ;
 361
 362 SYNTAX: S@
 363     scan-word scan-object swap memory>struct suffix! ;
 364
 365 ! functor support
 366
 367 <PRIVATE
 368 : scan-c-type` ( -- c-type/param )
 369     scan dup "{" = [ drop \ } parse-until >array ] [ search ] if ;
 370
 371 : parse-struct-slot` ( accum -- accum )
 372     scan-string-param scan-c-type` \ } parse-until
 373     [ <struct-slot-spec> suffix! ] 3curry append! ;
 374
 375 : parse-struct-slots` ( accum -- accum more? )
 376     scan {
 377         { ";" [ f ] }
 378         { "{" [ parse-struct-slot` t ] }
 379         [ invalid-struct-slot ]
 380     } case ;
 381 PRIVATE>
 382
 383 FUNCTOR-SYNTAX: STRUCT:
 384     scan-param suffix!
 385     [ 8 <vector> ] append!
 386     [ parse-struct-slots` ] [ ] while
 387     [ >array define-struct-class ] append! ;
 388
 389 USING: vocabs vocabs.loader ;
 390
 391 { "classes.struct" "prettyprint" } "classes.struct.prettyprint" require-when