basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors sequences math math.order fry
   4 combinators binary-search compiler.cfg.instructions compiler.cfg.registers
   5 compiler.cfg.def-use compiler.cfg.liveness compiler.cfg.linearization.order
   6 compiler.cfg cpu.architecture ;
   7 IN: compiler.cfg.linear-scan.live-intervals
   8
   9 TUPLE: live-range from to ;
  10
  11 C: <live-range> live-range
  12
  13 SYMBOLS: +def+ +use+ +memory+ ;
  14
  15 TUPLE: vreg-use n type ;
  16
  17 C: <vreg-use> vreg-use
  18
  19 TUPLE: live-interval
  20 vreg
  21 reg spill-to reload-from
  22 start end ranges uses
  23 reg-class ;
  24
  25 : first-use ( live-interval -- use ) uses>> first ; inline
  26
  27 : last-use ( live-interval -- use ) uses>> last ; inline
  28
  29 GENERIC: covers? ( insn# obj -- ? )
  30
  31 M: f covers? 2drop f ;
  32
  33 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  34
  35 M: live-interval covers? ( insn# live-interval -- ? )
  36     ranges>>
  37     dup length 4 <= [
  38         [ covers? ] with any?
  39     ] [
  40         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  41         covers?
  42     ] if ;
  43
  44 : add-new-range ( from to live-interval -- )
  45     [ <live-range> ] dip ranges>> push ;
  46
  47 : shorten-range ( n live-interval -- )
  48     dup ranges>> empty?
  49     [ dupd add-new-range ] [ ranges>> last (>>from) ] if ;
  50
  51 : extend-range ( from to live-range -- )
  52     ranges>> last
  53     [ max ] change-to
  54     [ min ] change-from
  55     drop ;
  56
  57 : extend-range? ( to live-interval -- ? )
  58     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  59
  60 : add-range ( from to live-interval -- )
  61     2dup extend-range?
  62     [ extend-range ] [ add-new-range ] if ;
  63
  64 : add-use ( insn live-interval type -- )
  65     dup +memory+ eq? [ 3drop ] [
  66         swap [ [ insn#>> ] dip <vreg-use> ] dip
  67         uses>> push
  68     ] if ;
  69
  70 : <live-interval> ( vreg -- live-interval )
  71     \ live-interval new
  72         V{ } clone >>uses
  73         V{ } clone >>ranges
  74         over rep-of reg-class-of >>reg-class
  75         swap >>vreg ;
  76
  77 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  78
  79 : block-to ( bb -- n ) instructions>> last insn#>> ;
  80
  81 ! Mapping from vreg to live-interval
  82 SYMBOL: live-intervals
  83
  84 : live-interval ( vreg -- live-interval )
  85     live-intervals get [ <live-interval> ] cache ;
  86
  87 GENERIC: compute-live-intervals* ( insn -- )
  88
  89 M: insn compute-live-intervals* drop ;
  90
  91 : handle-output ( insn vreg type -- )
  92     [ live-interval ] dip
  93     [ drop [ insn#>> ] dip shorten-range ] [ add-use ] 3bi ;
  94
  95 : handle-input ( insn vreg type -- )
  96     [ live-interval ] dip
  97     [ drop [ [ basic-block get block-from ] dip insn#>> ] dip add-range ]
  98     [ add-use ]
  99     3bi ;
 100
 101 : handle-temp ( insn vreg -- )
 102     live-interval
 103     [ [ insn#>> dup ] dip add-range ] [ +def+ add-use ] 2bi ;
 104
 105 M: vreg-insn compute-live-intervals*
 106     [ dup defs-vreg [ +def+ handle-output ] with when* ]
 107     [ dup uses-vregs [ +use+ handle-input ] with each ]
 108     [ dup temp-vregs [ handle-temp ] with each ]
 109     tri ;
 110
 111 M: clobber-insn compute-live-intervals*
 112     [ dup defs-vreg [ +use+ handle-output ] with when* ]
 113     [ dup uses-vregs [ +memory+ handle-input ] with each ]
 114     [ dup temp-vregs [ handle-temp ] with each ]
 115     tri ;
 116
 117 : handle-live-out ( bb -- )
 118     [ block-from ] [ block-to ] [ live-out keys ] tri
 119     [ live-interval add-range ] with with each ;
 120
 121 ! A location where all registers have to be spilled
 122 TUPLE: sync-point n ;
 123
 124 C: <sync-point> sync-point
 125
 126 ! Sequence of sync points
 127 SYMBOL: sync-points
 128
 129 GENERIC: compute-sync-points* ( insn -- )
 130
 131 M: clobber-insn compute-sync-points*
 132     insn#>> <sync-point> sync-points get push ;
 133
 134 M: insn compute-sync-points* drop ;
 135
 136 : compute-live-intervals-step ( bb -- )
 137     [ basic-block set ]
 138     [ handle-live-out ]
 139     [
 140         instructions>> <reversed> [
 141             [ compute-live-intervals* ]
 142             [ compute-sync-points* ]
 143             bi
 144         ] each
 145     ] tri ;
 146
 147 : init-live-intervals ( -- )
 148     H{ } clone live-intervals set
 149     V{ } clone sync-points set ;
 150
 151 : compute-start/end ( live-interval -- )
 152     dup ranges>> [ first from>> ] [ last to>> ] bi
 153     [ >>start ] [ >>end ] bi* drop ;
 154
 155 ERROR: bad-live-interval live-interval ;
 156
 157 : check-start ( live-interval -- )
 158     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 159
 160 : finish-live-intervals ( live-intervals -- seq )
 161     ! Since live intervals are computed in a backward order, we have
 162     ! to reverse some sequences, and compute the start and end.
 163     values dup [
 164         {
 165             [ ranges>> reverse! drop ]
 166             [ uses>> reverse! drop ]
 167             [ compute-start/end ]
 168             [ check-start ]
 169         } cleave
 170     ] each ;
 171
 172 : compute-live-intervals ( cfg -- live-intervals sync-points )
 173     init-live-intervals
 174     linearization-order <reversed> [ compute-live-intervals-step ] each
 175     live-intervals get finish-live-intervals
 176     sync-points get ;
 177
 178 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 179     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 180
 181 : intersect-live-range ( range1 range2 -- n/f )
 182     2dup [ from>> ] bi@ > [ swap ] when
 183     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 184
 185 : intersect-live-ranges ( ranges1 ranges2 -- n )
 186     {
 187         { [ over empty? ] [ 2drop f ] }
 188         { [ dup empty? ] [ 2drop f ] }
 189         [
 190             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 191                 drop
 192                 2dup [ first from>> ] bi@ <
 193                 [ [ rest-slice ] dip ] [ rest-slice ] if
 194                 intersect-live-ranges
 195             ] if
 196         ]
 197     } cond ;
 198
 199 : intervals-intersect? ( interval1 interval2 -- ? )
 200     relevant-ranges intersect-live-ranges >boolean ; inline