basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs binary-search combinators
   4 compiler.cfg.def-use compiler.cfg.instructions
   5 compiler.cfg.linearization compiler.cfg.liveness
   6 compiler.cfg.registers compiler.cfg.ssa.destruction.leaders cpu.architecture
   7 fry kernel locals math math.intervals math.order namespaces sequences ;
   8 IN: compiler.cfg.linear-scan.live-intervals
   9
  10 TUPLE: live-range from to ;
  11
  12 C: <live-range> live-range
  13
  14 TUPLE: vreg-use n def-rep use-rep spill-slot? ;
  15
  16 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  17
  18 TUPLE: live-interval-state
  19 vreg
  20 reg spill-to spill-rep reload-from reload-rep
  21 start end ranges uses
  22 reg-class ;
  23
  24 : first-use ( live-interval -- use ) uses>> first ; inline
  25
  26 : last-use ( live-interval -- use ) uses>> last ; inline
  27
  28 : new-use ( insn# uses -- use )
  29     [ <vreg-use> dup ] dip push ;
  30
  31 : last-use? ( insn# uses -- use/f )
  32     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  33
  34 :: (add-use) ( insn# live-interval spill-slot? -- use )
  35     live-interval uses>> :> uses
  36     insn# uses last-use? [ insn# uses new-use ] unless*
  37     spill-slot? [ t >>spill-slot? ] when ;
  38
  39 GENERIC: covers? ( insn# obj -- ? )
  40
  41 M: f covers? 2drop f ;
  42
  43 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  44
  45 M: live-interval-state covers? ( insn# live-interval -- ? )
  46     ranges>>
  47     dup length 4 <= [
  48         [ covers? ] with any?
  49     ] [
  50         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  51         covers?
  52     ] if ;
  53
  54 : (find-use) ( insn# live-interval -- vreg-use )
  55     uses>> [ n>> <=> ] with search nip ;
  56
  57 :: find-use ( insn# live-interval -- vreg-use )
  58     insn# live-interval (find-use)
  59     dup [ dup n>> insn# = [ drop f ] unless ] when ;
  60
  61 : add-new-range ( from to live-interval -- )
  62     [ <live-range> ] dip ranges>> push ;
  63
  64 : shorten-range ( n live-interval -- )
  65     dup ranges>> empty?
  66     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  67
  68 : extend-range ( from to live-range -- )
  69     ranges>> last
  70     [ max ] change-to
  71     [ min ] change-from
  72     drop ;
  73
  74 : extend-range? ( to live-interval -- ? )
  75     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  76
  77 : add-range ( from to live-interval -- )
  78     2dup extend-range?
  79     [ extend-range ] [ add-new-range ] if ;
  80
  81 : <live-interval> ( vreg reg-class -- live-interval )
  82     \ live-interval-state new
  83         V{ } clone >>uses
  84         V{ } clone >>ranges
  85         swap >>reg-class
  86         swap >>vreg ;
  87
  88 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  89
  90 : block-to ( bb -- n ) instructions>> last insn#>> ;
  91
  92 SYMBOLS: from to ;
  93
  94 SYMBOL: live-intervals
  95
  96 : live-interval ( vreg -- live-interval )
  97     leader live-intervals get
  98     [ dup rep-of reg-class-of <live-interval> ] cache ;
  99
 100 GENERIC: compute-live-intervals* ( insn -- )
 101
 102 M: insn compute-live-intervals* drop ;
 103
 104 :: record-def ( vreg n spill-slot? -- )
 105     vreg live-interval :> live-interval
 106
 107     n live-interval shorten-range
 108     n live-interval spill-slot? (add-use) vreg rep-of >>def-rep drop ;
 109
 110 :: record-use ( vreg n spill-slot? -- )
 111     vreg live-interval :> live-interval
 112
 113     from get n live-interval add-range
 114     n live-interval spill-slot? (add-use) vreg rep-of >>use-rep drop ;
 115
 116 :: record-temp ( vreg n -- )
 117     vreg live-interval :> live-interval
 118
 119     n n live-interval add-range
 120     n live-interval f (add-use) vreg rep-of >>def-rep drop ;
 121
 122 M: vreg-insn compute-live-intervals* ( insn -- )
 123     dup insn#>>
 124     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 125     [ [ uses-vregs ] dip '[ _ f record-use ] each ]
 126     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 127     2tri ;
 128
 129 ! Extend lifetime intervals of base pointers, so that their
 130 ! values are available even if the base pointer is never used
 131 ! again.
 132
 133 GENERIC: uses-vregs* ( insn -- seq )
 134
 135 M: gc-map-insn uses-vregs*
 136     [ uses-vregs ] [ gc-map>> derived-roots>> values ] bi append ;
 137
 138 M: vreg-insn uses-vregs* uses-vregs ;
 139
 140 M: insn uses-vregs* drop f ;
 141
 142 M: clobber-insn compute-live-intervals* ( insn -- )
 143     dup insn#>>
 144     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 145     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 146     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 147     2tri ;
 148
 149 M: hairy-clobber-insn compute-live-intervals* ( insn -- )
 150     dup insn#>>
 151     [ [ defs-vregs ] dip '[ _ t record-def ] each ]
 152     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 153     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 154     2tri ;
 155
 156 : handle-live-out ( bb -- )
 157     [ from get to get ] dip live-out keys
 158     [ live-interval add-range ] 2with each ;
 159
 160 : compute-live-intervals-step ( bb -- )
 161     {
 162         [ block-from from set ]
 163         [ block-to to set ]
 164         [ handle-live-out ]
 165         [ instructions>> <reversed> [ compute-live-intervals* ] each ]
 166     } cleave ;
 167
 168 : compute-start/end ( live-interval -- )
 169     dup ranges>> [ first from>> ] [ last to>> ] bi
 170     [ >>start ] [ >>end ] bi* drop ;
 171
 172 ERROR: bad-live-interval live-interval ;
 173
 174 : check-start ( live-interval -- )
 175     dup start>> -1 = [ throw-bad-live-interval ] [ drop ] if ;
 176
 177 : finish-live-intervals ( live-intervals -- )
 178     [
 179         {
 180             [ [ { } like reverse! ] change-ranges drop ]
 181             [ [ { } like reverse! ] change-uses drop ]
 182             [ compute-start/end ]
 183             [ check-start ]
 184         } cleave
 185     ] each ;
 186
 187 TUPLE: sync-point n keep-dst? ;
 188
 189 C: <sync-point> sync-point
 190
 191 GENERIC: insn>sync-point ( insn -- sync-point/f )
 192
 193 M: hairy-clobber-insn insn>sync-point
 194     insn#>> f <sync-point> ;
 195
 196 M: clobber-insn insn>sync-point
 197     insn#>> t <sync-point> ;
 198
 199 M: insn insn>sync-point drop f ;
 200
 201 : cfg>sync-points ( cfg -- sync-points )
 202     cfg>insns [ insn>sync-point ] map sift ;
 203
 204 : cfg>live-intervals ( cfg -- live-intervals )
 205     H{ } clone live-intervals set
 206     linearization-order <reversed> [ compute-live-intervals-step ] each
 207     live-intervals get values dup finish-live-intervals ;
 208
 209 : compute-live-intervals ( cfg -- intervals/sync-points )
 210     [ cfg>live-intervals ] [ cfg>sync-points ] bi append ;
 211
 212 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 213     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 214
 215 : intersect-live-range ( range1 range2 -- n/f )
 216     2dup [ from>> ] bi@ > [ swap ] when
 217     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 218
 219 : intersect-live-ranges ( ranges1 ranges2 -- n )
 220     {
 221         { [ over empty? ] [ 2drop f ] }
 222         { [ dup empty? ] [ 2drop f ] }
 223         [
 224             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 225                 drop
 226                 2dup [ first from>> ] bi@ <
 227                 [ [ rest-slice ] dip ] [ rest-slice ] if
 228                 intersect-live-ranges
 229             ] if
 230         ]
 231     } cond ;
 232
 233 : intervals-intersect? ( interval1 interval2 -- ? )
 234     relevant-ranges intersect-live-ranges >boolean ; inline