basis/compiler/cfg/stack-frame/stack-frame.factor

   1 ! Copyright (C) 2009, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: math math.order namespaces accessors kernel layouts
   4 combinators assocs sequences cpu.architecture
   5 words compiler.cfg.instructions ;
   6 IN: compiler.cfg.stack-frame
   7
   8 TUPLE: stack-frame
   9 { params integer }
  10 { return integer }
  11 { spill-area-size integer }
  12 { total-size integer }
  13 { calls-vm? boolean } ;
  14
  15 ! Stack frame utilities
  16 : return-offset ( -- offset )
  17     stack-frame get params>> ;
  18
  19 : spill-offset ( n -- offset )
  20     stack-frame get [ params>> ] [ return>> ] bi + + ;
  21
  22 : (stack-frame-size) ( stack-frame -- n )
  23     [ params>> ] [ return>> ] [ spill-area-size>> ] tri + + ;
  24
  25 : max-stack-frame ( frame1 frame2 -- frame3 )
  26     [ stack-frame new ] 2dip
  27     {
  28         [ [ params>> ] bi@ max >>params ]
  29         [ [ return>> ] bi@ max >>return ]
  30         [ [ spill-area-size>> ] bi@ max >>spill-area-size ]
  31         [ [ calls-vm?>> ] bi@ or >>calls-vm? ]
  32     } 2cleave ;
  33
  34 ! PowerPC backend sets frame-required? for ##integer>float too
  35 \ ##spill t "frame-required?" set-word-prop
  36 \ ##unary-float-function t "frame-required?" set-word-prop
  37 \ ##binary-float-function t "frame-required?" set-word-prop