basis/compiler/cfg/build-stack-frame/build-stack-frame.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces accessors math.order assocs kernel sequences
   4 combinators classes words cpu.architecture layouts compiler.cfg
   5 compiler.cfg.rpo compiler.cfg.instructions
   6 compiler.cfg.registers compiler.cfg.stack-frame ;
   7 IN: compiler.cfg.build-stack-frame
   8
   9 SYMBOL: frame-required?
  10
  11 GENERIC: compute-stack-frame* ( insn -- )
  12
  13 : request-stack-frame ( stack-frame -- )
  14     frame-required? on
  15     stack-frame [ max-stack-frame ] change ;
  16
  17 UNION: stack-frame-insn
  18     ##alien-invoke
  19     ##alien-indirect
  20     ##alien-assembly
  21     ##alien-callback ;
  22
  23 M: stack-frame-insn compute-stack-frame*
  24     stack-frame>> request-stack-frame ;
  25
  26 M: ##call compute-stack-frame* drop frame-required? on ;
  27
  28 M: ##call-gc compute-stack-frame*
  29     drop
  30     frame-required? on
  31     stack-frame new t >>calls-vm? request-stack-frame ;
  32
  33 M: insn compute-stack-frame*
  34     class "frame-required?" word-prop
  35     [ frame-required? on ] when ;
  36
  37 : initial-stack-frame ( -- stack-frame )
  38     stack-frame new cfg get spill-area-size>> >>spill-area-size ;
  39
  40 : compute-stack-frame ( insns -- )
  41     frame-required? off
  42     initial-stack-frame stack-frame set
  43     [ instructions>> [ compute-stack-frame* ] each ] each-basic-block
  44     stack-frame get dup stack-frame-size >>total-size drop ;
  45
  46 : build-stack-frame ( cfg -- cfg )
  47     [
  48         [ compute-stack-frame ]
  49         [
  50             frame-required? get stack-frame get f ?
  51             >>stack-frame
  52         ] bi
  53     ] with-scope ;