basis/command-line/command-line.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.strings assocs continuations fry init
   4 io.encodings.utf8 io.files io.pathnames kernel kernel.private
   5 namespaces parser parser.notes sequences source-files
   6 source-files.errors splitting system vocabs.loader ;
   7 IN: command-line
   8
   9 SYMBOL: user-init-errors
  10 SYMBOL: +user-init-error+
  11
  12 TUPLE: user-init-error error path line# asset ;
  13
  14 : <user-init-error> ( error -- error' )
  15     [ ] [ error-file ] [ error-line ] tri
  16     f user-init-error boa ; inline
  17 M: user-init-error error-file path>> ;
  18 M: user-init-error error-line line#>> ;
  19 M: user-init-error error-type drop +user-init-error+ ;
  20
  21 SYMBOL: script
  22 SYMBOL: command-line
  23
  24 : (command-line) ( -- args )
  25     OBJ-ARGS special-object sift [ alien>native-string ] map ;
  26
  27 : try-user-init ( file -- )
  28     "user-init" get swap '[
  29         _ [ ?run-file ] [
  30             <user-init-error>
  31             swap user-init-errors get set-at
  32             notify-error-observers
  33         ] recover
  34     ] when ;
  35
  36 : run-bootstrap-init ( -- )
  37     "~/.factor-boot-rc" try-user-init ;
  38
  39 : run-user-init ( -- )
  40     "~/.factor-rc" try-user-init ;
  41
  42 : load-vocab-roots ( -- )
  43     "user-init" get [
  44         "~/.factor-roots" dup file-exists? [
  45             utf8 file-lines harvest [ add-vocab-root ] each
  46         ] [ drop ] if
  47         "roots" get [
  48             os windows? ";" ":" ?
  49             split [ add-vocab-root ] each
  50         ] when*
  51     ] when ;
  52
  53 : var-param ( name value -- ) swap set-global ;
  54
  55 : bool-param ( name -- ) "no-" ?head not var-param ;
  56
  57 : param ( param -- )
  58     "=" split1 [ var-param ] [ bool-param ] if* ;
  59
  60 : run-script ( file -- )
  61     t parser-quiet? [
  62         [ run-file ]
  63         [ path>source-file main>> [ execute( -- ) ] when* ] bi
  64     ] with-variable ;
  65
  66 : (parse-command-line) ( args -- )
  67     [
  68         unclip "-" ?head [
  69             [ CHAR: - = ] trim-head
  70             [ param ] [ "run=" head? ] bi
  71             [ command-line set ]
  72             [ (parse-command-line) ] if
  73         ] [
  74             script set command-line set
  75         ] if
  76     ] unless-empty ;
  77
  78 : parse-command-line ( args -- )
  79     command-line off
  80     script off
  81     rest (parse-command-line) ;
  82
  83 SYMBOL: main-vocab-hook
  84
  85 : main-vocab ( -- vocab )
  86     embedded? [
  87         "alien.remote-control"
  88     ] [
  89         main-vocab-hook get [ call( -- vocab ) ] [ "listener" ] if*
  90     ] if ;
  91
  92 : default-cli-args ( -- )
  93     [
  94         "e" off
  95         "user-init" on
  96         main-vocab "run" set
  97     ] with-global ;
  98
  99 [
 100     H{ } user-init-errors set-global
 101     default-cli-args
 102 ] "command-line" add-startup-hook
 103
 104 { "debugger" "command-line" } "command-line.debugger" require-when