basis/compiler/cfg/build-stack-frame/build-stack-frame.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces accessors math.order assocs kernel sequences
   4 combinators classes words cpu.architecture layouts compiler.cfg
   5 compiler.cfg.rpo compiler.cfg.instructions
   6 compiler.cfg.registers compiler.cfg.stack-frame ;
   7 IN: compiler.cfg.build-stack-frame
   8
   9 SYMBOL: frame-required?
  10
  11 GENERIC: compute-stack-frame* ( insn -- )
  12
  13 : request-stack-frame ( stack-frame -- )
  14     frame-required? on
  15     stack-frame [ max-stack-frame ] change ;
  16
  17 M: ##stack-frame compute-stack-frame*
  18     stack-frame>> request-stack-frame ;
  19
  20 M: ##call compute-stack-frame* drop frame-required? on ;
  21
  22 M: ##call-gc compute-stack-frame*
  23     drop
  24     frame-required? on
  25     stack-frame new t >>calls-vm? request-stack-frame ;
  26
  27 M: insn compute-stack-frame*
  28     class "frame-required?" word-prop
  29     [ frame-required? on ] when ;
  30
  31 : initial-stack-frame ( -- stack-frame )
  32     stack-frame new cfg get spill-area-size>> >>spill-area-size ;
  33
  34 : compute-stack-frame ( insns -- )
  35     frame-required? off
  36     initial-stack-frame stack-frame set
  37     [ instructions>> [ compute-stack-frame* ] each ] each-basic-block
  38     stack-frame get dup stack-frame-size >>total-size drop ;
  39
  40 : build-stack-frame ( cfg -- cfg )
  41     [
  42         [ compute-stack-frame ]
  43         [
  44             frame-required? get stack-frame get f ?
  45             >>stack-frame
  46         ] bi
  47     ] with-scope ;