basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors locals sequences math
   4 math.order fry combinators binary-search
   5 compiler.cfg.instructions
   6 compiler.cfg.registers
   7 compiler.cfg.def-use
   8 compiler.cfg.liveness
   9 compiler.cfg.linearization
  10 compiler.cfg.ssa.destruction
  11 compiler.cfg
  12 cpu.architecture ;
  13 IN: compiler.cfg.linear-scan.live-intervals
  14
  15 TUPLE: live-range from to ;
  16
  17 C: <live-range> live-range
  18
  19 SYMBOLS: +def+ +use+ +memory+ ;
  20
  21 TUPLE: vreg-use rep n type ;
  22
  23 C: <vreg-use> vreg-use
  24
  25 TUPLE: live-interval
  26 vreg
  27 reg spill-to reload-from
  28 start end ranges uses
  29 reg-class ;
  30
  31 : first-use ( live-interval -- use ) uses>> first ; inline
  32
  33 : last-use ( live-interval -- use ) uses>> last ; inline
  34
  35 GENERIC: covers? ( insn# obj -- ? )
  36
  37 M: f covers? 2drop f ;
  38
  39 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  40
  41 M: live-interval covers? ( insn# live-interval -- ? )
  42     ranges>>
  43     dup length 4 <= [
  44         [ covers? ] with any?
  45     ] [
  46         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  47         covers?
  48     ] if ;
  49
  50 : add-new-range ( from to live-interval -- )
  51     [ <live-range> ] dip ranges>> push ;
  52
  53 : shorten-range ( n live-interval -- )
  54     dup ranges>> empty?
  55     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  56
  57 : extend-range ( from to live-range -- )
  58     ranges>> last
  59     [ max ] change-to
  60     [ min ] change-from
  61     drop ;
  62
  63 : extend-range? ( to live-interval -- ? )
  64     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  65
  66 : add-range ( from to live-interval -- )
  67     2dup extend-range?
  68     [ extend-range ] [ add-new-range ] if ;
  69
  70 :: add-use ( rep n type live-interval -- )
  71     type +memory+ eq? [
  72         rep n type <vreg-use>
  73         live-interval uses>> push
  74     ] unless ;
  75
  76 : <live-interval> ( vreg reg-class -- live-interval )
  77     \ live-interval new
  78         V{ } clone >>uses
  79         V{ } clone >>ranges
  80         swap >>reg-class
  81         swap >>vreg ;
  82
  83 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  84
  85 : block-to ( bb -- n ) instructions>> last insn#>> ;
  86
  87 SYMBOLS: from to ;
  88
  89 ! Mapping from vreg to live-interval
  90 SYMBOL: live-intervals
  91
  92 : live-interval ( vreg -- live-interval )
  93     leader live-intervals get
  94     [ dup rep-of reg-class-of <live-interval> ] cache ;
  95
  96 GENERIC: compute-live-intervals* ( insn -- )
  97
  98 M: insn compute-live-intervals* drop ;
  99
 100 :: record-def ( vreg n type -- )
 101     vreg rep-of :> rep
 102     vreg live-interval :> live-interval
 103
 104     n live-interval shorten-range
 105     rep n type live-interval add-use ;
 106
 107 :: record-use ( vreg n type -- )
 108     vreg rep-of :> rep
 109     vreg live-interval :> live-interval
 110
 111     from get n live-interval add-range
 112     rep n type live-interval add-use ;
 113
 114 :: record-temp ( vreg n -- )
 115     vreg rep-of :> rep
 116     vreg live-interval :> live-interval
 117
 118     n n live-interval add-range
 119     rep n +def+ live-interval add-use ;
 120
 121 M:: vreg-insn compute-live-intervals* ( insn -- )
 122     insn insn#>> :> n
 123
 124     insn defs-vreg [ n +def+ record-def ] when*
 125     insn uses-vregs [ n +use+ record-use ] each
 126     insn temp-vregs [ n record-temp ] each ;
 127
 128 M:: clobber-insn compute-live-intervals* ( insn -- )
 129     insn insn#>> :> n
 130
 131     insn defs-vreg [ n +use+ record-def ] when*
 132     insn uses-vregs [ n +memory+ record-use ] each
 133     insn temp-vregs [ n record-temp ] each ;
 134
 135 : handle-live-out ( bb -- )
 136     live-out dup assoc-empty? [ drop ] [
 137         [ from get to get ] dip keys
 138         [ live-interval add-range ] with with each
 139     ] if ;
 140
 141 ! A location where all registers have to be spilled
 142 TUPLE: sync-point n ;
 143
 144 C: <sync-point> sync-point
 145
 146 ! Sequence of sync points
 147 SYMBOL: sync-points
 148
 149 GENERIC: compute-sync-points* ( insn -- )
 150
 151 M: clobber-insn compute-sync-points*
 152     insn#>> <sync-point> sync-points get push ;
 153
 154 M: insn compute-sync-points* drop ;
 155
 156 : compute-live-intervals-step ( bb -- )
 157     {
 158         [ block-from from set ]
 159         [ block-to to set ]
 160         [ handle-live-out ]
 161         [
 162             instructions>> <reversed> [
 163                 [ compute-live-intervals* ]
 164                 [ compute-sync-points* ]
 165                 bi
 166             ] each
 167         ]
 168     } cleave ;
 169
 170 : init-live-intervals ( -- )
 171     H{ } clone live-intervals set
 172     V{ } clone sync-points set ;
 173
 174 : compute-start/end ( live-interval -- )
 175     dup ranges>> [ first from>> ] [ last to>> ] bi
 176     [ >>start ] [ >>end ] bi* drop ;
 177
 178 ERROR: bad-live-interval live-interval ;
 179
 180 : check-start ( live-interval -- )
 181     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 182
 183 : finish-live-intervals ( live-intervals -- seq )
 184     ! Since live intervals are computed in a backward order, we have
 185     ! to reverse some sequences, and compute the start and end.
 186     values dup [
 187         {
 188             [ ranges>> reverse! drop ]
 189             [ uses>> reverse! drop ]
 190             [ compute-start/end ]
 191             [ check-start ]
 192         } cleave
 193     ] each ;
 194
 195 : compute-live-intervals ( cfg -- live-intervals sync-points )
 196     init-live-intervals
 197     linearization-order <reversed> [ compute-live-intervals-step ] each
 198     live-intervals get finish-live-intervals
 199     sync-points get ;
 200
 201 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 202     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 203
 204 : intersect-live-range ( range1 range2 -- n/f )
 205     2dup [ from>> ] bi@ > [ swap ] when
 206     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 207
 208 : intersect-live-ranges ( ranges1 ranges2 -- n )
 209     {
 210         { [ over empty? ] [ 2drop f ] }
 211         { [ dup empty? ] [ 2drop f ] }
 212         [
 213             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 214                 drop
 215                 2dup [ first from>> ] bi@ <
 216                 [ [ rest-slice ] dip ] [ rest-slice ] if
 217                 intersect-live-ranges
 218             ] if
 219         ]
 220     } cond ;
 221
 222 : intervals-intersect? ( interval1 interval2 -- ? )
 223     relevant-ranges intersect-live-ranges >boolean ; inline