basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors sequences math math.order fry
   4 combinators binary-search compiler.cfg.instructions compiler.cfg.registers
   5 compiler.cfg.def-use compiler.cfg.liveness compiler.cfg.rpo
   6 compiler.cfg ;
   7 IN: compiler.cfg.linear-scan.live-intervals
   8
   9 TUPLE: live-range from to ;
  10
  11 C: <live-range> live-range
  12
  13 TUPLE: live-interval
  14 vreg
  15 reg spill-to reload-from
  16 start end ranges uses
  17 copy-from ;
  18
  19 GENERIC: covers? ( insn# obj -- ? )
  20
  21 M: f covers? 2drop f ;
  22
  23 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  24
  25 M: live-interval covers? ( insn# live-interval -- ? )
  26     ranges>>
  27     dup length 4 <= [
  28         [ covers? ] with any?
  29     ] [
  30         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  31         covers?
  32     ] if ;
  33
  34 ERROR: dead-value-error vreg ;
  35
  36 : shorten-range ( n live-interval -- )
  37     dup ranges>> empty?
  38     [ vreg>> dead-value-error ] [ ranges>> last (>>from) ] if ;
  39
  40 : extend-range ( from to live-range -- )
  41     ranges>> last
  42     [ max ] change-to
  43     [ min ] change-from
  44     drop ;
  45
  46 : add-new-range ( from to live-interval -- )
  47     [ <live-range> ] dip ranges>> push ;
  48
  49 : extend-range? ( to live-interval -- ? )
  50     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  51
  52 : add-range ( from to live-interval -- )
  53     2dup extend-range?
  54     [ extend-range ] [ add-new-range ] if ;
  55
  56 : add-use ( n live-interval -- )
  57     uses>> push ;
  58
  59 : <live-interval> ( vreg -- live-interval )
  60     \ live-interval new
  61         V{ } clone >>uses
  62         V{ } clone >>ranges
  63         swap >>vreg ;
  64
  65 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  66
  67 : block-to ( bb -- n ) instructions>> last insn#>> ;
  68
  69 M: live-interval hashcode*
  70     nip [ start>> ] [ end>> 1000 * ] bi + ;
  71
  72 M: live-interval clone
  73     call-next-method [ clone ] change-uses ;
  74
  75 ! Mapping from vreg to live-interval
  76 SYMBOL: live-intervals
  77
  78 : live-interval ( vreg live-intervals -- live-interval )
  79     [ <live-interval> ] cache ;
  80
  81 GENERIC: compute-live-intervals* ( insn -- )
  82
  83 M: insn compute-live-intervals* drop ;
  84
  85 : handle-output ( n vreg live-intervals -- )
  86     live-interval
  87     [ add-use ] [ shorten-range ] 2bi ;
  88
  89 : handle-input ( n vreg live-intervals -- )
  90     live-interval
  91     [ [ basic-block get block-from ] 2dip add-range ] [ add-use ] 2bi ;
  92
  93 : handle-temp ( n vreg live-intervals -- )
  94     live-interval
  95     [ dupd add-range ] [ add-use ] 2bi ;
  96
  97 M: vreg-insn compute-live-intervals*
  98     dup insn#>>
  99     live-intervals get
 100     [ [ defs-vreg ] 2dip '[ [ _ ] dip _ handle-output ] when* ]
 101     [ [ uses-vregs ] 2dip '[ [ _ ] dip _ handle-input ] each ]
 102     [ [ temp-vregs ] 2dip '[ [ _ ] dip _ handle-temp ] each ]
 103     3tri ;
 104
 105 : record-copy ( insn -- )
 106     [ dst>> live-intervals get at ] [ src>> ] bi >>copy-from drop ;
 107
 108 M: ##copy compute-live-intervals*
 109     [ call-next-method ] [ record-copy ] bi ;
 110
 111 M: ##copy-float compute-live-intervals*
 112     [ call-next-method ] [ record-copy ] bi ;
 113
 114 : handle-live-out ( bb -- )
 115     live-out keys
 116     basic-block get [ block-from ] [ block-to ] bi
 117     live-intervals get '[
 118         [ _ _ ] dip _ live-interval add-range
 119     ] each ;
 120
 121 : compute-live-intervals-step ( bb -- )
 122     [ basic-block set ]
 123     [ handle-live-out ]
 124     [ instructions>> <reversed> [ compute-live-intervals* ] each ] tri ;
 125
 126 : compute-start/end ( live-interval -- )
 127     dup ranges>> [ first from>> ] [ last to>> ] bi
 128     [ >>start ] [ >>end ] bi* drop ;
 129
 130 ERROR: bad-live-interval live-interval ;
 131
 132 : check-start ( live-interval -- )
 133     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 134
 135 : finish-live-intervals ( live-intervals -- )
 136     ! Since live intervals are computed in a backward order, we have
 137     ! to reverse some sequences, and compute the start and end.
 138     [
 139         {
 140             [ ranges>> reverse-here ]
 141             [ uses>> reverse-here ]
 142             [ compute-start/end ]
 143             [ check-start ]
 144         } cleave
 145     ] each ;
 146
 147 : compute-live-intervals ( cfg -- live-intervals )
 148     H{ } clone [
 149         live-intervals set
 150         post-order [ compute-live-intervals-step ] each
 151     ] keep values dup finish-live-intervals ;
 152
 153 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 154     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 155
 156 : intersect-live-range ( range1 range2 -- n/f )
 157     2dup [ from>> ] bi@ > [ swap ] when
 158     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 159
 160 : intersect-live-ranges ( ranges1 ranges2 -- n )
 161     {
 162         { [ over empty? ] [ 2drop f ] }
 163         { [ dup empty? ] [ 2drop f ] }
 164         [
 165             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 166                 drop
 167                 2dup [ first from>> ] bi@ <
 168                 [ [ rest-slice ] dip ] [ rest-slice ] if
 169                 intersect-live-ranges
 170             ] if
 171         ]
 172     } cond ;
 173
 174 : intervals-intersect? ( interval1 interval2 -- ? )
 175     relevant-ranges intersect-live-ranges >boolean ; inline