basis/classes/struct/struct.factor

   1 ! (c)Joe Groff, Daniel Ehrenberg bsd license
   2 USING: accessors alien alien.c-types alien.data alien.parser arrays
   3 byte-arrays classes classes.parser classes.tuple classes.tuple.parser
   4 classes.tuple.private combinators combinators.short-circuit
   5 combinators.smart cpu.architecture definitions functors.backend
   6 fry generalizations generic.parser kernel kernel.private lexer
   7 libc locals macros make math math.order parser quotations
   8 sequences slots slots.private specialized-arrays vectors words
   9 summary namespaces assocs vocabs.parser math.functions
  10 classes.struct.bit-accessors bit-arrays ;
  11 QUALIFIED: math
  12 IN: classes.struct
  13
  14 SPECIALIZED-ARRAY: uchar
  15
  16 ERROR: struct-must-have-slots ;
  17
  18 M: struct-must-have-slots summary
  19     drop "Struct definitions must have slots" ;
  20
  21 TUPLE: struct
  22     { (underlying) c-ptr read-only } ;
  23
  24 TUPLE: struct-slot-spec < slot-spec
  25     type ;
  26
  27 ! For a struct-bit-slot-spec, offset is in bits, not bytes
  28 TUPLE: struct-bit-slot-spec < struct-slot-spec
  29     bits signed? ;
  30
  31 PREDICATE: struct-class < tuple-class
  32     superclass \ struct eq? ;
  33
  34 M: struct-class valid-superclass? drop f ;
  35
  36 SLOT: fields
  37
  38 : struct-slots ( struct-class -- slots )
  39     "c-type" word-prop fields>> ;
  40
  41 ! struct allocation
  42
  43 M: struct >c-ptr
  44     2 slot { c-ptr } declare ; inline
  45
  46 M: struct equal?
  47     {
  48         [ [ class ] bi@ = ]
  49         [ [ >c-ptr ] [ [ >c-ptr ] [ byte-length ] bi ] bi* memory= ]
  50     } 2&& ; inline
  51
  52 M: struct hashcode*
  53     [ >c-ptr ] [ byte-length ] bi <direct-uchar-array> hashcode* ; inline
  54
  55 : struct-prototype ( class -- prototype ) "prototype" word-prop ; foldable
  56
  57 : memory>struct ( ptr class -- struct )
  58     ! This is sub-optimal if the class is not literal, but gets
  59     ! optimized down to efficient code if it is.
  60     '[ _ boa ] call( ptr -- struct ) ; inline
  61
  62 <PRIVATE
  63 : (init-struct) ( class with-prototype: ( prototype -- alien ) sans-prototype: ( class -- alien ) -- alien )
  64     '[ dup struct-prototype _ _ ?if ] keep memory>struct ; inline
  65 PRIVATE>
  66
  67 : (malloc-struct) ( class -- struct )
  68     [ heap-size malloc ] keep memory>struct ; inline
  69
  70 : malloc-struct ( class -- struct )
  71     [ >c-ptr malloc-byte-array ] [ 1 swap heap-size calloc ] (init-struct) ; inline
  72
  73 : (struct) ( class -- struct )
  74     [ heap-size (byte-array) ] keep memory>struct ; inline
  75
  76 : <struct> ( class -- struct )
  77     [ >c-ptr clone ] [ heap-size <byte-array> ] (init-struct) ; inline
  78
  79 MACRO: <struct-boa> ( class -- quot: ( ... -- struct ) )
  80     [
  81         [ <wrapper> \ (struct) [ ] 2sequence ]
  82         [
  83             struct-slots
  84             [ length \ ndip ]
  85             [ [ name>> setter-word 1quotation ] map \ spread ] bi
  86         ] bi
  87     ] [ ] output>sequence ;
  88
  89 <PRIVATE
  90 : pad-struct-slots ( values class -- values' class )
  91     [ struct-slots [ initial>> ] map over length tail append ] keep ;
  92
  93 : sign-extend ( n bits -- n' )
  94     ! formula from:
  95     ! http://guru.multimedia.cx/fast-sign-extension/
  96     1 - -1 swap shift [ + ] keep bitxor ; inline
  97
  98 : sign-extender ( signed? bits -- quot )
  99     '[ _ [ _ sign-extend ] when ] ;
 100
 101 GENERIC: (reader-quot) ( slot -- quot )
 102
 103 M: struct-slot-spec (reader-quot)
 104     [ type>> c-type-getter-boxer ]
 105     [ offset>> [ >c-ptr ] swap suffix ] bi prepend ;
 106
 107 M: struct-bit-slot-spec (reader-quot)
 108     [ [ offset>> ] [ bits>> ] bi bit-reader ]
 109     [ [ signed?>> ] [ bits>> ] bi sign-extender ]
 110     bi compose
 111     [ >c-ptr ] prepose ;
 112
 113 GENERIC: (writer-quot) ( slot -- quot )
 114
 115 M: struct-slot-spec (writer-quot)
 116     [ type>> c-setter ]
 117     [ offset>> [ >c-ptr ] swap suffix ] bi prepend ;
 118
 119 M: struct-bit-slot-spec (writer-quot)
 120     [ offset>> ] [ bits>> ] bi bit-writer
 121     [ >c-ptr ] prepose ;
 122
 123 : (boxer-quot) ( class -- quot )
 124     '[ _ memory>struct ] ;
 125
 126 : (unboxer-quot) ( class -- quot )
 127     drop [ >c-ptr ] ;
 128 PRIVATE>
 129
 130 M: struct-class boa>object
 131     swap pad-struct-slots
 132     [ <struct> ] [ struct-slots ] bi
 133     [ [ (writer-quot) call( value struct -- ) ] with 2each ] curry keep ;
 134
 135 M: struct-class initial-value* <struct> ; inline
 136
 137 ! Struct slot accessors
 138
 139 GENERIC: struct-slot-values ( struct -- sequence )
 140
 141 M: struct-class reader-quot
 142     nip (reader-quot) ;
 143
 144 M: struct-class writer-quot
 145     nip (writer-quot) ;
 146
 147 : offset-of ( field struct -- offset )
 148     struct-slots slot-named offset>> ; inline
 149
 150 ! c-types
 151
 152 TUPLE: struct-c-type < abstract-c-type
 153     fields
 154     return-in-registers? ;
 155
 156 INSTANCE: struct-c-type value-type
 157
 158 M: struct-c-type c-type ;
 159
 160 M: struct-c-type c-type-stack-align? drop f ;
 161
 162 : if-value-struct ( ctype true false -- )
 163     [ dup value-struct? ] 2dip '[ drop void* @ ] if ; inline
 164
 165 M: struct-c-type unbox-parameter
 166     [ %unbox-large-struct ] [ unbox-parameter ] if-value-struct ;
 167
 168 M: struct-c-type box-parameter
 169     [ %box-large-struct ] [ box-parameter ] if-value-struct ;
 170
 171 : if-small-struct ( c-type true false -- ? )
 172     [ dup return-struct-in-registers? ] 2dip '[ f swap @ ] if ; inline
 173
 174 M: struct-c-type unbox-return
 175     [ %unbox-small-struct ] [ %unbox-large-struct ] if-small-struct ;
 176
 177 M: struct-c-type box-return
 178     [ %box-small-struct ] [ %box-large-struct ] if-small-struct ;
 179
 180 M: struct-c-type stack-size
 181     [ heap-size ] [ stack-size ] if-value-struct ;
 182
 183 M: struct-c-type c-struct? drop t ;
 184
 185 <PRIVATE
 186 : struct-slot-values-quot ( class -- quot )
 187     struct-slots
 188     [ name>> reader-word 1quotation ] map
 189     \ cleave [ ] 2sequence
 190     \ output>array [ ] 2sequence ;
 191
 192 : define-inline-method ( class generic quot -- )
 193     [ create-method-in ] dip [ define ] [ drop make-inline ] 2bi ;
 194
 195 : (define-struct-slot-values-method) ( class -- )
 196     [ \ struct-slot-values ] [ struct-slot-values-quot ] bi
 197     define-inline-method ;
 198
 199 : clone-underlying ( struct -- byte-array )
 200     [ >c-ptr ] [ byte-length ] bi memory>byte-array ; inline
 201
 202 : (define-clone-method) ( class -- )
 203     [ \ clone ]
 204     [ \ clone-underlying swap literalize \ memory>struct [ ] 3sequence ] bi
 205     define-inline-method ;
 206
 207 :: c-type-for-class ( class slots size align -- c-type )
 208     struct-c-type new
 209         byte-array >>class
 210         class >>boxed-class
 211         slots >>fields
 212         size >>size
 213         align >>align
 214         align >>align-first
 215         class (unboxer-quot) >>unboxer-quot
 216         class (boxer-quot) >>boxer-quot ;
 217
 218 GENERIC: compute-slot-offset ( offset class -- offset' )
 219
 220 : c-type-align-at ( class offset -- n )
 221     0 = [ c-type-align-first ] [ c-type-align ] if ;
 222
 223 M: struct-slot-spec compute-slot-offset
 224     [ type>> over c-type-align-at 8 * align ] keep
 225     [ [ 8 /i ] dip (>>offset) ] [ type>> heap-size 8 * + ] 2bi ;
 226
 227 M: struct-bit-slot-spec compute-slot-offset
 228     [ (>>offset) ] [ bits>> + ] 2bi ;
 229
 230 : compute-struct-offsets ( slots -- size )
 231     0 [ compute-slot-offset ] reduce 8 align 8 /i ;
 232
 233 : compute-union-offsets ( slots -- size )
 234     1 [ 0 >>offset type>> heap-size max ] reduce ;
 235
 236 : struct-alignment ( slots -- align )
 237     [ struct-bit-slot-spec? not ] filter
 238     1 [ [ type>> ] [ offset>> ] bi c-type-align-at max ] reduce ;
 239
 240 PRIVATE>
 241
 242 M: struct byte-length class "struct-size" word-prop ; foldable
 243
 244 ! class definition
 245
 246 <PRIVATE
 247 GENERIC: binary-zero? ( value -- ? )
 248
 249 M: object binary-zero? drop f ;
 250 M: f binary-zero? drop t ;
 251 M: number binary-zero? 0 = ;
 252 M: struct binary-zero? >c-ptr [ 0 = ] all? ;
 253
 254 : struct-needs-prototype? ( class -- ? )
 255     struct-slots [ initial>> binary-zero? ] all? not ;
 256
 257 : make-struct-prototype ( class -- prototype )
 258     dup struct-needs-prototype? [
 259         [ "c-type" word-prop size>> <byte-array> ]
 260         [ memory>struct ]
 261         [ struct-slots ] tri
 262         [
 263             [ initial>> ]
 264             [ (writer-quot) ] bi
 265             over [ swapd [ call( value struct -- ) ] curry keep ] [ 2drop ] if
 266         ] each
 267     ] [ drop f ] if ;
 268
 269 : (struct-methods) ( class -- )
 270     [ (define-struct-slot-values-method) ]
 271     [ (define-clone-method) ]
 272     bi ;
 273
 274 : check-struct-slots ( slots -- )
 275     [ type>> c-type drop ] each ;
 276
 277 : redefine-struct-tuple-class ( class -- )
 278     [ dup class? [ forget-class ] [ drop ] if ] [ struct f define-tuple-class ] bi ;
 279
 280 :: (define-struct-class) ( class slots offsets-quot -- )
 281     slots empty? [ struct-must-have-slots ] when
 282     class redefine-struct-tuple-class
 283     slots make-slots dup check-struct-slots :> slot-specs
 284     slot-specs offsets-quot call :> unaligned-size
 285     slot-specs struct-alignment :> alignment
 286     unaligned-size alignment align :> size
 287
 288     class  slot-specs  size  alignment  c-type-for-class :> c-type
 289
 290     c-type class typedef
 291     class slot-specs define-accessors
 292     class size "struct-size" set-word-prop
 293     class dup make-struct-prototype "prototype" set-word-prop
 294     class (struct-methods) ; inline
 295 PRIVATE>
 296
 297 : define-struct-class ( class slots -- )
 298     [ compute-struct-offsets ] (define-struct-class) ;
 299
 300 : define-union-struct-class ( class slots -- )
 301     [ compute-union-offsets ] (define-struct-class) ;
 302
 303 M: struct-class reset-class
 304     [ call-next-method ] [ name>> c-types get delete-at ] bi ;
 305
 306 ERROR: invalid-struct-slot token ;
 307
 308 : struct-slot-class ( c-type -- class' )
 309     c-type c-type-boxed-class
 310     dup \ byte-array = [ drop \ c-ptr ] when ;
 311
 312 SYMBOL: bits:
 313
 314 <PRIVATE
 315
 316 ERROR: bad-type-for-bits type ;
 317
 318 :: set-bits ( slot-spec n -- slot-spec )
 319     struct-bit-slot-spec new
 320         n >>bits
 321         slot-spec type>> {
 322             { int [ t ] }
 323             { uint [ f ] }
 324             [ bad-type-for-bits ]
 325         } case >>signed?
 326         slot-spec name>> >>name
 327         slot-spec class>> >>class
 328         slot-spec type>> >>type
 329         slot-spec read-only>> >>read-only
 330         slot-spec initial>> >>initial ;
 331
 332 : peel-off-struct-attributes ( slot-spec array -- slot-spec array )
 333     dup empty? [
 334         unclip {
 335             { initial: [ [ first >>initial ] [ rest ] bi ] }
 336             { read-only [ [ t >>read-only ] dip ] }
 337             { bits: [ [ first set-bits ] [ rest ] bi ] }
 338             [ bad-slot-attribute ]
 339         } case
 340     ] unless ;
 341
 342 PRIVATE>
 343
 344 : <struct-slot-spec> ( name c-type attributes -- slot-spec )
 345     [ struct-slot-spec new ] 3dip
 346     [ >>name ]
 347     [ [ >>type ] [ struct-slot-class >>class ] bi ]
 348     [ [ dup empty? ] [ peel-off-struct-attributes ] until drop ] tri* ;
 349
 350 <PRIVATE
 351 : parse-struct-slot ( -- slot )
 352     scan scan-c-type \ } parse-until <struct-slot-spec> ;
 353
 354 : parse-struct-slots ( slots -- slots' more? )
 355     scan {
 356         { ";" [ f ] }
 357         { "{" [ parse-struct-slot suffix! t ] }
 358         { f [ unexpected-eof ] }
 359         [ invalid-struct-slot ]
 360     } case ;
 361
 362 : parse-struct-definition ( -- class slots )
 363     CREATE-CLASS 8 <vector> [ parse-struct-slots ] [ ] while >array ;
 364 PRIVATE>
 365
 366 SYNTAX: STRUCT:
 367     parse-struct-definition define-struct-class ;
 368 SYNTAX: UNION-STRUCT:
 369     parse-struct-definition define-union-struct-class ;
 370
 371 SYNTAX: S{
 372     scan-word dup struct-slots parse-tuple-literal-slots suffix! ;
 373
 374 SYNTAX: S@
 375     scan-word scan-object swap memory>struct suffix! ;
 376
 377 ! functor support
 378
 379 <PRIVATE
 380 : scan-c-type` ( -- c-type/param )
 381     scan dup "{" = [ drop \ } parse-until >array ] [ search ] if ;
 382
 383 : parse-struct-slot` ( accum -- accum )
 384     scan-string-param scan-c-type` \ } parse-until
 385     [ <struct-slot-spec> suffix! ] 3curry append! ;
 386
 387 : parse-struct-slots` ( accum -- accum more? )
 388     scan {
 389         { ";" [ f ] }
 390         { "{" [ parse-struct-slot` t ] }
 391         [ invalid-struct-slot ]
 392     } case ;
 393 PRIVATE>
 394
 395 FUNCTOR-SYNTAX: STRUCT:
 396     scan-param suffix!
 397     [ 8 <vector> ] append!
 398     [ parse-struct-slots` ] [ ] while
 399     [ >array define-struct-class ] append! ;
 400
 401 USING: vocabs vocabs.loader ;
 402
 403 "prettyprint" vocab [ "classes.struct.prettyprint" require ] when