basis/classes/struct/struct.factor

   1 ! Copyright (C) 2010, 2011 Joe Groff, Daniel Ehrenberg,
   2 ! John Benediktsson, Slava Pestov.
   3 ! See https://factorcode.org/license.txt for BSD license
   4 IN: classes.struct
   5 DEFER: struct-slots ! for stack-checker
   6 DEFER: struct-class? ! for stack-checker
   7 DEFER: <struct-boa> ! for stack-checker
   8 USING: accessors alien alien.c-types alien.data alien.parser
   9 arrays assocs byte-arrays classes classes.parser classes.private
  10 classes.struct.bit-accessors classes.tuple classes.tuple.parser
  11 classes.tuple.private combinators combinators.short-circuit
  12 combinators.smart cpu.architecture definitions delegate.private
  13 effects functors.backend generalizations generic generic.parser
  14 io kernel kernel.private lexer libc math math.order parser
  15 quotations sequences sequences.private slots slots.private
  16 specialized-arrays stack-checker.dependencies summary vectors
  17 vocabs.loader vocabs.parser words ;
  18
  19 SPECIALIZED-ARRAY: uchar
  20
  21 ERROR: struct-must-have-slots ;
  22
  23 M: struct-must-have-slots summary
  24     drop "Struct definitions must have slots" ;
  25
  26 TUPLE: struct
  27     { (underlying) c-ptr read-only } ;
  28
  29 ! We hijack the core slots vocab's slot-spec type for struct
  30 ! fields. Note that 'offset' is in bits, not bytes, to support
  31 ! bitfields.
  32 TUPLE: struct-slot-spec < slot-spec
  33     type packed? ;
  34
  35 ! For a struct-bit-slot-spec, offset is in bits, not bytes
  36 TUPLE: struct-bit-slot-spec < struct-slot-spec
  37     bits signed? ;
  38
  39 PREDICATE: struct-class < tuple-class
  40     superclass-of \ struct eq? ;
  41
  42 SLOT: fields
  43
  44 : struct-slots ( struct-class -- slots )
  45     "c-type" word-prop fields>> ;
  46
  47 M: struct-class group-words
  48     struct-slots slot-group-words ;
  49
  50 ! struct allocation
  51 M: struct >c-ptr
  52     2 slot { c-ptr } declare ; inline
  53
  54 : struct-prototype ( class -- prototype ) "prototype" word-prop ; foldable
  55
  56 : memory>struct ( ptr class -- struct )
  57     ! This is sub-optimal if the class is not literal, but gets
  58     ! optimized down to efficient code if it is.
  59     struct-class check-instance
  60     M\ tuple-class boa execute( ptr class -- struct ) ;
  61
  62 : read-struct ( class -- struct )
  63     [ heap-size read ] [ memory>struct ] bi ;
  64
  65 <PRIVATE
  66
  67 : init-struct ( class with-prototype: ( prototype -- alien ) sans-prototype: ( class -- alien ) -- alien )
  68     '[ dup struct-prototype _ _ ?if-old ] keep memory>struct ; inline
  69
  70 PRIVATE>
  71
  72 : (malloc-struct) ( class -- struct )
  73     [ heap-size malloc ] keep memory>struct ; inline
  74
  75 : malloc-struct ( class -- struct )
  76     [ >c-ptr malloc-byte-array ] [ 1 swap heap-size calloc ] init-struct ; inline
  77
  78 : (struct) ( class -- struct )
  79     [ heap-size (byte-array) ] keep memory>struct ; inline
  80
  81 : <struct> ( class -- struct )
  82     [ >c-ptr clone ] [ heap-size <byte-array> ] init-struct ; inline
  83
  84 <PRIVATE
  85
  86 : pad-struct-slots ( values class -- values' class )
  87     [ struct-slots [ initial>> ] map over length tail append ] keep ;
  88
  89 : sign-extend ( n bits -- n' )
  90     ! formula from:
  91     ! https://guru.multimedia.cx/fast-sign-extension/
  92     1 - -1 swap shift [ + ] keep bitxor ; inline
  93
  94 : sign-extender ( signed? bits -- quot )
  95     '[ _ [ _ sign-extend ] when ] ;
  96
  97 GENERIC: (reader-quot) ( slot -- quot: ( struct -- value ) )
  98
  99 M: struct-slot-spec (reader-quot)
 100     [ offset>> ] [ type>> ] bi '[ >c-ptr _ _ alien-value ] ;
 101
 102 M: struct-bit-slot-spec (reader-quot)
 103     [ [ offset>> ] [ bits>> ] bi bit-reader ]
 104     [ [ signed?>> ] [ bits>> ] bi sign-extender ]
 105     bi compose
 106     [ >c-ptr ] prepose ;
 107
 108 GENERIC: (writer-quot) ( slot -- quot: ( value struct -- ) )
 109
 110 M: struct-slot-spec (writer-quot)
 111     [ offset>> ] [ type>> ] bi '[ >c-ptr _ _ set-alien-value ] ;
 112
 113 M: struct-bit-slot-spec (writer-quot)
 114     [ offset>> ] [ bits>> ] bi bit-writer [ >c-ptr ] prepose ;
 115
 116 : (boxer-quot) ( class -- quot )
 117     '[ _ memory>struct ] ;
 118
 119 : (unboxer-quot) ( class -- quot )
 120     drop [ >c-ptr ] ;
 121
 122 MACRO: read-struct-slot ( slot -- quot: ( struct -- value ) )
 123     dup type>> add-depends-on-c-type
 124     (reader-quot) ;
 125
 126 MACRO: write-struct-slot ( slot -- quot: ( value struct -- ) )
 127     dup type>> add-depends-on-c-type
 128     (writer-quot) ;
 129
 130 PRIVATE>
 131
 132 MACRO: <struct-boa> ( class -- quot: ( ... -- struct ) )
 133     dup struct-slots
 134     [ length ] [ [ (writer-quot) '[ over @ ] ] map ] bi
 135     '[ [ _ (struct) ] _ ndip _ spread ] ;
 136
 137 M: struct-class boa>object
 138     swap pad-struct-slots
 139     [ <struct> ] [ struct-slots ] bi
 140     [ [ (writer-quot) call( value struct -- ) ] with 2each ] keepd ;
 141
 142 M: struct-class new <struct> ;
 143
 144 M: struct-class boa <struct-boa> ;
 145
 146 M: struct-class boa-effect
 147     [ struct-slots [ name>> ] map ] [ name>> 1array ] bi <effect> ;
 148
 149 M: struct-class initial-value* <struct> t ; inline
 150
 151 ! Struct slot accessors
 152
 153 GENERIC: struct-slot-values ( struct -- sequence )
 154
 155 M: struct-class reader-quot
 156     dup type>> array? [ dup type>> first define-array-vocab drop ] when
 157     nip '[ _ read-struct-slot ] ;
 158
 159 M: struct-class writer-quot
 160     nip '[ _ write-struct-slot ] ;
 161
 162 : offset-of ( field struct -- offset )
 163     struct-slots slot-named offset>> ; inline
 164
 165 M: struct equal?
 166     2dup [ class-of ] same? [
 167         [ struct-slot-values ] same?
 168     ] [ 2drop f ] if ; inline
 169
 170 M: struct hashcode*
 171     nip dup >c-ptr [ struct-slot-values hashcode ] [ drop 0 ] if ; inline
 172
 173 ! c-types
 174
 175 TUPLE: struct-c-type < abstract-c-type
 176     fields
 177     return-in-registers? ;
 178
 179 INSTANCE: struct-c-type value-type
 180
 181 M: struct-c-type lookup-c-type ;
 182
 183 M: struct-c-type base-type ;
 184
 185 : large-struct? ( type -- ? )
 186     {
 187         { [ dup void? ] [ drop f ] }
 188         { [ dup base-type struct-c-type? not ] [ drop f ] }
 189         [ return-struct-in-registers? not ]
 190     } cond ;
 191
 192 <PRIVATE
 193 : struct-slot-values-quot ( class -- quot )
 194     struct-slots
 195     [ name>> reader-word 1quotation ] map
 196     '[ _ cleave>array ] ;
 197
 198 : define-struct-slot-values-method ( class -- )
 199     [ \ struct-slot-values ] [ struct-slot-values-quot ] bi
 200     define-inline-method ;
 201
 202 : forget-struct-slot-values-method ( class -- )
 203     \ struct-slot-values ?lookup-method forget ;
 204
 205 : clone-underlying ( struct -- byte-array )
 206     binary-object memory>byte-array ; inline
 207
 208 : define-clone-method ( class -- )
 209     [ \ clone ] [ '[ clone-underlying _ memory>struct ] ] bi
 210     define-inline-method ;
 211
 212 : forget-clone-method ( class -- )
 213     \ clone ?lookup-method forget ;
 214
 215 :: c-type-for-class ( class slots size align -- c-type )
 216     struct-c-type new
 217         byte-array >>class
 218         class >>boxed-class
 219         slots >>fields
 220         size >>size
 221         align >>align
 222         align >>align-first
 223         class (unboxer-quot) >>unboxer-quot
 224         class (boxer-quot) >>boxer-quot ;
 225
 226 GENERIC: compute-slot-offset ( offset class -- offset' )
 227
 228 : c-type-align-at ( slot-spec offset -- n )
 229     over packed?>> [ 2drop 1 ] [
 230         [ type>> ] dip
 231         0 = [ c-type-align-first ] [ c-type-align ] if
 232     ] if ;
 233
 234 M: struct-slot-spec compute-slot-offset
 235     [ over c-type-align-at 8 * align ] keep
 236     [ [ 8 /i ] dip offset<< ] [ type>> heap-size 8 * + ] 2bi ;
 237
 238 M: struct-bit-slot-spec compute-slot-offset
 239     [ offset<< ] [ bits>> + ] 2bi ;
 240
 241 : compute-struct-offsets ( slots -- size )
 242     0 [ compute-slot-offset ] reduce 8 align 8 /i ;
 243
 244 : compute-union-offsets ( slots -- size )
 245     1 [ 0 >>offset type>> heap-size max ] reduce ;
 246
 247 : struct-alignment ( slots -- align )
 248     [ struct-bit-slot-spec? ] reject
 249     1 [ dup offset>> c-type-align-at max ] reduce ;
 250
 251 PRIVATE>
 252
 253 : struct-size ( class -- n ) "struct-size" word-prop ; inline
 254
 255 M: struct byte-length class-of struct-size ; inline foldable
 256 M: struct binary-zero? binary-object uchar <c-direct-array> [ 0 = ] all? ; inline
 257
 258 ! class definition
 259
 260 <PRIVATE
 261 : struct-needs-prototype? ( class -- ? )
 262     struct-slots [ initial>> binary-zero? ] all? not ;
 263
 264 : make-struct-prototype ( class -- prototype )
 265     dup struct-needs-prototype? [
 266         [ "c-type" word-prop size>> <byte-array> ]
 267         [ memory>struct ]
 268         [ struct-slots ] tri
 269         [
 270             [ initial>> ]
 271             [ (writer-quot) ] bi
 272             over [ swapd [ call( value struct -- ) ] keepd ] [ 2drop ] if
 273         ] each
 274     ] [ drop f ] if ;
 275
 276 : define-struct-methods ( class -- )
 277     [ define-struct-slot-values-method ] [ define-clone-method ] bi ;
 278
 279 : check-struct-slots ( slots -- )
 280     [ type>> lookup-c-type drop ] each ;
 281
 282 : redefine-struct-tuple-class ( class -- )
 283     [ struct f redefine-tuple-class ] [ make-final ] bi ;
 284
 285 : resize-underlying ( struct -- )
 286     [ 2 slot dup byte-array? ]
 287     [ class-of "struct-size" word-prop '[ _ swap resize ] [ drop f ] if ]
 288     [ 2 set-slot ] tri ;
 289
 290 M: struct update-tuple
 291     ! make sure underlying byte-array is correct size, but maybe
 292     ! has incorrect contents... is there something better to do?
 293     [ resize-underlying ] [ call-next-method ] bi ;
 294
 295 : forget-struct-slot-accessors ( class -- )
 296     dup "c-type" word-prop [
 297         dup struct-c-type? [
 298             fields>> forget-slot-accessors
 299         ] [ 2drop ] if
 300     ] [ drop ] if* ;
 301
 302 :: (define-struct-class) ( class slot-specs offsets-quot alignment-quot -- )
 303     slot-specs check-struct-slots
 304     slot-specs empty? [ struct-must-have-slots ] when
 305     class redefine-struct-tuple-class
 306     slot-specs offsets-quot call :> unaligned-size
 307     slot-specs alignment-quot call :> alignment
 308     unaligned-size alignment align :> size
 309
 310     class slot-specs size alignment c-type-for-class :> c-type
 311
 312     class forget-struct-slot-accessors
 313
 314     c-type class typedef
 315     class slot-specs define-accessors
 316     class size "struct-size" set-word-prop
 317     class dup make-struct-prototype "prototype" set-word-prop
 318     class define-struct-methods ; inline
 319
 320 : make-packed-slots ( slots -- slot-specs )
 321     make-slots [ t >>packed? ] map! ;
 322
 323 PRIVATE>
 324
 325 : define-struct-class ( class slots -- )
 326     make-slots
 327     [ compute-struct-offsets ] [ struct-alignment ]
 328     (define-struct-class) ;
 329
 330 : define-packed-struct-class ( class slots -- )
 331     make-packed-slots
 332     [ compute-struct-offsets ] [ drop 1 ]
 333     (define-struct-class) ;
 334
 335 : define-union-struct-class ( class slots -- )
 336     make-slots
 337     [ compute-union-offsets ] [ struct-alignment ]
 338     (define-struct-class) ;
 339
 340 ERROR: invalid-struct-slot token ;
 341
 342 : struct-slot-class ( c-type -- class' )
 343     lookup-c-type c-type-boxed-class
 344     dup \ byte-array = [ drop \ c-ptr ] when ;
 345
 346 M: struct-class reset-class
 347     {
 348         [ \ <struct-boa> def>> first delete-at ]
 349         [ forget-struct-slot-accessors ]
 350         [ forget-struct-slot-values-method ]
 351         [ forget-clone-method ]
 352         [ { "c-type" "layout" "struct-size" } remove-word-props ]
 353         [ call-next-method ]
 354     } cleave ;
 355
 356 SYMBOL: bits:
 357
 358 <PRIVATE
 359
 360 :: set-bits ( slot-spec n -- slot-spec )
 361     struct-bit-slot-spec new
 362         n >>bits
 363         slot-spec type>> c-type-signed >>signed?
 364         slot-spec name>> >>name
 365         slot-spec class>> >>class
 366         slot-spec type>> >>type
 367         slot-spec read-only>> >>read-only
 368         slot-spec initial>> >>initial ;
 369
 370 : peel-off-struct-attributes ( slot-spec array -- slot-spec array )
 371     dup empty? [
 372         unclip {
 373             { initial: [ [ first >>initial ] [ rest ] bi ] }
 374             { read-only [ [ t >>read-only ] dip ] }
 375             { bits: [ [ first set-bits ] [ rest ] bi ] }
 376             [ bad-slot-attribute ]
 377         } case
 378     ] unless ;
 379
 380 PRIVATE>
 381
 382 : <struct-slot-spec> ( name c-type attributes -- slot-spec )
 383     [ struct-slot-spec new ] 3dip
 384     [ >>name ]
 385     [ [ >>type ] [ struct-slot-class init-slot-class ] bi ]
 386     [ [ dup empty? ] [ peel-off-struct-attributes ] until drop ] tri* ;
 387
 388 <PRIVATE
 389 : parse-struct-slot ( -- slot )
 390     scan-token scan-c-type \ } parse-until <struct-slot-spec> ;
 391
 392 : parse-struct-slots ( slots -- slots' more? )
 393     scan-token {
 394         { ";" [ f ] }
 395         { "{" [ parse-struct-slot suffix! t ] }
 396         [ invalid-struct-slot ]
 397     } case ;
 398
 399 : parse-struct-definition ( -- class slots )
 400     scan-new-class 8 <vector> [ parse-struct-slots ] [ ] while >array
 401     dup [ name>> ] map check-duplicate-slots ;
 402 PRIVATE>
 403
 404 SYNTAX: STRUCT:
 405     parse-struct-definition define-struct-class ;
 406
 407 SYNTAX: PACKED-STRUCT:
 408     parse-struct-definition define-packed-struct-class ;
 409
 410 SYNTAX: UNION-STRUCT:
 411     parse-struct-definition define-union-struct-class ;
 412
 413 SYNTAX: S{
 414     scan-word dup struct-slots parse-tuple-literal-slots suffix! ;
 415
 416 SYNTAX: S@
 417     scan-word scan-object swap memory>struct suffix! ;
 418
 419 ! functor support
 420
 421 <PRIVATE
 422 : scan-c-type* ( -- c-type/param )
 423     scan-token dup "{" = [ drop \ } parse-until >array ] [ search ] if ;
 424
 425 : parse-struct-slot* ( accum -- accum )
 426     scan-string-param scan-c-type* \ } parse-until
 427     [ <struct-slot-spec> suffix! ] 3curry append! ;
 428
 429 : parse-struct-slots* ( accum -- accum more? )
 430     scan-token {
 431         { ";" [ f ] }
 432         { "{" [ parse-struct-slot* t ] }
 433         [ invalid-struct-slot ]
 434     } case ;
 435
 436 PRIVATE>
 437
 438 FUNCTOR-SYNTAX: STRUCT:
 439     scan-param suffix!
 440     [ 8 <vector> ] append!
 441     [ parse-struct-slots* ] [ ] while
 442     [ >array define-struct-class ] append! ;
 443
 444 { "classes.struct" "prettyprint" } "classes.struct.prettyprint" require-when