basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs binary-search combinators
   4 compiler.cfg.def-use compiler.cfg.instructions
   5 compiler.cfg.linearization compiler.cfg.liveness
   6 compiler.cfg.registers compiler.cfg.ssa.destruction.leaders cpu.architecture
   7 fry kernel locals math math.intervals math.order namespaces sequences ;
   8 IN: compiler.cfg.linear-scan.live-intervals
   9
  10 TUPLE: live-range from to ;
  11
  12 C: <live-range> live-range
  13
  14 TUPLE: vreg-use n def-rep use-rep spill-slot? ;
  15
  16 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  17
  18 TUPLE: live-interval-state
  19 vreg
  20 reg spill-to spill-rep reload-from reload-rep
  21 start end ranges uses
  22 reg-class ;
  23
  24 : first-use ( live-interval -- use ) uses>> first ; inline
  25
  26 : last-use ( live-interval -- use ) uses>> last ; inline
  27
  28 : new-use ( insn# uses -- use )
  29     [ <vreg-use> dup ] dip push ;
  30
  31 : last-use? ( insn# uses -- use/f )
  32     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  33
  34 :: (add-use) ( insn# live-interval spill-slot? -- use )
  35     live-interval uses>> :> uses
  36     insn# uses last-use? [ insn# uses new-use ] unless*
  37     spill-slot? [ t >>spill-slot? ] when ;
  38
  39 GENERIC: covers? ( insn# obj -- ? )
  40
  41 M: f covers? 2drop f ;
  42
  43 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  44
  45 M: live-interval-state covers? ( insn# live-interval -- ? )
  46     ranges>>
  47     dup length 4 <= [
  48         [ covers? ] with any?
  49     ] [
  50         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  51         covers?
  52     ] if ;
  53
  54 : (find-use) ( insn# live-interval -- vreg-use )
  55     uses>> [ n>> <=> ] with search nip ;
  56
  57 :: find-use ( insn# live-interval -- vreg-use )
  58     insn# live-interval (find-use)
  59     dup [ dup n>> insn# = [ drop f ] unless ] when ;
  60
  61 : add-new-range ( from to live-interval -- )
  62     [ <live-range> ] dip ranges>> push ;
  63
  64 : shorten-range ( n live-interval -- )
  65     dup ranges>> empty?
  66     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  67
  68 : extend-range ( from to live-range -- )
  69     ranges>> last
  70     [ max ] change-to
  71     [ min ] change-from
  72     drop ;
  73
  74 : extend-range? ( to live-interval -- ? )
  75     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  76
  77 : add-range ( from to live-interval -- )
  78     2dup extend-range?
  79     [ extend-range ] [ add-new-range ] if ;
  80
  81 : <live-interval> ( vreg reg-class -- live-interval )
  82     \ live-interval-state new
  83         V{ } clone >>uses
  84         V{ } clone >>ranges
  85         swap >>reg-class
  86         swap >>vreg ;
  87
  88 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  89
  90 : block-to ( bb -- n ) instructions>> last insn#>> ;
  91
  92 SYMBOLS: from to ;
  93
  94 SYMBOL: live-intervals
  95
  96 : live-interval ( vreg -- live-interval )
  97     leader live-intervals get
  98     [ dup rep-of reg-class-of <live-interval> ] cache ;
  99
 100 GENERIC: compute-live-intervals* ( insn -- )
 101
 102 M: insn compute-live-intervals* drop ;
 103
 104 :: record-def ( vreg n spill-slot? -- )
 105     vreg live-interval :> live-interval
 106
 107     n live-interval shorten-range
 108     n live-interval spill-slot? (add-use) vreg rep-of >>def-rep drop ;
 109
 110 :: record-use ( vreg n spill-slot? -- )
 111     vreg live-interval :> live-interval
 112
 113     from get n live-interval add-range
 114     n live-interval spill-slot? (add-use) vreg rep-of >>use-rep drop ;
 115
 116 :: record-temp ( vreg n -- )
 117     vreg live-interval :> live-interval
 118
 119     n n live-interval add-range
 120     n live-interval f (add-use) vreg rep-of >>def-rep drop ;
 121
 122 M: vreg-insn compute-live-intervals* ( insn -- )
 123     dup insn#>>
 124     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 125     [ [ uses-vregs ] dip '[ _ f record-use ] each ]
 126     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 127     2tri ;
 128
 129 ! Extend lifetime intervals of base pointers, so that their
 130 ! values are available even if the base pointer is never used
 131 ! again.
 132
 133 GENERIC: uses-vregs* ( insn -- seq )
 134
 135 M: gc-map-insn uses-vregs*
 136     [ uses-vregs ] [ gc-map>> derived-roots>> values ] bi append ;
 137
 138 M: vreg-insn uses-vregs* uses-vregs ;
 139
 140 M: insn uses-vregs* drop f ;
 141
 142 M: clobber-insn compute-live-intervals* ( insn -- )
 143     dup insn#>>
 144     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 145     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 146     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 147     2tri ;
 148
 149 M: hairy-clobber-insn compute-live-intervals* ( insn -- )
 150     dup insn#>>
 151     [ [ defs-vregs ] dip '[ _ t record-def ] each ]
 152     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 153     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 154     2tri ;
 155
 156 : handle-live-out ( bb -- )
 157     live-out dup assoc-empty? [ drop ] [
 158         [ from get to get ] dip keys
 159         [ live-interval add-range ] 2with each
 160     ] if ;
 161
 162 TUPLE: sync-point n keep-dst? ;
 163
 164 C: <sync-point> sync-point
 165
 166 SYMBOL: sync-points
 167
 168 GENERIC: compute-sync-points* ( insn -- )
 169
 170 M: hairy-clobber-insn compute-sync-points*
 171     insn#>> f <sync-point> sync-points get push ;
 172
 173 M: clobber-insn compute-sync-points*
 174     insn#>> t <sync-point> sync-points get push ;
 175
 176 M: insn compute-sync-points* drop ;
 177
 178 : compute-live-intervals-step ( bb -- )
 179     {
 180         [ block-from from set ]
 181         [ block-to to set ]
 182         [ handle-live-out ]
 183         [
 184             instructions>> <reversed> [
 185                 [ compute-live-intervals* ]
 186                 [ compute-sync-points* ]
 187                 bi
 188             ] each
 189         ]
 190     } cleave ;
 191
 192 : init-live-intervals ( -- )
 193     H{ } clone live-intervals set
 194     V{ } clone sync-points set ;
 195
 196 : compute-start/end ( live-interval -- )
 197     dup ranges>> [ first from>> ] [ last to>> ] bi
 198     [ >>start ] [ >>end ] bi* drop ;
 199
 200 ERROR: bad-live-interval live-interval ;
 201
 202 : check-start ( live-interval -- )
 203     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 204
 205 : finish-live-intervals ( live-intervals -- seq )
 206     values dup [
 207         {
 208             [ [ { } like reverse! ] change-ranges drop ]
 209             [ [ { } like reverse! ] change-uses drop ]
 210             [ compute-start/end ]
 211             [ check-start ]
 212         } cleave
 213     ] each ;
 214
 215 : compute-live-intervals ( cfg -- live-intervals sync-points )
 216     init-live-intervals
 217     linearization-order <reversed> [ kill-block?>> ] reject
 218     [ compute-live-intervals-step ] each
 219     live-intervals get finish-live-intervals
 220     sync-points get ;
 221
 222 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 223     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 224
 225 : intersect-live-range ( range1 range2 -- n/f )
 226     2dup [ from>> ] bi@ > [ swap ] when
 227     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 228
 229 : intersect-live-ranges ( ranges1 ranges2 -- n )
 230     {
 231         { [ over empty? ] [ 2drop f ] }
 232         { [ dup empty? ] [ 2drop f ] }
 233         [
 234             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 235                 drop
 236                 2dup [ first from>> ] bi@ <
 237                 [ [ rest-slice ] dip ] [ rest-slice ] if
 238                 intersect-live-ranges
 239             ] if
 240         ]
 241     } cond ;
 242
 243 : intervals-intersect? ( interval1 interval2 -- ? )
 244     relevant-ranges intersect-live-ranges >boolean ; inline