basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs fry kernel namespaces
   4 sequences sequences.deep
   5 sets vectors
   6 compiler.cfg.rpo
   7 compiler.cfg.def-use
   8 compiler.cfg.renaming
   9 compiler.cfg.dominance
  10 compiler.cfg.instructions
  11 compiler.cfg.liveness.ssa
  12 compiler.cfg.ssa.cssa
  13 compiler.cfg.ssa.interference
  14 compiler.cfg.ssa.interference.live-ranges
  15 compiler.utilities ;
  16 IN: compiler.cfg.ssa.destruction
  17
  18 ! Maps vregs to leaders.
  19 SYMBOL: leader-map
  20
  21 : leader ( vreg -- vreg' ) leader-map get compress-path ;
  22
  23 ! Maps leaders to equivalence class elements.
  24 SYMBOL: class-element-map
  25
  26 : class-elements ( vreg -- elts ) class-element-map get at ;
  27
  28 ! Sequence of vreg pairs
  29 SYMBOL: copies
  30
  31 : init-coalescing ( -- )
  32     H{ } clone leader-map set
  33     H{ } clone class-element-map set
  34     V{ } clone copies set ;
  35
  36 : classes-interfere? ( vreg1 vreg2 -- ? )
  37     [ leader ] bi@ 2dup eq? [ 2drop f ] [
  38         [ class-elements flatten ] bi@ sets-interfere?
  39     ] if ;
  40
  41 : update-leaders ( vreg1 vreg2 -- )
  42     swap leader-map get set-at ;
  43
  44 : merge-classes ( vreg1 vreg2 -- )
  45     [ [ class-elements ] bi@ push ]
  46     [ drop class-element-map get delete-at ] 2bi ;
  47
  48 : eliminate-copy ( vreg1 vreg2 -- )
  49     [ leader ] bi@
  50     2dup eq? [ 2drop ] [
  51         [ update-leaders ] [ merge-classes ] 2bi
  52     ] if ;
  53
  54 : introduce-vreg ( vreg -- )
  55     [ leader-map get conjoin ]
  56     [ [ 1vector ] keep class-element-map get set-at ] bi ;
  57
  58 GENERIC: prepare-insn ( insn -- )
  59
  60 M: ##copy prepare-insn
  61     [ dst>> ] [ src>> ] bi 2array copies get push ;
  62
  63 M: ##phi prepare-insn
  64     [ dst>> ] [ inputs>> values ] bi
  65     [ eliminate-copy ] with each ;
  66
  67 M: insn prepare-insn drop ;
  68
  69 : prepare-block ( bb -- )
  70     instructions>> [ prepare-insn ] each ;
  71
  72 : prepare-coalescing ( cfg -- )
  73     init-coalescing
  74     defs get keys [ introduce-vreg ] each
  75     [ prepare-block ] each-basic-block ;
  76
  77 : process-copies ( -- )
  78     copies get [
  79         2dup classes-interfere?
  80         [ 2drop ] [ eliminate-copy ] if
  81     ] assoc-each ;
  82
  83 : useless-copy? ( ##copy -- ? )
  84     dup ##copy? [ [ dst>> ] [ src>> ] bi eq? ] [ drop f ] if ;
  85
  86 : perform-renaming ( cfg -- )
  87     leader-map get keys [ dup leader ] H{ } map>assoc renamings set
  88     [
  89         instructions>> [
  90             [ rename-insn-defs ]
  91             [ rename-insn-uses ]
  92             [ [ useless-copy? ] [ ##phi? ] bi or not ] tri
  93         ] filter-here
  94     ] each-basic-block ;
  95
  96 : destruct-ssa ( cfg -- cfg' )
  97     dup construct-cssa
  98     compute-ssa-live-sets
  99     dup compute-defs
 100     dup compute-dominance
 101     dup compute-live-ranges
 102     dup prepare-coalescing
 103     process-copies
 104     dup perform-renaming ;