basis/compiler/cfg/linear-scan/assignment/assignment.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators compiler.cfg
   4 compiler.cfg.linearization compiler.cfg.liveness compiler.cfg.registers
   5 compiler.cfg.instructions compiler.cfg.linear-scan.allocation.state
   6 compiler.cfg.linear-scan.live-intervals compiler.cfg.renaming.functor
   7 compiler.cfg.ssa.destruction.leaders cpu.architecture
   8 fry heaps kernel locals make math namespaces sequences sets ;
   9 FROM: namespaces => set ;
  10 IN: compiler.cfg.linear-scan.assignment
  11
  12 ! This contains both active and inactive intervals; any interval
  13 ! such that start <= insn# <= end is in this set.
  14 SYMBOL: pending-interval-heap
  15 SYMBOL: pending-interval-assoc
  16
  17 : add-pending ( live-interval -- )
  18     [ dup end>> pending-interval-heap get heap-push ]
  19     [ [ reg>> ] [ vreg>> ] bi pending-interval-assoc get set-at ]
  20     bi ;
  21
  22 : remove-pending ( live-interval -- )
  23     vreg>> pending-interval-assoc get delete-at ;
  24
  25 :: vreg>reg ( vreg -- reg )
  26     vreg leader :> leader
  27     leader pending-interval-assoc get at* [
  28         drop leader vreg rep-of lookup-spill-slot
  29     ] unless ;
  30
  31 ERROR: not-spilled-error vreg ;
  32
  33 : vreg>spill-slot ( vreg -- spill-slot )
  34     dup vreg>reg dup spill-slot? [ nip ] [ drop leader not-spilled-error ] if ;
  35
  36 : vregs>regs ( vregs -- assoc )
  37     [ f ] [ [ dup vreg>reg ] H{ } map>assoc ] if-empty ;
  38
  39 SYMBOL: unhandled-intervals
  40
  41 : init-unhandled ( live-intervals -- unhandled-intervals  )
  42     [ dup start>> swap 2array ] map >min-heap  ;
  43
  44 ! Liveness info is used by resolve pass
  45 SYMBOL: machine-live-ins
  46
  47 : machine-live-in ( bb -- assoc )
  48     machine-live-ins get at ;
  49
  50 : compute-live-in ( bb -- )
  51     [ live-in keys vregs>regs ] keep machine-live-ins get set-at ;
  52
  53 ! Mapping from basic blocks to predecessors to values which are
  54 ! live on a particular incoming edge
  55 SYMBOL: machine-edge-live-ins
  56
  57 : machine-edge-live-in ( predecessor bb -- assoc )
  58     machine-edge-live-ins get at at ;
  59
  60 : compute-edge-live-in ( bb -- )
  61     [ edge-live-ins get at [ keys vregs>regs ] assoc-map ] keep
  62     machine-edge-live-ins get set-at ;
  63
  64 SYMBOL: machine-live-outs
  65
  66 : machine-live-out ( bb -- assoc )
  67     machine-live-outs get at ;
  68
  69 : compute-live-out ( bb -- )
  70     [ live-out keys vregs>regs ] keep machine-live-outs get set-at ;
  71
  72 : init-assignment ( live-intervals -- )
  73     init-unhandled unhandled-intervals set
  74     <min-heap> pending-interval-heap set
  75     H{ } clone pending-interval-assoc set
  76     H{ } clone machine-live-ins set
  77     H{ } clone machine-edge-live-ins set
  78     H{ } clone machine-live-outs set ;
  79
  80 : heap-pop-while ( heap quot: ( key -- ? ) -- values )
  81     '[ dup heap-empty? [ f f ] [ dup heap-peek @ ] if ]
  82     [ over heap-pop* ] produce 2nip ; inline
  83
  84 : insert-spill ( live-interval -- )
  85     [ reg>> ] [ spill-rep>> ] [ spill-to>> ] tri ##spill, ;
  86
  87 : handle-spill ( live-interval -- )
  88     dup spill-to>> [ insert-spill ] [ drop ] if ;
  89
  90 : expire-interval ( live-interval -- )
  91     [ remove-pending ] [ handle-spill ] bi ;
  92
  93 : expire-old-intervals ( n -- )
  94     pending-interval-heap get swap '[ _ < ] heap-pop-while
  95     [ expire-interval ] each ;
  96
  97 : insert-reload ( live-interval -- )
  98     [ reg>> ] [ reload-rep>> ] [ reload-from>> ] tri ##reload, ;
  99
 100 : handle-reload ( live-interval -- )
 101     dup reload-from>> [ insert-reload ] [ drop ] if ;
 102
 103 : activate-interval ( live-interval -- )
 104     [ add-pending ] [ handle-reload ] bi ;
 105
 106 : activate-new-intervals ( n -- )
 107     unhandled-intervals get swap '[ _ = ] heap-pop-while
 108     [ activate-interval ] each ;
 109
 110 : prepare-insn ( n -- )
 111     [ expire-old-intervals ] [ activate-new-intervals ] bi ;
 112
 113 GENERIC: assign-registers-in-insn ( insn -- )
 114
 115 RENAMING: assign [ vreg>reg ] [ vreg>reg ] [ vreg>reg ]
 116
 117 M: vreg-insn assign-registers-in-insn
 118     [ assign-insn-defs ] [ assign-insn-uses ] [ assign-insn-temps ] tri ;
 119
 120 : assign-gc-roots ( gc-map -- )
 121     [ [ vreg>spill-slot ] map ] change-gc-roots drop ;
 122
 123 : assign-derived-roots ( gc-map -- )
 124     [ [ [ vreg>spill-slot ] bi@ ] assoc-map ] change-derived-roots drop ;
 125
 126 M: gc-map-insn assign-registers-in-insn
 127     [ [ assign-insn-defs ] [ assign-insn-uses ] [ assign-insn-temps ] tri ]
 128     [ gc-map>> [ assign-gc-roots ] [ assign-derived-roots ] bi ]
 129     bi ;
 130
 131 M: insn assign-registers-in-insn drop ;
 132
 133 : begin-block ( bb -- )
 134     {
 135         [ basic-block set ]
 136         [ block-from activate-new-intervals ]
 137         [ compute-edge-live-in ]
 138         [ compute-live-in ]
 139     } cleave ;
 140
 141 :: assign-registers-in-block ( bb -- )
 142     bb [
 143         [
 144             bb begin-block
 145             [
 146                 {
 147                     [ insn#>> 1 - prepare-insn ]
 148                     [ insn#>> prepare-insn ]
 149                     [ assign-registers-in-insn ]
 150                     [ , ]
 151                 } cleave
 152             ] each
 153             bb compute-live-out
 154         ] V{ } make
 155     ] change-instructions drop ;
 156
 157 : assign-registers ( live-intervals cfg -- )
 158     [ init-assignment ] dip
 159     linearization-order [ kill-block?>> not ] filter
 160     [ assign-registers-in-block ] each ;