basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors sequences math math.order fry
   4 combinators compiler.cfg.instructions compiler.cfg.registers
   5 compiler.cfg.def-use compiler.cfg.liveness compiler.cfg ;
   6 IN: compiler.cfg.linear-scan.live-intervals
   7
   8 TUPLE: live-range from to ;
   9
  10 C: <live-range> live-range
  11
  12 TUPLE: live-interval
  13 vreg
  14 reg spill-to reload-from
  15 split-before split-after split-next
  16 start end ranges uses
  17 copy-from ;
  18
  19 : covers? ( insn# live-interval -- ? )
  20     ranges>> [ [ from>> ] [ to>> ] bi between? ] with any? ;
  21
  22 : child-interval-at ( insn# interval -- interval' )
  23     dup split-after>> [
  24         2dup split-after>> start>> <
  25         [ split-before>> ] [ split-after>> ] if
  26         child-interval-at
  27     ] [ nip ] if ;
  28
  29 ERROR: dead-value-error vreg ;
  30
  31 : shorten-range ( n live-interval -- )
  32     dup ranges>> empty?
  33     [ vreg>> dead-value-error ] [ ranges>> last (>>from) ] if ;
  34
  35 : extend-range ( from to live-range -- )
  36     ranges>> last
  37     [ max ] change-to
  38     [ min ] change-from
  39     drop ;
  40
  41 : add-new-range ( from to live-interval -- )
  42     [ <live-range> ] dip ranges>> push ;
  43
  44 : extend-range? ( to live-interval -- ? )
  45     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  46
  47 : add-range ( from to live-interval -- )
  48     2dup extend-range?
  49     [ extend-range ] [ add-new-range ] if ;
  50
  51 : add-use ( n live-interval -- )
  52     uses>> push ;
  53
  54 : <live-interval> ( vreg -- live-interval )
  55     \ live-interval new
  56         V{ } clone >>uses
  57         V{ } clone >>ranges
  58         swap >>vreg ;
  59
  60 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  61
  62 : block-to ( bb -- n ) instructions>> last insn#>> ;
  63
  64 M: live-interval hashcode*
  65     nip [ start>> ] [ end>> 1000 * ] bi + ;
  66
  67 M: live-interval clone
  68     call-next-method [ clone ] change-uses ;
  69
  70 ! Mapping from vreg to live-interval
  71 SYMBOL: live-intervals
  72
  73 : live-interval ( vreg live-intervals -- live-interval )
  74     [ <live-interval> ] cache ;
  75
  76 GENERIC: compute-live-intervals* ( insn -- )
  77
  78 M: insn compute-live-intervals* drop ;
  79
  80 : handle-output ( n vreg live-intervals -- )
  81     live-interval
  82     [ add-use ] [ shorten-range ] 2bi ;
  83
  84 : handle-input ( n vreg live-intervals -- )
  85     live-interval
  86     [ [ basic-block get block-from ] 2dip add-range ] [ add-use ] 2bi ;
  87
  88 : handle-temp ( n vreg live-intervals -- )
  89     live-interval
  90     [ dupd add-range ] [ add-use ] 2bi ;
  91
  92 M: vreg-insn compute-live-intervals*
  93     dup insn#>>
  94     live-intervals get
  95     [ [ defs-vregs ] 2dip '[ [ _ ] dip _ handle-output ] each ]
  96     [ [ uses-vregs ] 2dip '[ [ _ ] dip _ handle-input ] each ]
  97     [ [ temp-vregs ] 2dip '[ [ _ ] dip _ handle-temp ] each ]
  98     3tri ;
  99
 100 : record-copy ( insn -- )
 101     [ dst>> live-intervals get at ] [ src>> ] bi >>copy-from drop ;
 102
 103 M: ##copy compute-live-intervals*
 104     [ call-next-method ] [ record-copy ] bi ;
 105
 106 M: ##copy-float compute-live-intervals*
 107     [ call-next-method ] [ record-copy ] bi ;
 108
 109 : handle-live-out ( bb -- )
 110     live-out keys
 111     basic-block get [ block-from ] [ block-to ] bi
 112     live-intervals get '[
 113         [ _ _ ] dip _ live-interval add-range
 114     ] each ;
 115
 116 : compute-live-intervals-step ( bb -- )
 117     [ basic-block set ]
 118     [ handle-live-out ]
 119     [ instructions>> <reversed> [ compute-live-intervals* ] each ] tri ;
 120
 121 : compute-start/end ( live-interval -- )
 122     dup ranges>> [ first from>> ] [ last to>> ] bi
 123     [ >>start ] [ >>end ] bi* drop ;
 124
 125 ERROR: bad-live-interval live-interval ;
 126
 127 : check-start ( live-interval -- )
 128     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 129
 130 : finish-live-intervals ( live-intervals -- )
 131     ! Since live intervals are computed in a backward order, we have
 132     ! to reverse some sequences, and compute the start and end.
 133     [
 134         {
 135             [ ranges>> reverse-here ]
 136             [ uses>> reverse-here ]
 137             [ compute-start/end ]
 138             [ check-start ]
 139         } cleave
 140     ] each ;
 141
 142 : compute-live-intervals ( rpo -- live-intervals )
 143     H{ } clone [
 144         live-intervals set
 145         <reversed> [ compute-live-intervals-step ] each
 146     ] keep values dup finish-live-intervals ;
 147
 148 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 149     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 150
 151 : intersect-live-range ( range1 range2 -- n/f )
 152     2dup [ from>> ] bi@ > [ swap ] when
 153     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 154
 155 : intersect-live-ranges ( ranges1 ranges2 -- n )
 156     {
 157         { [ over empty? ] [ 2drop f ] }
 158         { [ dup empty? ] [ 2drop f ] }
 159         [
 160             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 161                 drop
 162                 2dup [ first from>> ] bi@ <
 163                 [ [ rest-slice ] dip ] [ rest-slice ] if
 164                 intersect-live-ranges
 165             ] if
 166         ]
 167     } cond ;
 168
 169 : intervals-intersect? ( interval1 interval2 -- ? )
 170     relevant-ranges intersect-live-ranges >boolean ; inline