basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors locals sequences math
   4 math.order fry combinators binary-search
   5 compiler.cfg.instructions
   6 compiler.cfg.registers
   7 compiler.cfg.def-use
   8 compiler.cfg.liveness
   9 compiler.cfg.linearization
  10 compiler.cfg.ssa.destruction
  11 compiler.cfg
  12 cpu.architecture ;
  13 IN: compiler.cfg.linear-scan.live-intervals
  14
  15 TUPLE: live-range from to ;
  16
  17 C: <live-range> live-range
  18
  19 TUPLE: vreg-use n def-rep use-rep ;
  20
  21 : <vreg-use> ( n -- vreg-use ) vreg-use new swap >>n ;
  22
  23 TUPLE: live-interval
  24 vreg
  25 reg spill-to spill-rep reload-from reload-rep
  26 start end ranges uses
  27 reg-class ;
  28
  29 : first-use ( live-interval -- use ) uses>> first ; inline
  30
  31 : last-use ( live-interval -- use ) uses>> last ; inline
  32
  33 : new-use ( insn# uses -- use )
  34     [ <vreg-use> dup ] dip push ;
  35
  36 : last-use? ( insn# uses -- use/f )
  37     [ drop f ] [ last [ n>> = ] keep and ] if-empty ;
  38
  39 : (add-use) ( insn# live-interval -- use )
  40     uses>> 2dup last-use? dup [ 2nip ] [ drop new-use ] if ;
  41
  42 GENERIC: covers? ( insn# obj -- ? )
  43
  44 M: f covers? 2drop f ;
  45
  46 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  47
  48 M: live-interval covers? ( insn# live-interval -- ? )
  49     ranges>>
  50     dup length 4 <= [
  51         [ covers? ] with any?
  52     ] [
  53         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  54         covers?
  55     ] if ;
  56
  57 : add-new-range ( from to live-interval -- )
  58     [ <live-range> ] dip ranges>> push ;
  59
  60 : shorten-range ( n live-interval -- )
  61     dup ranges>> empty?
  62     [ dupd add-new-range ] [ ranges>> last from<< ] if ;
  63
  64 : extend-range ( from to live-range -- )
  65     ranges>> last
  66     [ max ] change-to
  67     [ min ] change-from
  68     drop ;
  69
  70 : extend-range? ( to live-interval -- ? )
  71     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  72
  73 : add-range ( from to live-interval -- )
  74     2dup extend-range?
  75     [ extend-range ] [ add-new-range ] if ;
  76
  77 : <live-interval> ( vreg reg-class -- live-interval )
  78     \ live-interval new
  79         V{ } clone >>uses
  80         V{ } clone >>ranges
  81         swap >>reg-class
  82         swap >>vreg ;
  83
  84 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  85
  86 : block-to ( bb -- n ) instructions>> last insn#>> ;
  87
  88 SYMBOLS: from to ;
  89
  90 ! Mapping from vreg to live-interval
  91 SYMBOL: live-intervals
  92
  93 : live-interval ( vreg -- live-interval )
  94     leader live-intervals get
  95     [ dup rep-of reg-class-of <live-interval> ] cache ;
  96
  97 GENERIC: compute-live-intervals* ( insn -- )
  98
  99 M: insn compute-live-intervals* drop ;
 100
 101 :: record-def ( vreg n -- )
 102     vreg live-interval :> live-interval
 103
 104     n live-interval shorten-range
 105     n live-interval (add-use) vreg rep-of >>def-rep drop ;
 106
 107 :: record-use ( vreg n -- )
 108     vreg live-interval :> live-interval
 109
 110     from get n live-interval add-range
 111     n live-interval (add-use) vreg rep-of >>use-rep drop ;
 112
 113 :: record-temp ( vreg n -- )
 114     vreg live-interval :> live-interval
 115
 116     n n live-interval add-range
 117     n live-interval (add-use) vreg rep-of >>def-rep drop ;
 118
 119 M: vreg-insn compute-live-intervals* ( insn -- )
 120     dup insn#>>
 121     [ [ defs-vreg ] dip '[ _ record-def ] when* ]
 122     [ [ uses-vregs ] dip '[ _ record-use ] each ]
 123     [ [ temp-vregs ] dip '[ _ record-temp ] each ]
 124     2tri ;
 125
 126 : handle-live-out ( bb -- )
 127     live-out dup assoc-empty? [ drop ] [
 128         [ from get to get ] dip keys
 129         [ live-interval add-range ] with with each
 130     ] if ;
 131
 132 ! A location where all registers have to be spilled
 133 TUPLE: sync-point n ;
 134
 135 C: <sync-point> sync-point
 136
 137 ! Sequence of sync points
 138 SYMBOL: sync-points
 139
 140 GENERIC: compute-sync-points* ( insn -- )
 141
 142 M: clobber-insn compute-sync-points*
 143     insn#>> <sync-point> sync-points get push ;
 144
 145 M: insn compute-sync-points* drop ;
 146
 147 : compute-live-intervals-step ( bb -- )
 148     {
 149         [ block-from from set ]
 150         [ block-to to set ]
 151         [ handle-live-out ]
 152         [
 153             instructions>> <reversed> [
 154                 [ compute-live-intervals* ]
 155                 [ compute-sync-points* ]
 156                 bi
 157             ] each
 158         ]
 159     } cleave ;
 160
 161 : init-live-intervals ( -- )
 162     H{ } clone live-intervals set
 163     V{ } clone sync-points set ;
 164
 165 : compute-start/end ( live-interval -- )
 166     dup ranges>> [ first from>> ] [ last to>> ] bi
 167     [ >>start ] [ >>end ] bi* drop ;
 168
 169 ERROR: bad-live-interval live-interval ;
 170
 171 : check-start ( live-interval -- )
 172     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 173
 174 : finish-live-intervals ( live-intervals -- seq )
 175     ! Since live intervals are computed in a backward order, we have
 176     ! to reverse some sequences, and compute the start and end.
 177     values dup [
 178         {
 179             [ ranges>> reverse! drop ]
 180             [ uses>> reverse! drop ]
 181             [ compute-start/end ]
 182             [ check-start ]
 183         } cleave
 184     ] each ;
 185
 186 : compute-live-intervals ( cfg -- live-intervals sync-points )
 187     init-live-intervals
 188     linearization-order <reversed> [ compute-live-intervals-step ] each
 189     live-intervals get finish-live-intervals
 190     sync-points get ;
 191
 192 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 193     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 194
 195 : intersect-live-range ( range1 range2 -- n/f )
 196     2dup [ from>> ] bi@ > [ swap ] when
 197     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 198
 199 : intersect-live-ranges ( ranges1 ranges2 -- n )
 200     {
 201         { [ over empty? ] [ 2drop f ] }
 202         { [ dup empty? ] [ 2drop f ] }
 203         [
 204             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 205                 drop
 206                 2dup [ first from>> ] bi@ <
 207                 [ [ rest-slice ] dip ] [ rest-slice ] if
 208                 intersect-live-ranges
 209             ] if
 210         ]
 211     } cond ;
 212
 213 : intervals-intersect? ( interval1 interval2 -- ? )
 214     relevant-ranges intersect-live-ranges >boolean ; inline