basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs binary-search combinators
   4 compiler.cfg.def-use compiler.cfg.instructions
   5 compiler.cfg.linearization compiler.cfg.liveness
   6 compiler.cfg.registers compiler.cfg.ssa.destruction.leaders
   7 cpu.architecture fry kernel locals math math.order namespaces
   8 sequences ;
   9 IN: compiler.cfg.linear-scan.live-intervals
  10
  11 TUPLE: live-range from to ;
  12
  13 C: <live-range> live-range
  14
  15 TUPLE: vreg-use n def-rep use-rep spill-slot? ;
  16
  17 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  18
  19 TUPLE: live-interval-state
  20 vreg
  21 reg spill-to spill-rep reload-from reload-rep
  22 start end ranges uses
  23 reg-class ;
  24
  25 : first-use ( live-interval -- use ) uses>> first ; inline
  26
  27 : last-use ( live-interval -- use ) uses>> last ; inline
  28
  29 : new-use ( insn# uses -- use )
  30     [ <vreg-use> dup ] dip push ;
  31
  32 : last-use? ( insn# uses -- use/f )
  33     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  34
  35 :: (add-use) ( insn# live-interval spill-slot? -- use )
  36     live-interval uses>> :> uses
  37     insn# uses last-use? [ insn# uses new-use ] unless*
  38     spill-slot? [ t >>spill-slot? ] when ;
  39
  40 GENERIC: covers? ( insn# obj -- ? )
  41
  42 M: f covers? 2drop f ;
  43
  44 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  45
  46 M: live-interval-state covers? ( insn# live-interval -- ? )
  47     ranges>>
  48     dup length 4 <= [
  49         [ covers? ] with any?
  50     ] [
  51         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  52         covers?
  53     ] if ;
  54
  55 : (find-use) ( insn# live-interval -- vreg-use )
  56     uses>> [ n>> <=> ] with search nip ;
  57
  58 :: find-use ( insn# live-interval -- vreg-use )
  59     insn# live-interval (find-use)
  60     dup [ dup n>> insn# = [ drop f ] unless ] when ;
  61
  62 : add-new-range ( from to live-interval -- )
  63     [ <live-range> ] dip ranges>> push ;
  64
  65 : shorten-range ( n live-interval -- )
  66     dup ranges>> empty?
  67     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  68
  69 : extend-range ( from to live-range -- )
  70     ranges>> last
  71     [ max ] change-to
  72     [ min ] change-from
  73     drop ;
  74
  75 : extend-range? ( to live-interval -- ? )
  76     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  77
  78 : add-range ( from to live-interval -- )
  79     2dup extend-range?
  80     [ extend-range ] [ add-new-range ] if ;
  81
  82 : <live-interval> ( vreg reg-class -- live-interval )
  83     \ live-interval-state new
  84         V{ } clone >>uses
  85         V{ } clone >>ranges
  86         swap >>reg-class
  87         swap >>vreg ;
  88
  89 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  90
  91 : block-to ( bb -- n ) instructions>> last insn#>> ;
  92
  93 SYMBOLS: from to ;
  94
  95 ! Mapping from vreg to live-interval
  96 SYMBOL: live-intervals
  97
  98 : live-interval ( vreg -- live-interval )
  99     leader live-intervals get
 100     [ dup rep-of reg-class-of <live-interval> ] cache ;
 101
 102 GENERIC: compute-live-intervals* ( insn -- )
 103
 104 M: insn compute-live-intervals* drop ;
 105
 106 :: record-def ( vreg n spill-slot? -- )
 107     vreg live-interval :> live-interval
 108
 109     n live-interval shorten-range
 110     n live-interval spill-slot? (add-use) vreg rep-of >>def-rep drop ;
 111
 112 :: record-use ( vreg n spill-slot? -- )
 113     vreg live-interval :> live-interval
 114
 115     from get n live-interval add-range
 116     n live-interval spill-slot? (add-use) vreg rep-of >>use-rep drop ;
 117
 118 :: record-temp ( vreg n -- )
 119     vreg live-interval :> live-interval
 120
 121     n n live-interval add-range
 122     n live-interval f (add-use) vreg rep-of >>def-rep drop ;
 123
 124 M: vreg-insn compute-live-intervals* ( insn -- )
 125     dup insn#>>
 126     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 127     [ [ uses-vregs ] dip '[ _ f record-use ] each ]
 128     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 129     2tri ;
 130
 131 ! Extend lifetime intervals of base pointers, so that their
 132 ! values are available even if the base pointer is never used
 133 ! again.
 134
 135 GENERIC: uses-vregs* ( insn -- seq )
 136
 137 M: gc-map-insn uses-vregs*
 138     [ uses-vregs ] [ gc-map>> derived-roots>> values ] bi append ;
 139
 140 M: vreg-insn uses-vregs* uses-vregs ;
 141
 142 M: insn uses-vregs* drop f ;
 143
 144 M: clobber-insn compute-live-intervals* ( insn -- )
 145     dup insn#>>
 146     [ [ defs-vregs ] dip '[ _ f record-def ] each ]
 147     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 148     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 149     2tri ;
 150
 151 M: hairy-clobber-insn compute-live-intervals* ( insn -- )
 152     dup insn#>>
 153     [ [ defs-vregs ] dip '[ _ t record-def ] each ]
 154     [ [ uses-vregs* ] dip '[ _ t record-use ] each ]
 155     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 156     2tri ;
 157
 158 : handle-live-out ( bb -- )
 159     live-out dup assoc-empty? [ drop ] [
 160         [ from get to get ] dip keys
 161         [ live-interval add-range ] 2with each
 162     ] if ;
 163
 164 ! A location where all registers have to be spilled
 165 TUPLE: sync-point n keep-dst? ;
 166
 167 C: <sync-point> sync-point
 168
 169 ! Sequence of sync points
 170 SYMBOL: sync-points
 171
 172 GENERIC: compute-sync-points* ( insn -- )
 173
 174 M: hairy-clobber-insn compute-sync-points*
 175     insn#>> f <sync-point> sync-points get push ;
 176
 177 M: clobber-insn compute-sync-points*
 178     insn#>> t <sync-point> sync-points get push ;
 179
 180 M: insn compute-sync-points* drop ;
 181
 182 : compute-live-intervals-step ( bb -- )
 183     dup kill-block?>> [ drop ] [
 184         {
 185             [ block-from from set ]
 186             [ block-to to set ]
 187             [ handle-live-out ]
 188             [
 189                 instructions>> <reversed> [
 190                     [ compute-live-intervals* ]
 191                     [ compute-sync-points* ]
 192                     bi
 193                 ] each
 194             ]
 195         } cleave
 196     ] if ;
 197
 198 : init-live-intervals ( -- )
 199     H{ } clone live-intervals set
 200     V{ } clone sync-points set ;
 201
 202 : compute-start/end ( live-interval -- )
 203     dup ranges>> [ first from>> ] [ last to>> ] bi
 204     [ >>start ] [ >>end ] bi* drop ;
 205
 206 ERROR: bad-live-interval live-interval ;
 207
 208 : check-start ( live-interval -- )
 209     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 210
 211 : finish-live-intervals ( live-intervals -- seq )
 212     ! Since live intervals are computed in a backward order, we have
 213     ! to reverse some sequences, and compute the start and end.
 214     values dup [
 215         {
 216             [ [ { } like reverse! ] change-ranges drop ]
 217             [ [ { } like reverse! ] change-uses drop ]
 218             [ compute-start/end ]
 219             [ check-start ]
 220         } cleave
 221     ] each ;
 222
 223 : compute-live-intervals ( cfg -- live-intervals sync-points )
 224     init-live-intervals
 225     linearization-order <reversed> [ compute-live-intervals-step ] each
 226     live-intervals get finish-live-intervals
 227     sync-points get ;
 228
 229 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 230     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 231
 232 : intersect-live-range ( range1 range2 -- n/f )
 233     2dup [ from>> ] bi@ > [ swap ] when
 234     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 235
 236 : intersect-live-ranges ( ranges1 ranges2 -- n )
 237     {
 238         { [ over empty? ] [ 2drop f ] }
 239         { [ dup empty? ] [ 2drop f ] }
 240         [
 241             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 242                 drop
 243                 2dup [ first from>> ] bi@ <
 244                 [ [ rest-slice ] dip ] [ rest-slice ] if
 245                 intersect-live-ranges
 246             ] if
 247         ]
 248     } cond ;
 249
 250 : intervals-intersect? ( interval1 interval2 -- ? )
 251     relevant-ranges intersect-live-ranges >boolean ; inline