basis/compiler/cfg/linear-scan/live-intervals/live-intervals.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces kernel assocs accessors sequences math math.order fry
   4 combinators binary-search compiler.cfg.instructions compiler.cfg.registers
   5 compiler.cfg.def-use compiler.cfg.liveness compiler.cfg.linearization.order
   6 compiler.cfg ;
   7 IN: compiler.cfg.linear-scan.live-intervals
   8
   9 TUPLE: live-range from to ;
  10
  11 C: <live-range> live-range
  12
  13 TUPLE: live-interval
  14 vreg
  15 reg spill-to reload-from
  16 start end ranges uses ;
  17
  18 GENERIC: covers? ( insn# obj -- ? )
  19
  20 M: f covers? 2drop f ;
  21
  22 M: live-range covers? [ from>> ] [ to>> ] bi between? ;
  23
  24 M: live-interval covers? ( insn# live-interval -- ? )
  25     ranges>>
  26     dup length 4 <= [
  27         [ covers? ] with any?
  28     ] [
  29         [ drop ] [ [ from>> <=> ] with search nip ] 2bi
  30         covers?
  31     ] if ;
  32
  33 : add-new-range ( from to live-interval -- )
  34     [ <live-range> ] dip ranges>> push ;
  35
  36 : shorten-range ( n live-interval -- )
  37     dup ranges>> empty?
  38     [ dupd add-new-range ] [ ranges>> last (>>from) ] if ;
  39
  40 : extend-range ( from to live-range -- )
  41     ranges>> last
  42     [ max ] change-to
  43     [ min ] change-from
  44     drop ;
  45
  46 : extend-range? ( to live-interval -- ? )
  47     ranges>> [ drop f ] [ last from>> >= ] if-empty ;
  48
  49 : add-range ( from to live-interval -- )
  50     2dup extend-range?
  51     [ extend-range ] [ add-new-range ] if ;
  52
  53 GENERIC: operands-in-registers? ( insn -- ? )
  54
  55 M: vreg-insn operands-in-registers? drop t ;
  56
  57 M: partial-sync-insn operands-in-registers? drop f ;
  58
  59 : add-def ( insn live-interval -- )
  60     [ insn#>> ] [ uses>> ] bi* push ;
  61
  62 : add-use ( insn live-interval -- )
  63     ! Every use is a potential def, no SSA here baby!
  64     over operands-in-registers? [ add-def ] [ 2drop ] if ;
  65
  66 : <live-interval> ( vreg -- live-interval )
  67     \ live-interval new
  68         V{ } clone >>uses
  69         V{ } clone >>ranges
  70         swap >>vreg ;
  71
  72 : block-from ( bb -- n ) instructions>> first insn#>> 1 - ;
  73
  74 : block-to ( bb -- n ) instructions>> last insn#>> ;
  75
  76 M: live-interval hashcode*
  77     nip [ start>> ] [ end>> 1000 * ] bi + ;
  78
  79 ! Mapping from vreg to live-interval
  80 SYMBOL: live-intervals
  81
  82 : live-interval ( vreg -- live-interval )
  83     live-intervals get [ <live-interval> ] cache ;
  84
  85 GENERIC: compute-live-intervals* ( insn -- )
  86
  87 M: insn compute-live-intervals* drop ;
  88
  89 : handle-output ( insn vreg -- )
  90     live-interval
  91     [ [ insn#>> ] dip shorten-range ] [ add-def ] 2bi ;
  92
  93 : handle-input ( insn vreg -- )
  94     live-interval
  95     [ [ [ basic-block get block-from ] dip insn#>> ] dip add-range ] [ add-use ] 2bi ;
  96
  97 : handle-temp ( insn vreg -- )
  98     live-interval
  99     [ [ insn#>> dup ] dip add-range ] [ add-use ] 2bi ;
 100
 101 M: vreg-insn compute-live-intervals*
 102     [ dup defs-vreg [ handle-output ] with when* ]
 103     [ dup uses-vregs [ handle-input ] with each ]
 104     [ dup temp-vregs [ handle-temp ] with each ]
 105     tri ;
 106
 107 : handle-live-out ( bb -- )
 108     [ block-from ] [ block-to ] [ live-out keys ] tri
 109     [ live-interval add-range ] with with each ;
 110
 111 ! A location where all registers have to be spilled
 112 TUPLE: sync-point n ;
 113
 114 C: <sync-point> sync-point
 115
 116 ! Sequence of sync points
 117 SYMBOL: sync-points
 118
 119 GENERIC: compute-sync-points* ( insn -- )
 120
 121 M: partial-sync-insn compute-sync-points*
 122     insn#>> <sync-point> sync-points get push ;
 123
 124 M: insn compute-sync-points* drop ;
 125
 126 : compute-live-intervals-step ( bb -- )
 127     [ basic-block set ]
 128     [ handle-live-out ]
 129     [
 130         instructions>> <reversed> [
 131             [ compute-live-intervals* ]
 132             [ compute-sync-points* ]
 133             bi
 134         ] each
 135     ] tri ;
 136
 137 : init-live-intervals ( -- )
 138     H{ } clone live-intervals set
 139     V{ } clone sync-points set ;
 140
 141 : compute-start/end ( live-interval -- )
 142     dup ranges>> [ first from>> ] [ last to>> ] bi
 143     [ >>start ] [ >>end ] bi* drop ;
 144
 145 ERROR: bad-live-interval live-interval ;
 146
 147 : check-start ( live-interval -- )
 148     dup start>> -1 = [ bad-live-interval ] [ drop ] if ;
 149
 150 : finish-live-intervals ( live-intervals -- seq )
 151     ! Since live intervals are computed in a backward order, we have
 152     ! to reverse some sequences, and compute the start and end.
 153     values dup [
 154         {
 155             [ ranges>> reverse! drop ]
 156             [ uses>> reverse! drop ]
 157             [ compute-start/end ]
 158             [ check-start ]
 159         } cleave
 160     ] each ;
 161
 162 : compute-live-intervals ( cfg -- live-intervals sync-points )
 163     init-live-intervals
 164     linearization-order <reversed> [ compute-live-intervals-step ] each
 165     live-intervals get finish-live-intervals
 166     sync-points get ;
 167
 168 : relevant-ranges ( interval1 interval2 -- ranges1 ranges2 )
 169     [ [ ranges>> ] bi@ ] [ nip start>> ] 2bi '[ to>> _ >= ] filter ;
 170
 171 : intersect-live-range ( range1 range2 -- n/f )
 172     2dup [ from>> ] bi@ > [ swap ] when
 173     2dup [ to>> ] [ from>> ] bi* >= [ nip from>> ] [ 2drop f ] if ;
 174
 175 : intersect-live-ranges ( ranges1 ranges2 -- n )
 176     {
 177         { [ over empty? ] [ 2drop f ] }
 178         { [ dup empty? ] [ 2drop f ] }
 179         [
 180             2dup [ first ] bi@ intersect-live-range dup [ 2nip ] [
 181                 drop
 182                 2dup [ first from>> ] bi@ <
 183                 [ [ rest-slice ] dip ] [ rest-slice ] if
 184                 intersect-live-ranges
 185             ] if
 186         ]
 187     } cond ;
 188
 189 : intervals-intersect? ( interval1 interval2 -- ? )
 190     relevant-ranges intersect-live-ranges >boolean ; inline