basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors sequences math math.order fry
   4 combinators binary-search compiler.cfg.instructions compiler.cfg.registers
   5 compiler.cfg.def-use compiler.cfg.liveness compiler.cfg.linearization.order
   6 compiler.cfg ;
   7 IN: compiler.cfg.linear-scan.live-intervals
   8
   9 TUPLE: live-range from to ;
  10
  11 C: <live-range> live-range
  12
  13 SYMBOLS: +def+ +use+ +memory+ ;
  14
  15 TUPLE: vreg-use n type ;
  16
  17 C: <vreg-use> vreg-use
  18
  19 TUPLE: live-interval
  20 vreg
  21 reg spill-to reload-from
  22 start end ranges uses ;
  23
  24 GENERIC: covers? ( insn# obj -- ? )
  25
  26 M: f covers? 2drop f ;
  27
  28 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  29
  30 M: live-interval covers? ( insn# live-interval -- ? )
  31     ranges>>
  32     dup length 4 <= [
  33         [ covers? ] with any?
  34     ] [
  35         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  36         covers?
  37     ] if ;
  38
  39 : add-new-range ( from to live-interval -- )
  40     [ <live-range> ] dip ranges>> push ;
  41
  42 : shorten-range ( n live-interval -- )
  43     dup ranges>> empty?
  44     [ dupd add-new-range ] [ ranges>> last (>>from) ] if ;
  45
  46 : extend-range ( from to live-range -- )
  47     ranges>> last
  48     [ max ] change-to
  49     [ min ] change-from
  50     drop ;
  51
  52 : extend-range? ( to live-interval -- ? )
  53     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  54
  55 : add-range ( from to live-interval -- )
  56     2dup extend-range?
  57     [ extend-range ] [ add-new-range ] if ;
  58
  59 : add-use ( insn live-interval type -- )
  60     dup +memory+ eq? [ 3drop ] [
  61         swap [ [ insn#>> ] dip <vreg-use> ] dip
  62         uses>> push
  63     ] if ;
  64
  65 : <live-interval> ( vreg -- live-interval )
  66     \ live-interval new
  67         V{ } clone >>uses
  68         V{ } clone >>ranges
  69         swap >>vreg ;
  70
  71 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  72
  73 : block-to ( bb -- n ) instructions>> last insn#>> ;
  74
  75 ! Mapping from vreg to live-interval
  76 SYMBOL: live-intervals
  77
  78 : live-interval ( vreg -- live-interval )
  79     live-intervals get [ <live-interval> ] cache ;
  80
  81 GENERIC: compute-live-intervals* ( insn -- )
  82
  83 M: insn compute-live-intervals* drop ;
  84
  85 : handle-output ( insn vreg type -- )
  86     [ live-interval ] dip
  87     [ drop [ insn#>> ] dip shorten-range ] [ add-use ] 3bi ;
  88
  89 : handle-input ( insn vreg type -- )
  90     [ live-interval ] dip
  91     [ drop [ [ basic-block get block-from ] dip insn#>> ] dip add-range ]
  92     [ add-use ]
  93     3bi ;
  94
  95 : handle-temp ( insn vreg -- )
  96     live-interval
  97     [ [ insn#>> dup ] dip add-range ] [ +def+ add-use ] 2bi ;
  98
  99 M: vreg-insn compute-live-intervals*
 100     [ dup defs-vreg [ +def+ handle-output ] with when* ]
 101     [ dup uses-vregs [ +use+ handle-input ] with each ]
 102     [ dup temp-vregs [ handle-temp ] with each ]
 103     tri ;
 104
 105 M: partial-sync-insn compute-live-intervals*
 106     [ dup defs-vreg [ +use+ handle-output ] with when* ]
 107     [ dup uses-vregs [ +memory+ handle-input ] with each ]
 108     [ dup temp-vregs [ handle-temp ] with each ]
 109     tri ;
 110
 111 : handle-live-out ( bb -- )
 112     [ block-from ] [ block-to ] [ live-out keys ] tri
 113     [ live-interval add-range ] with with each ;
 114
 115 ! A location where all registers have to be spilled
 116 TUPLE: sync-point n ;
 117
 118 C: <sync-point> sync-point
 119
 120 ! Sequence of sync points
 121 SYMBOL: sync-points
 122
 123 GENERIC: compute-sync-points* ( insn -- )
 124
 125 M: partial-sync-insn compute-sync-points*
 126     insn#>> <sync-point> sync-points get push ;
 127
 128 M: insn compute-sync-points* drop ;
 129
 130 : compute-live-intervals-step ( bb -- )
 131     [ basic-block set ]
 132     [ handle-live-out ]
 133     [
 134         instructions>> <reversed> [
 135             [ compute-live-intervals* ]
 136             [ compute-sync-points* ]
 137             bi
 138         ] each
 139     ] tri ;
 140
 141 : init-live-intervals ( -- )
 142     H{ } clone live-intervals set
 143     V{ } clone sync-points set ;
 144
 145 : compute-start/end ( live-interval -- )
 146     dup ranges>> [ first from>> ] [ last to>> ] bi
 147     [ >>start ] [ >>end ] bi* drop ;
 148
 149 ERROR: bad-live-interval live-interval ;
 150
 151 : check-start ( live-interval -- )
 152     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 153
 154 : finish-live-intervals ( live-intervals -- seq )
 155     ! Since live intervals are computed in a backward order, we have
 156     ! to reverse some sequences, and compute the start and end.
 157     values dup [
 158         {
 159             [ ranges>> reverse! drop ]
 160             [ uses>> reverse! drop ]
 161             [ compute-start/end ]
 162             [ check-start ]
 163         } cleave
 164     ] each ;
 165
 166 : compute-live-intervals ( cfg -- live-intervals sync-points )
 167     init-live-intervals
 168     linearization-order <reversed> [ compute-live-intervals-step ] each
 169     live-intervals get finish-live-intervals
 170     sync-points get ;
 171
 172 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 173     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 174
 175 : intersect-live-range ( range1 range2 -- n/f )
 176     2dup [ from>> ] bi@ > [ swap ] when
 177     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 178
 179 : intersect-live-ranges ( ranges1 ranges2 -- n )
 180     {
 181         { [ over empty? ] [ 2drop f ] }
 182         { [ dup empty? ] [ 2drop f ] }
 183         [
 184             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 185                 drop
 186                 2dup [ first from>> ] bi@ <
 187                 [ [ rest-slice ] dip ] [ rest-slice ] if
 188                 intersect-live-ranges
 189             ] if
 190         ]
 191     } cond ;
 192
 193 : intervals-intersect? ( interval1 interval2 -- ? )
 194     relevant-ranges intersect-live-ranges >boolean ; inline