basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs fry kernel namespaces
   4 sequences sequences.deep
   5 sets vectors
   6 compiler.cfg.rpo
   7 compiler.cfg.def-use
   8 compiler.cfg.renaming
   9 compiler.cfg.registers
  10 compiler.cfg.dominance
  11 compiler.cfg.instructions
  12 compiler.cfg.liveness.ssa
  13 compiler.cfg.ssa.cssa
  14 compiler.cfg.ssa.interference
  15 compiler.cfg.ssa.interference.live-ranges
  16 compiler.cfg.utilities
  17 compiler.utilities ;
  18 FROM: namespaces => set ;
  19 IN: compiler.cfg.ssa.destruction
  20
  21 ! Maps vregs to leaders.
  22 SYMBOL: leader-map
  23
  24 : leader ( vreg -- vreg' ) leader-map get compress-path ;
  25
  26 ! Maps leaders to equivalence class elements.
  27 SYMBOL: class-element-map
  28
  29 : class-elements ( vreg -- elts ) class-element-map get at ;
  30
  31 ! Sequence of vreg pairs
  32 SYMBOL: copies
  33
  34 : init-coalescing ( -- )
  35     H{ } clone leader-map set
  36     H{ } clone class-element-map set
  37     V{ } clone copies set ;
  38
  39 : classes-interfere? ( vreg1 vreg2 -- ? )
  40     [ leader ] bi@ 2dup eq? [ 2drop f ] [
  41         [ class-elements flatten ] bi@ sets-interfere?
  42     ] if ;
  43
  44 : update-leaders ( vreg1 vreg2 -- )
  45     swap leader-map get set-at ;
  46
  47 : merge-classes ( vreg1 vreg2 -- )
  48     [ [ class-elements ] bi@ push ]
  49     [ drop class-element-map get delete-at ] 2bi ;
  50
  51 : eliminate-copy ( vreg1 vreg2 -- )
  52     [ leader ] bi@
  53     2dup eq? [ 2drop ] [
  54         [ update-leaders ]
  55         [ merge-classes ]
  56         2bi
  57     ] if ;
  58
  59 : introduce-vreg ( vreg -- )
  60     [ leader-map get conjoin ]
  61     [ [ 1vector ] keep class-element-map get set-at ] bi ;
  62
  63 GENERIC: prepare-insn ( insn -- )
  64
  65 : try-to-coalesce ( dst src -- ) 2array copies get push ;
  66
  67 M: insn prepare-insn
  68     [ defs-vreg ] [ uses-vregs ] bi
  69     2dup empty? not and [
  70         first
  71         2dup [ rep-of ] bi@ eq?
  72         [ try-to-coalesce ] [ 2drop ] if
  73     ] [ 2drop ] if ;
  74
  75 M: ##copy prepare-insn
  76     [ dst>> ] [ src>> ] bi try-to-coalesce ;
  77
  78 M: ##phi prepare-insn
  79     [ dst>> ] [ inputs>> values ] bi
  80     [ eliminate-copy ] with each ;
  81
  82 : prepare-block ( bb -- )
  83     instructions>> [ prepare-insn ] each ;
  84
  85 : prepare-coalescing ( cfg -- )
  86     init-coalescing
  87     defs get keys [ introduce-vreg ] each
  88     [ prepare-block ] each-basic-block ;
  89
  90 : process-copies ( -- )
  91     copies get [
  92         2dup classes-interfere?
  93         [ 2drop ] [ eliminate-copy ] if
  94     ] assoc-each ;
  95
  96 : useless-copy? ( ##copy -- ? )
  97     dup ##copy? [ [ dst>> ] [ src>> ] bi eq? ] [ drop f ] if ;
  98
  99 : perform-renaming ( cfg -- )
 100     leader-map get keys [ dup leader ] H{ } map>assoc renamings set
 101     [
 102         instructions>> [
 103             [ rename-insn-defs ]
 104             [ rename-insn-uses ]
 105             [ [ useless-copy? ] [ ##phi? ] bi or not ] tri
 106         ] filter! drop
 107     ] each-basic-block ;
 108
 109 : destruct-ssa ( cfg -- cfg' )
 110     needs-dominance
 111
 112     dup construct-cssa
 113     dup compute-defs
 114     compute-ssa-live-sets
 115     dup compute-live-ranges
 116     dup prepare-coalescing
 117     process-copies
 118     dup perform-renaming ;