basis/compiler/cfg/build-stack-frame/build-stack-frame.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces accessors math math.order assocs kernel sequences
   4 combinators classes words system cpu.architecture layouts compiler.cfg
   5 compiler.cfg.rpo compiler.cfg.instructions
   6 compiler.cfg.registers compiler.cfg.stack-frame ;
   7 IN: compiler.cfg.build-stack-frame
   8
   9 SYMBOL: frame-required?
  10
  11 GENERIC: compute-stack-frame* ( insn -- )
  12
  13 : request-stack-frame ( stack-frame -- )
  14     frame-required? on
  15     stack-frame [ max-stack-frame ] change ;
  16
  17 M: ##stack-frame compute-stack-frame*
  18     stack-frame>> request-stack-frame ;
  19
  20 : frame-required ( -- ) frame-required? on ;
  21
  22 : vm-frame-required ( -- )
  23     frame-required
  24     stack-frame new vm-stack-space >>params request-stack-frame ;
  25
  26 M: ##call-gc compute-stack-frame* drop vm-frame-required ;
  27 M: ##box compute-stack-frame* drop vm-frame-required ;
  28 M: ##unbox compute-stack-frame* drop vm-frame-required ;
  29 M: ##box-long-long compute-stack-frame* drop vm-frame-required ;
  30 M: ##begin-callback compute-stack-frame* drop vm-frame-required ;
  31 M: ##end-callback compute-stack-frame* drop vm-frame-required ;
  32 M: ##unary-float-function compute-stack-frame* drop vm-frame-required ;
  33 M: ##binary-float-function compute-stack-frame* drop vm-frame-required ;
  34
  35 M: ##call compute-stack-frame* drop frame-required ;
  36 M: ##alien-callback compute-stack-frame* drop frame-required ;
  37 M: ##spill compute-stack-frame* drop frame-required ;
  38 M: ##reload compute-stack-frame* drop frame-required ;
  39
  40 M: ##float>integer compute-stack-frame*
  41     drop integer-float-needs-stack-frame? [ frame-required ] when ;
  42
  43 M: ##integer>float compute-stack-frame*
  44     drop integer-float-needs-stack-frame? [ frame-required ] when ;
  45
  46 M: insn compute-stack-frame* drop ;
  47
  48 : initial-stack-frame ( -- stack-frame )
  49     stack-frame new cfg get spill-area-size>> >>spill-area-size ;
  50
  51 : compute-stack-frame ( cfg -- )
  52     initial-stack-frame stack-frame set
  53     [ spill-area-size>> 0 > frame-required? set ]
  54     [ [ instructions>> [ compute-stack-frame* ] each ] each-basic-block ] bi
  55     stack-frame get dup stack-frame-size >>total-size drop ;
  56
  57 : build-stack-frame ( cfg -- cfg )
  58     [
  59         [ compute-stack-frame ]
  60         [
  61             frame-required? get stack-frame get f ?
  62             >>stack-frame
  63         ] bi
  64     ] with-scope ;