basis/compiler/cfg/linear-scan/assignment/assignment.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel math assocs namespaces sequences heaps
   4 fry make combinators combinators.short-circuit sets locals arrays
   5 cpu.architecture layouts
   6 compiler.cfg
   7 compiler.cfg.def-use
   8 compiler.cfg.liveness
   9 compiler.cfg.registers
  10 compiler.cfg.instructions
  11 compiler.cfg.renaming.functor
  12 compiler.cfg.linearization.order
  13 compiler.cfg.linear-scan.allocation
  14 compiler.cfg.linear-scan.allocation.state
  15 compiler.cfg.linear-scan.live-intervals ;
  16 FROM: namespaces => set ;
  17 IN: compiler.cfg.linear-scan.assignment
  18
  19 ! This contains both active and inactive intervals; any interval
  20 ! such that start <= insn# <= end is in this set.
  21 SYMBOL: pending-interval-heap
  22 SYMBOL: pending-interval-assoc
  23
  24 : add-pending ( live-interval -- )
  25     [ dup end>> pending-interval-heap get heap-push ]
  26     [ [ reg>> ] [ vreg>> ] bi pending-interval-assoc get set-at ]
  27     bi ;
  28
  29 : remove-pending ( live-interval -- )
  30     vreg>> pending-interval-assoc get delete-at ;
  31
  32 ERROR: bad-vreg vreg ;
  33
  34 : (vreg>reg) ( vreg pending -- reg )
  35     ! If a live vreg is not in the pending set, then it must
  36     ! have been spilled.
  37     ?at [ spill-slots get ?at [ ] [ bad-vreg ] if ] unless ;
  38
  39 : vreg>reg ( vreg -- reg )
  40     pending-interval-assoc get (vreg>reg) ;
  41
  42 : vregs>regs ( vregs -- assoc )
  43     dup assoc-empty? [
  44         pending-interval-assoc get
  45         '[ _ (vreg>reg) ] assoc-map
  46     ] unless ;
  47
  48 ! Minheap of live intervals which still need a register allocation
  49 SYMBOL: unhandled-intervals
  50
  51 : add-unhandled ( live-interval -- )
  52     dup start>> unhandled-intervals get heap-push ;
  53
  54 : init-unhandled ( live-intervals -- )
  55     [ add-unhandled ] each ;
  56
  57 ! Mapping from basic blocks to values which are live at the start
  58 SYMBOL: register-live-ins
  59
  60 ! Mapping from basic blocks to values which are live at the end
  61 SYMBOL: register-live-outs
  62
  63 : init-assignment ( live-intervals -- )
  64     <min-heap> pending-interval-heap set
  65     H{ } clone pending-interval-assoc set
  66     <min-heap> unhandled-intervals set
  67     H{ } clone register-live-ins set
  68     H{ } clone register-live-outs set
  69     init-unhandled ;
  70
  71 : spill-rep ( live-interval -- rep ) vreg>> rep-of ;
  72
  73 : insert-spill ( live-interval -- )
  74     [ reg>> ] [ spill-rep ] [ spill-to>> ] tri ##spill ;
  75
  76 : handle-spill ( live-interval -- )
  77     dup spill-to>> [ insert-spill ] [ drop ] if ;
  78
  79 : expire-interval ( live-interval -- )
  80     [ remove-pending ] [ handle-spill ] bi ;
  81
  82 : (expire-old-intervals) ( n heap -- )
  83     dup heap-empty? [ 2drop ] [
  84         2dup heap-peek nip <= [ 2drop ] [
  85             dup heap-pop drop expire-interval
  86             (expire-old-intervals)
  87         ] if
  88     ] if ;
  89
  90 : expire-old-intervals ( n -- )
  91     pending-interval-heap get (expire-old-intervals) ;
  92
  93 : reload-rep ( live-interval -- rep ) vreg>> rep-of ;
  94
  95 : insert-reload ( live-interval -- )
  96     [ reg>> ] [ reload-rep ] [ reload-from>> ] tri ##reload ;
  97
  98 : insert-reload? ( live-interval -- ? )
  99     ! Don't insert a reload if the register will be written to
 100     ! before being read again.
 101     {
 102         [ reload-from>> ]
 103         [ first-use type>> +use+ eq? ]
 104     } 1&& ;
 105
 106 : handle-reload ( live-interval -- )
 107     dup insert-reload? [ insert-reload ] [ drop ] if ;
 108
 109 : activate-interval ( live-interval -- )
 110     [ add-pending ] [ handle-reload ] bi ;
 111
 112 : (activate-new-intervals) ( n heap -- )
 113     dup heap-empty? [ 2drop ] [
 114         2dup heap-peek nip = [
 115             dup heap-pop drop activate-interval
 116             (activate-new-intervals)
 117         ] [ 2drop ] if
 118     ] if ;
 119
 120 : activate-new-intervals ( n -- )
 121     unhandled-intervals get (activate-new-intervals) ;
 122
 123 : prepare-insn ( n -- )
 124     [ expire-old-intervals ] [ activate-new-intervals ] bi ;
 125
 126 GENERIC: assign-registers-in-insn ( insn -- )
 127
 128 RENAMING: assign [ vreg>reg ] [ vreg>reg ] [ vreg>reg ]
 129
 130 M: vreg-insn assign-registers-in-insn
 131     [ assign-insn-defs ] [ assign-insn-uses ] [ assign-insn-temps ] tri ;
 132
 133 M: ##call-gc assign-registers-in-insn
 134     dup call-next-method
 135     [ [ vreg>reg ] map ] change-gc-roots drop ;
 136
 137 M: insn assign-registers-in-insn drop ;
 138
 139 : begin-block ( bb -- )
 140     dup basic-block set
 141     dup block-from activate-new-intervals
 142     [ live-in vregs>regs ] keep register-live-ins get set-at ;
 143
 144 : end-block ( bb -- )
 145     [ live-out vregs>regs ] keep register-live-outs get set-at ;
 146
 147 : vreg-at-start ( vreg bb -- state )
 148     register-live-ins get at ?at [ bad-vreg ] unless ;
 149
 150 : vreg-at-end ( vreg bb -- state )
 151     register-live-outs get at ?at [ bad-vreg ] unless ;
 152
 153 :: assign-registers-in-block ( bb -- )
 154     bb [
 155         [
 156             bb begin-block
 157             [
 158                 {
 159                     [ insn#>> 1 - prepare-insn ]
 160                     [ insn#>> prepare-insn ]
 161                     [ assign-registers-in-insn ]
 162                     [ , ]
 163                 } cleave
 164             ] each
 165             bb end-block
 166         ] V{ } make
 167     ] change-instructions drop ;
 168
 169 : assign-registers ( live-intervals cfg -- )
 170     [ init-assignment ] dip
 171     linearization-order [ assign-registers-in-block ] each ;