basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors sequences math math.order fry
   4 combinators binary-search compiler.cfg.instructions compiler.cfg.registers
   5 compiler.cfg.def-use compiler.cfg.liveness compiler.cfg.linearization.order
   6 compiler.cfg ;
   7 IN: compiler.cfg.linear-scan.live-intervals
   8
   9 TUPLE: live-range from to ;
  10
  11 C: <live-range> live-range
  12
  13 TUPLE: live-interval
  14 vreg
  15 reg spill-to reload-from
  16 start end ranges uses ;
  17
  18 GENERIC: covers? ( insn# obj -- ? )
  19
  20 M: f covers? 2drop f ;
  21
  22 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  23
  24 M: live-interval covers? ( insn# live-interval -- ? )
  25     ranges>>
  26     dup length 4 <= [
  27         [ covers? ] with any?
  28     ] [
  29         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  30         covers?
  31     ] if ;
  32
  33 ERROR: dead-value-error vreg ;
  34
  35 : shorten-range ( n live-interval -- )
  36     dup ranges>> empty?
  37     [ vreg>> dead-value-error ] [ ranges>> last (>>from) ] if ;
  38
  39 : extend-range ( from to live-range -- )
  40     ranges>> last
  41     [ max ] change-to
  42     [ min ] change-from
  43     drop ;
  44
  45 : add-new-range ( from to live-interval -- )
  46     [ <live-range> ] dip ranges>> push ;
  47
  48 : extend-range? ( to live-interval -- ? )
  49     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  50
  51 : add-range ( from to live-interval -- )
  52     2dup extend-range?
  53     [ extend-range ] [ add-new-range ] if ;
  54
  55 : add-use ( n live-interval -- )
  56     uses>> push ;
  57
  58 : <live-interval> ( vreg -- live-interval )
  59     \ live-interval new
  60         V{ } clone >>uses
  61         V{ } clone >>ranges
  62         swap >>vreg ;
  63
  64 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  65
  66 : block-to ( bb -- n ) instructions>> last insn#>> ;
  67
  68 M: live-interval hashcode*
  69     nip [ start>> ] [ end>> 1000 * ] bi + ;
  70
  71 M: live-interval clone
  72     call-next-method [ clone ] change-uses ;
  73
  74 ! Mapping from vreg to live-interval
  75 SYMBOL: live-intervals
  76
  77 : live-interval ( vreg live-intervals -- live-interval )
  78     [ <live-interval> ] cache ;
  79
  80 GENERIC: compute-live-intervals* ( insn -- )
  81
  82 M: insn compute-live-intervals* drop ;
  83
  84 : handle-output ( n vreg live-intervals -- )
  85     live-interval
  86     [ add-use ] [ shorten-range ] 2bi ;
  87
  88 : handle-input ( n vreg live-intervals -- )
  89     live-interval
  90     [ [ basic-block get block-from ] 2dip add-range ] [ add-use ] 2bi ;
  91
  92 : handle-temp ( n vreg live-intervals -- )
  93     live-interval
  94     [ dupd add-range ] [ add-use ] 2bi ;
  95
  96 M: vreg-insn compute-live-intervals*
  97     dup insn#>>
  98     live-intervals get
  99     [ [ defs-vreg ] 2dip '[ [ _ ] dip _ handle-output ] when* ]
 100     [ [ uses-vregs ] 2dip '[ [ _ ] dip _ handle-input ] each ]
 101     [ [ temp-vregs ] 2dip '[ [ _ ] dip _ handle-temp ] each ]
 102     3tri ;
 103
 104 : handle-live-out ( bb -- )
 105     live-out keys
 106     basic-block get [ block-from ] [ block-to ] bi
 107     live-intervals get '[
 108         [ _ _ ] dip _ live-interval add-range
 109     ] each ;
 110
 111 : compute-live-intervals-step ( bb -- )
 112     [ basic-block set ]
 113     [ handle-live-out ]
 114     [ instructions>> <reversed> [ compute-live-intervals* ] each ] tri ;
 115
 116 : compute-start/end ( live-interval -- )
 117     dup ranges>> [ first from>> ] [ last to>> ] bi
 118     [ >>start ] [ >>end ] bi* drop ;
 119
 120 ERROR: bad-live-interval live-interval ;
 121
 122 : check-start ( live-interval -- )
 123     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 124
 125 : finish-live-intervals ( live-intervals -- )
 126     ! Since live intervals are computed in a backward order, we have
 127     ! to reverse some sequences, and compute the start and end.
 128     [
 129         {
 130             [ ranges>> reverse-here ]
 131             [ uses>> reverse-here ]
 132             [ compute-start/end ]
 133             [ check-start ]
 134         } cleave
 135     ] each ;
 136
 137 : compute-live-intervals ( cfg -- live-intervals )
 138     H{ } clone [
 139         live-intervals set
 140         linearization-order <reversed>
 141         [ compute-live-intervals-step ] each
 142     ] keep values dup finish-live-intervals ;
 143
 144 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 145     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 146
 147 : intersect-live-range ( range1 range2 -- n/f )
 148     2dup [ from>> ] bi@ > [ swap ] when
 149     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 150
 151 : intersect-live-ranges ( ranges1 ranges2 -- n )
 152     {
 153         { [ over empty? ] [ 2drop f ] }
 154         { [ dup empty? ] [ 2drop f ] }
 155         [
 156             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 157                 drop
 158                 2dup [ first from>> ] bi@ <
 159                 [ [ rest-slice ] dip ] [ rest-slice ] if
 160                 intersect-live-ranges
 161             ] if
 162         ]
 163     } cond ;
 164
 165 : intervals-intersect? ( interval1 interval2 -- ? )
 166     relevant-ranges intersect-live-ranges >boolean ; inline