basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors sequences math math.order fry
   4 combinators binary-search compiler.cfg.instructions compiler.cfg.registers
   5 compiler.cfg.def-use compiler.cfg.liveness compiler.cfg.linearization.order
   6 compiler.cfg ;
   7 IN: compiler.cfg.linear-scan.live-intervals
   8
   9 TUPLE: live-range from to ;
  10
  11 C: <live-range> live-range
  12
  13 TUPLE: live-interval
  14 vreg
  15 reg spill-to reload-from
  16 start end ranges uses ;
  17
  18 GENERIC: covers? ( insn# obj -- ? )
  19
  20 M: f covers? 2drop f ;
  21
  22 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  23
  24 M: live-interval covers? ( insn# live-interval -- ? )
  25     ranges>>
  26     dup length 4 <= [
  27         [ covers? ] with any?
  28     ] [
  29         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  30         covers?
  31     ] if ;
  32
  33 ERROR: dead-value-error vreg ;
  34
  35 : add-new-range ( from to live-interval -- )
  36     [ <live-range> ] dip ranges>> push ;
  37
  38 : shorten-range ( n live-interval -- )
  39     dup ranges>> empty?
  40     [ dupd add-new-range ] [ ranges>> last (>>from) ] if ;
  41
  42 : extend-range ( from to live-range -- )
  43     ranges>> last
  44     [ max ] change-to
  45     [ min ] change-from
  46     drop ;
  47
  48 : extend-range? ( to live-interval -- ? )
  49     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  50
  51 : add-range ( from to live-interval -- )
  52     2dup extend-range?
  53     [ extend-range ] [ add-new-range ] if ;
  54
  55 GENERIC: operands-in-registers? ( insn -- ? )
  56
  57 M: vreg-insn operands-in-registers? drop t ;
  58
  59 M: partial-sync-insn operands-in-registers? drop f ;
  60
  61 : add-def ( insn live-interval -- )
  62     [ insn#>> ] [ uses>> ] bi* push ;
  63
  64 : add-use ( insn live-interval -- )
  65     ! Every use is a potential def, no SSA here baby!
  66     over operands-in-registers? [ add-def ] [ 2drop ] if ;
  67
  68 : <live-interval> ( vreg -- live-interval )
  69     \ live-interval new
  70         V{ } clone >>uses
  71         V{ } clone >>ranges
  72         swap >>vreg ;
  73
  74 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  75
  76 : block-to ( bb -- n ) instructions>> last insn#>> ;
  77
  78 M: live-interval hashcode*
  79     nip [ start>> ] [ end>> 1000 * ] bi + ;
  80
  81 ! Mapping from vreg to live-interval
  82 SYMBOL: live-intervals
  83
  84 : live-interval ( vreg -- live-interval )
  85     live-intervals get [ <live-interval> ] cache ;
  86
  87 GENERIC: compute-live-intervals* ( insn -- )
  88
  89 M: insn compute-live-intervals* drop ;
  90
  91 : handle-output ( insn vreg -- )
  92     live-interval
  93     [ [ insn#>> ] dip shorten-range ] [ add-def ] 2bi ;
  94
  95 : handle-input ( insn vreg -- )
  96     live-interval
  97     [ [ [ basic-block get block-from ] dip insn#>> ] dip add-range ] [ add-use ] 2bi ;
  98
  99 : handle-temp ( insn vreg -- )
 100     live-interval
 101     [ [ insn#>> dup ] dip add-range ] [ add-use ] 2bi ;
 102
 103 M: vreg-insn compute-live-intervals*
 104     [ dup defs-vreg [ handle-output ] with when* ]
 105     [ dup uses-vregs [ handle-input ] with each ]
 106     [ dup temp-vregs [ handle-temp ] with each ]
 107     tri ;
 108
 109 : handle-live-out ( bb -- )
 110     [ block-from ] [ block-to ] [ live-out keys ] tri
 111     [ live-interval add-range ] with with each ;
 112
 113 ! A location where all registers have to be spilled
 114 TUPLE: sync-point n ;
 115
 116 C: <sync-point> sync-point
 117
 118 ! Sequence of sync points
 119 SYMBOL: sync-points
 120
 121 GENERIC: compute-sync-points* ( insn -- )
 122
 123 M: partial-sync-insn compute-sync-points*
 124     insn#>> <sync-point> sync-points get push ;
 125
 126 M: insn compute-sync-points* drop ;
 127
 128 : compute-live-intervals-step ( bb -- )
 129     [ basic-block set ]
 130     [ handle-live-out ]
 131     [
 132         instructions>> <reversed> [
 133             [ compute-live-intervals* ]
 134             [ compute-sync-points* ]
 135             bi
 136         ] each
 137     ] tri ;
 138
 139 : init-live-intervals ( -- )
 140     H{ } clone live-intervals set
 141     V{ } clone sync-points set ;
 142
 143 : compute-start/end ( live-interval -- )
 144     dup ranges>> [ first from>> ] [ last to>> ] bi
 145     [ >>start ] [ >>end ] bi* drop ;
 146
 147 ERROR: bad-live-interval live-interval ;
 148
 149 : check-start ( live-interval -- )
 150     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 151
 152 : finish-live-intervals ( live-intervals -- seq )
 153     ! Since live intervals are computed in a backward order, we have
 154     ! to reverse some sequences, and compute the start and end.
 155     values dup [
 156         {
 157             [ ranges>> reverse-here ]
 158             [ uses>> reverse-here ]
 159             [ compute-start/end ]
 160             [ check-start ]
 161         } cleave
 162     ] each ;
 163
 164 : compute-live-intervals ( cfg -- live-intervals sync-points )
 165     init-live-intervals
 166     linearization-order <reversed> [ compute-live-intervals-step ] each
 167     live-intervals get finish-live-intervals
 168     sync-points get ;
 169
 170 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 171     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 172
 173 : intersect-live-range ( range1 range2 -- n/f )
 174     2dup [ from>> ] bi@ > [ swap ] when
 175     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 176
 177 : intersect-live-ranges ( ranges1 ranges2 -- n )
 178     {
 179         { [ over empty? ] [ 2drop f ] }
 180         { [ dup empty? ] [ 2drop f ] }
 181         [
 182             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 183                 drop
 184                 2dup [ first from>> ] bi@ <
 185                 [ [ rest-slice ] dip ] [ rest-slice ] if
 186                 intersect-live-ranges
 187             ] if
 188         ]
 189     } cond ;
 190
 191 : intervals-intersect? ( interval1 interval2 -- ? )
 192     relevant-ranges intersect-live-ranges >boolean ; inline