basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors locals sequences math
   4 math.order fry combinators binary-search
   5 compiler.cfg.instructions
   6 compiler.cfg.registers
   7 compiler.cfg.def-use
   8 compiler.cfg.liveness
   9 compiler.cfg.linearization
  10 compiler.cfg.ssa.destruction
  11 compiler.cfg
  12 cpu.architecture ;
  13 IN: compiler.cfg.linear-scan.live-intervals
  14
  15 TUPLE: live-range from to ;
  16
  17 C: <live-range> live-range
  18
  19 TUPLE: vreg-use n def-rep use-rep ;
  20
  21 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  22
  23 TUPLE: live-interval
  24 vreg
  25 reg spill-to spill-rep reload-from reload-rep
  26 start end ranges uses
  27 reg-class ;
  28
  29 : first-use ( live-interval -- use ) uses>> first ; inline
  30
  31 : last-use ( live-interval -- use ) uses>> last ; inline
  32
  33 : new-use ( insn# uses -- use )
  34     [ <vreg-use> dup ] dip push ;
  35
  36 : last-use? ( insn# uses -- use/f )
  37     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  38
  39 : (add-use) ( insn# live-interval -- use )
  40     uses>> 2dup last-use? dup [ 2nip ] [ drop new-use ] if ;
  41
  42 GENERIC: covers? ( insn# obj -- ? )
  43
  44 M: f covers? 2drop f ;
  45
  46 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  47
  48 M: live-interval covers? ( insn# live-interval -- ? )
  49     ranges>>
  50     dup length 4 <= [
  51         [ covers? ] with any?
  52     ] [
  53         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  54         covers?
  55     ] if ;
  56
  57 :: find-use ( insn# live-interval -- vreg-use )
  58     insn# live-interval uses>> [ n>> <=> ] with search nip
  59     dup [ dup n>> insn# = [ drop f ] unless ] when ;
  60
  61 : add-new-range ( from to live-interval -- )
  62     [ <live-range> ] dip ranges>> push ;
  63
  64 : shorten-range ( n live-interval -- )
  65     dup ranges>> empty?
  66     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  67
  68 : extend-range ( from to live-range -- )
  69     ranges>> last
  70     [ max ] change-to
  71     [ min ] change-from
  72     drop ;
  73
  74 : extend-range? ( to live-interval -- ? )
  75     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  76
  77 : add-range ( from to live-interval -- )
  78     2dup extend-range?
  79     [ extend-range ] [ add-new-range ] if ;
  80
  81 : <live-interval> ( vreg reg-class -- live-interval )
  82     \ live-interval new
  83         V{ } clone >>uses
  84         V{ } clone >>ranges
  85         swap >>reg-class
  86         swap >>vreg ;
  87
  88 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  89
  90 : block-to ( bb -- n ) instructions>> last insn#>> ;
  91
  92 SYMBOLS: from to ;
  93
  94 ! Mapping from vreg to live-interval
  95 SYMBOL: live-intervals
  96
  97 : live-interval ( vreg -- live-interval )
  98     leader live-intervals get
  99     [ dup rep-of reg-class-of <live-interval> ] cache ;
 100
 101 GENERIC: compute-live-intervals* ( insn -- )
 102
 103 M: insn compute-live-intervals* drop ;
 104
 105 :: record-def ( vreg n -- )
 106     vreg live-interval :> live-interval
 107
 108     n live-interval shorten-range
 109     n live-interval (add-use) vreg rep-of >>def-rep drop ;
 110
 111 :: record-use ( vreg n -- )
 112     vreg live-interval :> live-interval
 113
 114     from get n live-interval add-range
 115     n live-interval (add-use) vreg rep-of >>use-rep drop ;
 116
 117 :: record-temp ( vreg n -- )
 118     vreg live-interval :> live-interval
 119
 120     n n live-interval add-range
 121     n live-interval (add-use) vreg rep-of >>def-rep drop ;
 122
 123 M: vreg-insn compute-live-intervals* ( insn -- )
 124     dup insn#>>
 125     [ [ defs-vreg ] dip '[ _ record-def ] when* ]
 126     [ [ uses-vregs ] dip '[ _ record-use ] each ]
 127     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 128     2tri ;
 129
 130 : handle-live-out ( bb -- )
 131     live-out dup assoc-empty? [ drop ] [
 132         [ from get to get ] dip keys
 133         [ live-interval add-range ] with with each
 134     ] if ;
 135
 136 ! A location where all registers have to be spilled
 137 TUPLE: sync-point n keep-dst? ;
 138
 139 C: <sync-point> sync-point
 140
 141 ! Sequence of sync points
 142 SYMBOL: sync-points
 143
 144 GENERIC: compute-sync-points* ( insn -- )
 145
 146 M: hairy-clobber-insn compute-sync-points*
 147     insn#>> f <sync-point> sync-points get push ;
 148
 149 M: clobber-insn compute-sync-points*
 150     insn#>> t <sync-point> sync-points get push ;
 151
 152 M: insn compute-sync-points* drop ;
 153
 154 : compute-live-intervals-step ( bb -- )
 155     {
 156         [ block-from from set ]
 157         [ block-to to set ]
 158         [ handle-live-out ]
 159         [
 160             instructions>> <reversed> [
 161                 [ compute-live-intervals* ]
 162                 [ compute-sync-points* ]
 163                 bi
 164             ] each
 165         ]
 166     } cleave ;
 167
 168 : init-live-intervals ( -- )
 169     H{ } clone live-intervals set
 170     V{ } clone sync-points set ;
 171
 172 : compute-start/end ( live-interval -- )
 173     dup ranges>> [ first from>> ] [ last to>> ] bi
 174     [ >>start ] [ >>end ] bi* drop ;
 175
 176 ERROR: bad-live-interval live-interval ;
 177
 178 : check-start ( live-interval -- )
 179     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 180
 181 : finish-live-intervals ( live-intervals -- seq )
 182     ! Since live intervals are computed in a backward order, we have
 183     ! to reverse some sequences, and compute the start and end.
 184     values dup [
 185         {
 186             [ [ { } like reverse! ] change-ranges drop ]
 187             [ [ { } like reverse! ] change-uses drop ]
 188             [ compute-start/end ]
 189             [ check-start ]
 190         } cleave
 191     ] each ;
 192
 193 : compute-live-intervals ( cfg -- live-intervals sync-points )
 194     init-live-intervals
 195     linearization-order <reversed> [ compute-live-intervals-step ] each
 196     live-intervals get finish-live-intervals
 197     sync-points get ;
 198
 199 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 200     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 201
 202 : intersect-live-range ( range1 range2 -- n/f )
 203     2dup [ from>> ] bi@ > [ swap ] when
 204     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 205
 206 : intersect-live-ranges ( ranges1 ranges2 -- n )
 207     {
 208         { [ over empty? ] [ 2drop f ] }
 209         { [ dup empty? ] [ 2drop f ] }
 210         [
 211             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 212                 drop
 213                 2dup [ first from>> ] bi@ <
 214                 [ [ rest-slice ] dip ] [ rest-slice ] if
 215                 intersect-live-ranges
 216             ] if
 217         ]
 218     } cond ;
 219
 220 : intervals-intersect? ( interval1 interval2 -- ? )
 221     relevant-ranges intersect-live-ranges >boolean ; inline