basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors locals sequences math
   4 math.order fry combinators binary-search
   5 compiler.cfg.instructions
   6 compiler.cfg.registers
   7 compiler.cfg.def-use
   8 compiler.cfg.liveness
   9 compiler.cfg.linearization
  10 compiler.cfg.ssa.destruction
  11 compiler.cfg
  12 cpu.architecture ;
  13 IN: compiler.cfg.linear-scan.live-intervals
  14
  15 TUPLE: live-range from to ;
  16
  17 C: <live-range> live-range
  18
  19 TUPLE: vreg-use n def-rep use-rep ;
  20
  21 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  22
  23 TUPLE: live-interval
  24 vreg
  25 reg spill-to spill-rep reload-from reload-rep
  26 start end ranges uses
  27 reg-class ;
  28
  29 : first-use ( live-interval -- use ) uses>> first ; inline
  30
  31 : last-use ( live-interval -- use ) uses>> last ; inline
  32
  33 : new-use ( insn# uses -- use )
  34     [ <vreg-use> dup ] dip push ;
  35
  36 : last-use? ( insn# uses -- use/f )
  37     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  38
  39 : (add-use) ( insn# live-interval -- use )
  40     uses>> 2dup last-use? dup [ 2nip ] [ drop new-use ] if ;
  41
  42 GENERIC: covers? ( insn# obj -- ? )
  43
  44 M: f covers? 2drop f ;
  45
  46 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  47
  48 M: live-interval covers? ( insn# live-interval -- ? )
  49     ranges>>
  50     dup length 4 <= [
  51         [ covers? ] with any?
  52     ] [
  53         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  54         covers?
  55     ] if ;
  56
  57 : (find-use) ( insn# live-interval -- vreg-use )
  58     uses>> [ n>> <=> ] with search nip ;
  59
  60 :: find-use ( insn# live-interval -- vreg-use )
  61     insn# live-interval (find-use)
  62     dup [ dup n>> insn# = [ drop f ] unless ] when ;
  63
  64 : add-new-range ( from to live-interval -- )
  65     [ <live-range> ] dip ranges>> push ;
  66
  67 : shorten-range ( n live-interval -- )
  68     dup ranges>> empty?
  69     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  70
  71 : extend-range ( from to live-range -- )
  72     ranges>> last
  73     [ max ] change-to
  74     [ min ] change-from
  75     drop ;
  76
  77 : extend-range? ( to live-interval -- ? )
  78     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  79
  80 : add-range ( from to live-interval -- )
  81     2dup extend-range?
  82     [ extend-range ] [ add-new-range ] if ;
  83
  84 : <live-interval> ( vreg reg-class -- live-interval )
  85     \ live-interval new
  86         V{ } clone >>uses
  87         V{ } clone >>ranges
  88         swap >>reg-class
  89         swap >>vreg ;
  90
  91 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  92
  93 : block-to ( bb -- n ) instructions>> last insn#>> ;
  94
  95 SYMBOLS: from to ;
  96
  97 ! Mapping from vreg to live-interval
  98 SYMBOL: live-intervals
  99
 100 : live-interval ( vreg -- live-interval )
 101     leader live-intervals get
 102     [ dup rep-of reg-class-of <live-interval> ] cache ;
 103
 104 GENERIC: compute-live-intervals* ( insn -- )
 105
 106 M: insn compute-live-intervals* drop ;
 107
 108 :: record-def ( vreg n -- )
 109     vreg live-interval :> live-interval
 110
 111     n live-interval shorten-range
 112     n live-interval (add-use) vreg rep-of >>def-rep drop ;
 113
 114 :: record-use ( vreg n -- )
 115     vreg live-interval :> live-interval
 116
 117     from get n live-interval add-range
 118     n live-interval (add-use) vreg rep-of >>use-rep drop ;
 119
 120 :: record-temp ( vreg n -- )
 121     vreg live-interval :> live-interval
 122
 123     n n live-interval add-range
 124     n live-interval (add-use) vreg rep-of >>def-rep drop ;
 125
 126 M: vreg-insn compute-live-intervals* ( insn -- )
 127     dup insn#>>
 128     [ [ defs-vregs ] dip '[ _ record-def ] each ]
 129     [ [ uses-vregs ] dip '[ _ record-use ] each ]
 130     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 131     2tri ;
 132
 133 : handle-live-out ( bb -- )
 134     live-out dup assoc-empty? [ drop ] [
 135         [ from get to get ] dip keys
 136         [ live-interval add-range ] with with each
 137     ] if ;
 138
 139 ! A location where all registers have to be spilled
 140 TUPLE: sync-point n keep-dst? ;
 141
 142 C: <sync-point> sync-point
 143
 144 ! Sequence of sync points
 145 SYMBOL: sync-points
 146
 147 GENERIC: compute-sync-points* ( insn -- )
 148
 149 M: hairy-clobber-insn compute-sync-points*
 150     insn#>> f <sync-point> sync-points get push ;
 151
 152 M: clobber-insn compute-sync-points*
 153     insn#>> t <sync-point> sync-points get push ;
 154
 155 M: insn compute-sync-points* drop ;
 156
 157 : compute-live-intervals-step ( bb -- )
 158     {
 159         [ block-from from set ]
 160         [ block-to to set ]
 161         [ handle-live-out ]
 162         [
 163             instructions>> <reversed> [
 164                 [ compute-live-intervals* ]
 165                 [ compute-sync-points* ]
 166                 bi
 167             ] each
 168         ]
 169     } cleave ;
 170
 171 : init-live-intervals ( -- )
 172     H{ } clone live-intervals set
 173     V{ } clone sync-points set ;
 174
 175 : compute-start/end ( live-interval -- )
 176     dup ranges>> [ first from>> ] [ last to>> ] bi
 177     [ >>start ] [ >>end ] bi* drop ;
 178
 179 ERROR: bad-live-interval live-interval ;
 180
 181 : check-start ( live-interval -- )
 182     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 183
 184 : finish-live-intervals ( live-intervals -- seq )
 185     ! Since live intervals are computed in a backward order, we have
 186     ! to reverse some sequences, and compute the start and end.
 187     values dup [
 188         {
 189             [ [ { } like reverse! ] change-ranges drop ]
 190             [ [ { } like reverse! ] change-uses drop ]
 191             [ compute-start/end ]
 192             [ check-start ]
 193         } cleave
 194     ] each ;
 195
 196 : compute-live-intervals ( cfg -- live-intervals sync-points )
 197     init-live-intervals
 198     linearization-order <reversed> [ compute-live-intervals-step ] each
 199     live-intervals get finish-live-intervals
 200     sync-points get ;
 201
 202 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 203     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 204
 205 : intersect-live-range ( range1 range2 -- n/f )
 206     2dup [ from>> ] bi@ > [ swap ] when
 207     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 208
 209 : intersect-live-ranges ( ranges1 ranges2 -- n )
 210     {
 211         { [ over empty? ] [ 2drop f ] }
 212         { [ dup empty? ] [ 2drop f ] }
 213         [
 214             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 215                 drop
 216                 2dup [ first from>> ] bi@ <
 217                 [ [ rest-slice ] dip ] [ rest-slice ] if
 218                 intersect-live-ranges
 219             ] if
 220         ]
 221     } cond ;
 222
 223 : intervals-intersect? ( interval1 interval2 -- ? )
 224     relevant-ranges intersect-live-ranges >boolean ; inline