basis/colors/hsv/hsv.factor

   1 ! Copyright (C) 2008 Eduardo Cavazos.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays colors combinators fry kernel locals
   4 math math.functions random sequences sorting ;
   5 IN: colors.hsv
   6
   7 ! h [0,360)
   8 ! s [0,1]
   9 ! v [0,1]
  10 TUPLE: hsva < color
  11 { hue read-only }
  12 { saturation read-only }
  13 { value read-only }
  14 { alpha read-only } ;
  15
  16 C: <hsva> hsva
  17
  18 <PRIVATE
  19
  20 : Hi ( hsv -- Hi ) hue>> 60 / floor 6 mod >integer ; inline
  21
  22 : f ( hsv -- f ) [ hue>> 60 / ] [ Hi ] bi - ; inline
  23
  24 : p ( hsv -- p ) [ saturation>> 1 swap - ] [ value>> ] bi * ; inline
  25
  26 : q ( hsv -- q ) [ [ f ] [ saturation>> ] bi * 1 swap - ] [ value>> ] bi * ; inline
  27
  28 : t ( hsv -- t ) [ [ f 1 swap - ] [ saturation>> ] bi * 1 swap - ] [ value>> ] bi * ; inline
  29
  30 PRIVATE>
  31
  32 M: hsva >rgba
  33     [
  34         dup Hi
  35         {
  36             { 0 [ [ value>> ] [ t ] [ p ] tri ] }
  37             { 1 [ [ q ] [ value>> ] [ p ] tri ] }
  38             { 2 [ [ p ] [ value>> ] [ t ] tri ] }
  39             { 3 [ [ p ] [ q ] [ value>> ] tri ] }
  40             { 4 [ [ t ] [ p ] [ value>> ] tri ] }
  41             { 5 [ [ value>> ] [ p ] [ q ] tri ] }
  42         } case
  43     ] [ alpha>> ] bi <rgba> ; inline
  44
  45 <PRIVATE
  46
  47 : sort-triple ( a b c -- d e f )
  48     sort-pair [ sort-pair ] dip sort-pair ;
  49
  50 PRIVATE>
  51
  52 GENERIC: >hsva ( color -- hsva )
  53
  54 M: object >hsva >rgba >hsva ;
  55
  56 M: hsva >hsva ; inline
  57
  58 M:: rgba >hsva ( rgba -- hsva )
  59     rgba >rgba-components :> ( r g b a )
  60     r g b sort-triple :> ( z y x )
  61     x z = x zero? or [ 0 0 x a <hsva> ] [
  62         {
  63             { [ r x = g z = and ] [ 5 x b - x z - / + ] }
  64             { [ r x = g z > and ] [ 1 x g - x z - / - ] }
  65             { [ g x = b z = and ] [ 1 x r - x z - / + ] }
  66             { [ g x = b z > and ] [ 3 x b - x z - / - ] }
  67             { [ b x = r z = and ] [ 3 x g - x z - / + ] }
  68             { [ b x = r z > and ] [ 5 x r - x z - / - ] }
  69         } cond 6 / 360 * x z - x / x a <hsva>
  70     ] if ;
  71
  72 : complimentary-color ( color -- color' )
  73     >hsva {
  74         [ hue>> 180 + 360 mod ]
  75         [ saturation>> ]
  76         [ value>> ]
  77         [ alpha>> ]
  78     } cleave <hsva> ;
  79
  80 : golden-rainbow ( num-colors saturation luminance -- colors )
  81     [ random-unit ] 3dip '[
  82         0.618033988749895 + 1.0 mod dup _ _ 1.0 <hsva>
  83     ] replicate nip ;