basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors locals sequences math
   4 math.order fry combinators binary-search
   5 compiler.cfg.instructions
   6 compiler.cfg.registers
   7 compiler.cfg.def-use
   8 compiler.cfg.liveness
   9 compiler.cfg.linearization
  10 compiler.cfg.ssa.destruction.leaders
  11 compiler.cfg
  12 cpu.architecture ;
  13 IN: compiler.cfg.linear-scan.live-intervals
  14
  15 TUPLE: live-range from to ;
  16
  17 C: <live-range> live-range
  18
  19 TUPLE: vreg-use n def-rep use-rep spill-slot? ;
  20
  21 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  22
  23 TUPLE: live-interval-state
  24 vreg
  25 reg spill-to spill-rep reload-from reload-rep
  26 start end ranges uses
  27 reg-class ;
  28
  29 : first-use ( live-interval -- use ) uses>> first ; inline
  30
  31 : last-use ( live-interval -- use ) uses>> last ; inline
  32
  33 : new-use ( insn# uses -- use )
  34     [ <vreg-use> dup ] dip push ;
  35
  36 : last-use? ( insn# uses -- use/f )
  37     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  38
  39 :: (add-use) ( insn# live-interval spill-slot? -- use )
  40     live-interval uses>> :> uses
  41     insn# uses last-use? [ insn# uses new-use ] unless*
  42     spill-slot? [ t >>spill-slot? ] when ;
  43
  44 GENERIC: covers? ( insn# obj -- ? )
  45
  46 M: f covers? 2drop f ;
  47
  48 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  49
  50 M: live-interval-state covers? ( insn# live-interval -- ? )
  51     ranges>>
  52     dup length 4 <= [
  53         [ covers? ] with any?
  54     ] [
  55         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  56         covers?
  57     ] if ;
  58
  59 : (find-use) ( insn# live-interval -- vreg-use )
  60     uses>> [ n>> <=> ] with search nip ;
  61
  62 :: find-use ( insn# live-interval -- vreg-use )
  63     insn# live-interval (find-use)
  64     dup [ dup n>> insn# = [ drop f ] unless ] when ;
  65
  66 : add-new-range ( from to live-interval -- )
  67     [ <live-range> ] dip ranges>> push ;
  68
  69 : shorten-range ( n live-interval -- )
  70     dup ranges>> empty?
  71     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  72
  73 : extend-range ( from to live-range -- )
  74     ranges>> last
  75     [ max ] change-to
  76     [ min ] change-from
  77     drop ;
  78
  79 : extend-range? ( to live-interval -- ? )
  80     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  81
  82 : add-range ( from to live-interval -- )
  83     2dup extend-range?
  84     [ extend-range ] [ add-new-range ] if ;
  85
  86 : <live-interval> ( vreg reg-class -- live-interval )
  87     \ live-interval-state new
  88         V{ } clone >>uses
  89         V{ } clone >>ranges
  90         swap >>reg-class
  91         swap >>vreg ;
  92
  93 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  94
  95 : block-to ( bb -- n ) instructions>> last insn#>> ;
  96
  97 SYMBOLS: from to ;
  98
  99 ! Mapping from vreg to live-interval
 100 SYMBOL: live-intervals
 101
 102 : live-interval ( vreg -- live-interval )
 103     leader live-intervals get
 104     [ dup rep-of reg-class-of <live-interval> ] cache ;
 105
 106 GENERIC: compute-live-intervals* ( insn -- )
 107
 108 M: insn compute-live-intervals* drop ;
 109
 110 :: record-def ( vreg n spill-slot? -- )
 111     vreg live-interval :> live-interval
 112
 113     n live-interval shorten-range
 114     n live-interval spill-slot? (add-use) vreg rep-of >>def-rep drop ;
 115
 116 :: record-use ( vreg n spill-slot? -- )
 117     vreg live-interval :> live-interval
 118
 119     from get n live-interval add-range
 120     n live-interval spill-slot? (add-use) vreg rep-of >>use-rep drop ;
 121
 122 :: record-temp ( vreg n -- )
 123     vreg live-interval :> live-interval
 124
 125     n n live-interval add-range
 126     n live-interval f (add-use) vreg rep-of >>def-rep drop ;
 127
 128 M: vreg-insn compute-live-intervals* ( insn -- )
 129     dup insn#>>
 130     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 131     [ [ uses-vregs ] dip '[ _ f record-use ] each ]
 132     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 133     2tri ;
 134
 135 ! Extend lifetime intervals of base pointers, so that their
 136 ! values are available even if the base pointer is never used
 137 ! again.
 138
 139 GENERIC: uses-vregs* ( insn -- seq )
 140
 141 M: gc-map-insn uses-vregs*
 142     [ uses-vregs ] [ gc-map>> derived-roots>> values ] bi append ;
 143
 144 M: vreg-insn uses-vregs* uses-vregs ;
 145
 146 M: insn uses-vregs* drop f ;
 147
 148 M: clobber-insn compute-live-intervals* ( insn -- )
 149     dup insn#>>
 150     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 151     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 152     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 153     2tri ;
 154
 155 M: hairy-clobber-insn compute-live-intervals* ( insn -- )
 156     dup insn#>>
 157     [ [ defs-vregs ] dip '[ _ t record-def ] each ]
 158     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 159     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 160     2tri ;
 161
 162 : handle-live-out ( bb -- )
 163     live-out dup assoc-empty? [ drop ] [
 164         [ from get to get ] dip keys
 165         [ live-interval add-range ] 2with each
 166     ] if ;
 167
 168 ! A location where all registers have to be spilled
 169 TUPLE: sync-point n keep-dst? ;
 170
 171 C: <sync-point> sync-point
 172
 173 ! Sequence of sync points
 174 SYMBOL: sync-points
 175
 176 GENERIC: compute-sync-points* ( insn -- )
 177
 178 M: hairy-clobber-insn compute-sync-points*
 179     insn#>> f <sync-point> sync-points get push ;
 180
 181 M: clobber-insn compute-sync-points*
 182     insn#>> t <sync-point> sync-points get push ;
 183
 184 M: insn compute-sync-points* drop ;
 185
 186 : compute-live-intervals-step ( bb -- )
 187     dup kill-block?>> [ drop ] [
 188         {
 189             [ block-from from set ]
 190             [ block-to to set ]
 191             [ handle-live-out ]
 192             [
 193                 instructions>> <reversed> [
 194                     [ compute-live-intervals* ]
 195                     [ compute-sync-points* ]
 196                     bi
 197                 ] each
 198             ]
 199         } cleave
 200     ] if ;
 201
 202 : init-live-intervals ( -- )
 203     H{ } clone live-intervals set
 204     V{ } clone sync-points set ;
 205
 206 : compute-start/end ( live-interval -- )
 207     dup ranges>> [ first from>> ] [ last to>> ] bi
 208     [ >>start ] [ >>end ] bi* drop ;
 209
 210 ERROR: bad-live-interval live-interval ;
 211
 212 : check-start ( live-interval -- )
 213     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 214
 215 : finish-live-intervals ( live-intervals -- seq )
 216     ! Since live intervals are computed in a backward order, we have
 217     ! to reverse some sequences, and compute the start and end.
 218     values dup [
 219         {
 220             [ [ { } like reverse! ] change-ranges drop ]
 221             [ [ { } like reverse! ] change-uses drop ]
 222             [ compute-start/end ]
 223             [ check-start ]
 224         } cleave
 225     ] each ;
 226
 227 : compute-live-intervals ( cfg -- live-intervals sync-points )
 228     init-live-intervals
 229     linearization-order <reversed> [ compute-live-intervals-step ] each
 230     live-intervals get finish-live-intervals
 231     sync-points get ;
 232
 233 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 234     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 235
 236 : intersect-live-range ( range1 range2 -- n/f )
 237     2dup [ from>> ] bi@ > [ swap ] when
 238     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 239
 240 : intersect-live-ranges ( ranges1 ranges2 -- n )
 241     {
 242         { [ over empty? ] [ 2drop f ] }
 243         { [ dup empty? ] [ 2drop f ] }
 244         [
 245             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 246                 drop
 247                 2dup [ first from>> ] bi@ <
 248                 [ [ rest-slice ] dip ] [ rest-slice ] if
 249                 intersect-live-ranges
 250             ] if
 251         ]
 252     } cond ;
 253
 254 : intervals-intersect? ( interval1 interval2 -- ? )
 255     relevant-ranges intersect-live-ranges >boolean ; inline