basis/classes/struct/struct.factor

   1 ! (c)Joe Groff, Daniel Ehrenberg bsd license
   2 USING: accessors alien alien.c-types alien.data alien.parser
   3 arrays byte-arrays classes classes.private classes.parser
   4 classes.tuple classes.tuple.parser classes.tuple.private
   5 combinators combinators.short-circuit combinators.smart
   6 cpu.architecture definitions functors.backend fry
   7 generalizations generic.parser kernel kernel.private lexer libc
   8 locals macros make math math.order parser quotations sequences
   9 slots slots.private specialized-arrays vectors words summary
  10 namespaces assocs vocabs.parser math.functions
  11 classes.struct.bit-accessors bit-arrays
  12 stack-checker.dependencies ;
  13 QUALIFIED: math
  14 IN: classes.struct
  15
  16 SPECIALIZED-ARRAY: uchar
  17
  18 ERROR: struct-must-have-slots ;
  19
  20 M: struct-must-have-slots summary
  21     drop "Struct definitions must have slots" ;
  22
  23 TUPLE: struct
  24     { (underlying) c-ptr read-only } ;
  25
  26 TUPLE: struct-slot-spec < slot-spec
  27     type ;
  28
  29 ! For a struct-bit-slot-spec, offset is in bits, not bytes
  30 TUPLE: struct-bit-slot-spec < struct-slot-spec
  31     bits signed? ;
  32
  33 PREDICATE: struct-class < tuple-class
  34     superclass \ struct eq? ;
  35
  36 SLOT: fields
  37
  38 : struct-slots ( struct-class -- slots )
  39     "c-type" word-prop fields>> ;
  40
  41 ! struct allocation
  42
  43 M: struct >c-ptr
  44     2 slot { c-ptr } declare ; inline
  45
  46 M: struct equal?
  47     {
  48         [ [ class ] bi@ = ]
  49         [ [ >c-ptr ] [ binary-object ] bi* memory= ]
  50     } 2&& ; inline
  51
  52 M: struct hashcode*
  53     binary-object <direct-uchar-array> hashcode* ; inline
  54
  55 : struct-prototype ( class -- prototype ) "prototype" word-prop ; foldable
  56
  57 : memory>struct ( ptr class -- struct )
  58     ! This is sub-optimal if the class is not literal, but gets
  59     ! optimized down to efficient code if it is.
  60     '[ _ boa ] call( ptr -- struct ) ; inline
  61
  62 <PRIVATE
  63 : (init-struct) ( class with-prototype: ( prototype -- alien ) sans-prototype: ( class -- alien ) -- alien )
  64     '[ dup struct-prototype _ _ ?if ] keep memory>struct ; inline
  65 PRIVATE>
  66
  67 : (malloc-struct) ( class -- struct )
  68     [ heap-size malloc ] keep memory>struct ; inline
  69
  70 : malloc-struct ( class -- struct )
  71     [ >c-ptr malloc-byte-array ] [ 1 swap heap-size calloc ] (init-struct) ; inline
  72
  73 : (struct) ( class -- struct )
  74     [ heap-size (byte-array) ] keep memory>struct ; inline
  75
  76 : <struct> ( class -- struct )
  77     [ >c-ptr clone ] [ heap-size <byte-array> ] (init-struct) ; inline
  78
  79 MACRO: <struct-boa> ( class -- quot: ( ... -- struct ) )
  80     [
  81         [ <wrapper> \ (struct) [ ] 2sequence ]
  82         [
  83             struct-slots
  84             [ length \ ndip ]
  85             [ [ name>> setter-word 1quotation ] map \ spread ] bi
  86         ] bi
  87     ] [ ] output>sequence ;
  88
  89 <PRIVATE
  90 : pad-struct-slots ( values class -- values' class )
  91     [ struct-slots [ initial>> ] map over length tail append ] keep ;
  92
  93 : sign-extend ( n bits -- n' )
  94     ! formula from:
  95     ! http://guru.multimedia.cx/fast-sign-extension/
  96     1 - -1 swap shift [ + ] keep bitxor ; inline
  97
  98 : sign-extender ( signed? bits -- quot )
  99     '[ _ [ _ sign-extend ] when ] ;
 100
 101 GENERIC: (reader-quot) ( slot -- quot )
 102
 103 M: struct-slot-spec (reader-quot)
 104     [ type>> c-type-getter-boxer ]
 105     [ offset>> [ >c-ptr ] swap suffix ] bi prepend ;
 106
 107 M: struct-bit-slot-spec (reader-quot)
 108     [ [ offset>> ] [ bits>> ] bi bit-reader ]
 109     [ [ signed?>> ] [ bits>> ] bi sign-extender ]
 110     bi compose
 111     [ >c-ptr ] prepose ;
 112
 113 GENERIC: (writer-quot) ( slot -- quot )
 114
 115 M: struct-slot-spec (writer-quot)
 116     [ type>> c-setter ]
 117     [ offset>> [ >c-ptr ] swap suffix ] bi prepend ;
 118
 119 M: struct-bit-slot-spec (writer-quot)
 120     [ offset>> ] [ bits>> ] bi bit-writer
 121     [ >c-ptr ] prepose ;
 122
 123 : (boxer-quot) ( class -- quot )
 124     '[ _ memory>struct ] ;
 125
 126 : (unboxer-quot) ( class -- quot )
 127     drop [ >c-ptr ] ;
 128
 129 MACRO: read-struct-slot ( slot -- )
 130     dup type>> depends-on-c-type
 131     (reader-quot) ;
 132
 133 MACRO: write-struct-slot ( slot -- )
 134     dup type>> depends-on-c-type
 135     (writer-quot) ;
 136 PRIVATE>
 137
 138 M: struct-class boa>object
 139     swap pad-struct-slots
 140     [ <struct> ] [ struct-slots ] bi
 141     [ [ (writer-quot) call( value struct -- ) ] with 2each ] curry keep ;
 142
 143 M: struct-class initial-value* <struct> ; inline
 144
 145 ! Struct slot accessors
 146
 147 GENERIC: struct-slot-values ( struct -- sequence )
 148
 149 M: struct-class reader-quot
 150     dup type>> array? [ dup type>> first define-array-vocab drop ] when
 151     nip '[ _ read-struct-slot ] ;
 152
 153 M: struct-class writer-quot
 154     nip '[ _ write-struct-slot ] ;
 155
 156 : offset-of ( field struct -- offset )
 157     struct-slots slot-named offset>> ; inline
 158
 159 ! c-types
 160
 161 TUPLE: struct-c-type < abstract-c-type
 162     fields
 163     return-in-registers? ;
 164
 165 INSTANCE: struct-c-type value-type
 166
 167 M: struct-c-type c-type ;
 168
 169 M: struct-c-type c-type-stack-align? drop f ;
 170
 171 : if-value-struct ( ctype true false -- )
 172     [ dup value-struct? ] 2dip '[ drop void* @ ] if ; inline
 173
 174 M: struct-c-type unbox-parameter
 175     [ %unbox-large-struct ] [ unbox-parameter ] if-value-struct ;
 176
 177 M: struct-c-type box-parameter
 178     [ %box-large-struct ] [ box-parameter ] if-value-struct ;
 179
 180 : if-small-struct ( c-type true false -- ? )
 181     [ dup return-struct-in-registers? ] 2dip '[ f swap @ ] if ; inline
 182
 183 M: struct-c-type unbox-return
 184     [ %unbox-small-struct ] [ %unbox-large-struct ] if-small-struct ;
 185
 186 M: struct-c-type box-return
 187     [ %box-small-struct ] [ %box-large-struct ] if-small-struct ;
 188
 189 M: struct-c-type stack-size
 190     [ heap-size ] [ stack-size ] if-value-struct ;
 191
 192 M: struct-c-type c-struct? drop t ;
 193
 194 <PRIVATE
 195 : struct-slot-values-quot ( class -- quot )
 196     struct-slots
 197     [ name>> reader-word 1quotation ] map
 198     \ cleave [ ] 2sequence
 199     \ output>array [ ] 2sequence ;
 200
 201 : (define-struct-slot-values-method) ( class -- )
 202     [ \ struct-slot-values ] [ struct-slot-values-quot ] bi
 203     define-inline-method ;
 204
 205 : clone-underlying ( struct -- byte-array )
 206     binary-object memory>byte-array ; inline
 207
 208 : (define-clone-method) ( class -- )
 209     [ \ clone ]
 210     [ \ clone-underlying swap literalize \ memory>struct [ ] 3sequence ] bi
 211     define-inline-method ;
 212
 213 :: c-type-for-class ( class slots size align -- c-type )
 214     struct-c-type new
 215         byte-array >>class
 216         class >>boxed-class
 217         slots >>fields
 218         size >>size
 219         align >>align
 220         align >>align-first
 221         class (unboxer-quot) >>unboxer-quot
 222         class (boxer-quot) >>boxer-quot ;
 223
 224 GENERIC: compute-slot-offset ( offset class -- offset' )
 225
 226 : c-type-align-at ( class offset -- n )
 227     0 = [ c-type-align-first ] [ c-type-align ] if ;
 228
 229 M: struct-slot-spec compute-slot-offset
 230     [ type>> over c-type-align-at 8 * align ] keep
 231     [ [ 8 /i ] dip (>>offset) ] [ type>> heap-size 8 * + ] 2bi ;
 232
 233 M: struct-bit-slot-spec compute-slot-offset
 234     [ (>>offset) ] [ bits>> + ] 2bi ;
 235
 236 : compute-struct-offsets ( slots -- size )
 237     0 [ compute-slot-offset ] reduce 8 align 8 /i ;
 238
 239 : compute-union-offsets ( slots -- size )
 240     1 [ 0 >>offset type>> heap-size max ] reduce ;
 241
 242 : struct-alignment ( slots -- align )
 243     [ struct-bit-slot-spec? not ] filter
 244     1 [ [ type>> ] [ offset>> ] bi c-type-align-at max ] reduce ;
 245
 246 PRIVATE>
 247
 248 M: struct byte-length class "struct-size" word-prop ; foldable
 249
 250 ! class definition
 251
 252 <PRIVATE
 253 GENERIC: binary-zero? ( value -- ? )
 254
 255 M: object binary-zero? drop f ;
 256 M: f binary-zero? drop t ;
 257 M: number binary-zero? 0 = ;
 258 M: struct binary-zero? >c-ptr [ 0 = ] all? ;
 259
 260 : struct-needs-prototype? ( class -- ? )
 261     struct-slots [ initial>> binary-zero? ] all? not ;
 262
 263 : make-struct-prototype ( class -- prototype )
 264     dup struct-needs-prototype? [
 265         [ "c-type" word-prop size>> <byte-array> ]
 266         [ memory>struct ]
 267         [ struct-slots ] tri
 268         [
 269             [ initial>> ]
 270             [ (writer-quot) ] bi
 271             over [ swapd [ call( value struct -- ) ] curry keep ] [ 2drop ] if
 272         ] each
 273     ] [ drop f ] if ;
 274
 275 : (struct-methods) ( class -- )
 276     [ (define-struct-slot-values-method) ]
 277     [ (define-clone-method) ]
 278     bi ;
 279
 280 : check-struct-slots ( slots -- )
 281     [ type>> c-type drop ] each ;
 282
 283 : redefine-struct-tuple-class ( class -- )
 284     [ struct f define-tuple-class ] [ make-final ] bi ;
 285
 286 :: (define-struct-class) ( class slots offsets-quot -- )
 287     slots empty? [ struct-must-have-slots ] when
 288     class redefine-struct-tuple-class
 289     slots make-slots dup check-struct-slots :> slot-specs
 290     slot-specs offsets-quot call :> unaligned-size
 291     slot-specs struct-alignment :> alignment
 292     unaligned-size alignment align :> size
 293
 294     class  slot-specs  size  alignment  c-type-for-class :> c-type
 295
 296     c-type class typedef
 297     class slot-specs define-accessors
 298     class size "struct-size" set-word-prop
 299     class dup make-struct-prototype "prototype" set-word-prop
 300     class (struct-methods) ; inline
 301 PRIVATE>
 302
 303 : define-struct-class ( class slots -- )
 304     [ compute-struct-offsets ] (define-struct-class) ;
 305
 306 : define-union-struct-class ( class slots -- )
 307     [ compute-union-offsets ] (define-struct-class) ;
 308
 309 ERROR: invalid-struct-slot token ;
 310
 311 : struct-slot-class ( c-type -- class' )
 312     c-type c-type-boxed-class
 313     dup \ byte-array = [ drop \ c-ptr ] when ;
 314
 315 SYMBOL: bits:
 316
 317 <PRIVATE
 318
 319 ERROR: bad-type-for-bits type ;
 320
 321 :: set-bits ( slot-spec n -- slot-spec )
 322     struct-bit-slot-spec new
 323         n >>bits
 324         slot-spec type>> {
 325             { int [ t ] }
 326             { uint [ f ] }
 327             [ bad-type-for-bits ]
 328         } case >>signed?
 329         slot-spec name>> >>name
 330         slot-spec class>> >>class
 331         slot-spec type>> >>type
 332         slot-spec read-only>> >>read-only
 333         slot-spec initial>> >>initial ;
 334
 335 : peel-off-struct-attributes ( slot-spec array -- slot-spec array )
 336     dup empty? [
 337         unclip {
 338             { initial: [ [ first >>initial ] [ rest ] bi ] }
 339             { read-only [ [ t >>read-only ] dip ] }
 340             { bits: [ [ first set-bits ] [ rest ] bi ] }
 341             [ bad-slot-attribute ]
 342         } case
 343     ] unless ;
 344
 345 PRIVATE>
 346
 347 : <struct-slot-spec> ( name c-type attributes -- slot-spec )
 348     [ struct-slot-spec new ] 3dip
 349     [ >>name ]
 350     [ [ >>type ] [ struct-slot-class >>class ] bi ]
 351     [ [ dup empty? ] [ peel-off-struct-attributes ] until drop ] tri* ;
 352
 353 <PRIVATE
 354 : parse-struct-slot ( -- slot )
 355     scan scan-c-type \ } parse-until <struct-slot-spec> ;
 356
 357 : parse-struct-slots ( slots -- slots' more? )
 358     scan {
 359         { ";" [ f ] }
 360         { "{" [ parse-struct-slot suffix! t ] }
 361         { f [ unexpected-eof ] }
 362         [ invalid-struct-slot ]
 363     } case ;
 364
 365 : parse-struct-definition ( -- class slots )
 366     CREATE-CLASS 8 <vector> [ parse-struct-slots ] [ ] while >array
 367     dup [ name>> ] map check-duplicate-slots ;
 368 PRIVATE>
 369
 370 SYNTAX: STRUCT:
 371     parse-struct-definition define-struct-class ;
 372 SYNTAX: UNION-STRUCT:
 373     parse-struct-definition define-union-struct-class ;
 374
 375 SYNTAX: S{
 376     scan-word dup struct-slots parse-tuple-literal-slots suffix! ;
 377
 378 SYNTAX: S@
 379     scan-word scan-object swap memory>struct suffix! ;
 380
 381 ! functor support
 382
 383 <PRIVATE
 384 : scan-c-type` ( -- c-type/param )
 385     scan dup "{" = [ drop \ } parse-until >array ] [ search ] if ;
 386
 387 : parse-struct-slot` ( accum -- accum )
 388     scan-string-param scan-c-type` \ } parse-until
 389     [ <struct-slot-spec> suffix! ] 3curry append! ;
 390
 391 : parse-struct-slots` ( accum -- accum more? )
 392     scan {
 393         { ";" [ f ] }
 394         { "{" [ parse-struct-slot` t ] }
 395         [ invalid-struct-slot ]
 396     } case ;
 397 PRIVATE>
 398
 399 FUNCTOR-SYNTAX: STRUCT:
 400     scan-param suffix!
 401     [ 8 <vector> ] append!
 402     [ parse-struct-slots` ] [ ] while
 403     [ >array define-struct-class ] append! ;
 404
 405 USING: vocabs vocabs.loader ;
 406
 407 "prettyprint" vocab [ "classes.struct.prettyprint" require ] when