basis/compiler/cfg/stacks/local/local.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators compiler.cfg
   4 compiler.cfg.instructions compiler.cfg.parallel-copy
   5 compiler.cfg.registers compiler.cfg.stacks.height
   6 kernel make math math.order namespaces sequences sets ;
   7 FROM: namespaces => set ;
   8 IN: compiler.cfg.stacks.local
   9
  10 : >loc< ( loc -- n ds? )
  11     [ n>> ] [ ds-loc? ] bi ;
  12
  13 : modify-height ( state loc -- )
  14     >loc< 0 1 ? rot nth [ + ] with map! drop ;
  15
  16 : adjust ( state loc -- )
  17     >loc< 0 1 ? rot nth dup first swapd + 0 rot set-nth ;
  18
  19 : reset-emits ( state -- )
  20     [ 0 1 rot set-nth ] each ;
  21
  22 : height-state>insns ( state -- insns )
  23     [ second ] map { ds-loc rs-loc } [ new swap >>n ] 2map
  24     [ n>> 0 = not ] filter [ ##inc new swap >>loc ] map ;
  25
  26 : translate-local-loc ( state loc -- loc' )
  27     >loc< [ 0 1 ? rot nth first - ] keep ds-loc rs-loc ? new swap >>n ;
  28
  29 : clone-height-state ( state -- state' )
  30     [ clone ] map ;
  31
  32 : initial-height-state ( -- state )
  33     { { 0 0 } { 0 0 } } clone-height-state ;
  34
  35 : kill-locations ( saved-height height -- seq )
  36     dupd [-] iota [ swap - ] with map ;
  37
  38 : local-kill-set ( ds-height rs-height state -- assoc )
  39     first2 [ first ] bi@ swapd [ kill-locations ] 2bi@
  40     [ [ <ds-loc> ] map ] [ [ <rs-loc> ] map ] bi*
  41     append unique ;
  42
  43 SYMBOLS: height-state peek-sets replace-sets kill-sets locs>vregs ;
  44
  45 : inc-stack ( loc -- )
  46     height-state get swap modify-height ;
  47
  48 : loc>vreg ( loc -- vreg ) locs>vregs get [ drop next-vreg ] cache ;
  49 : vreg>loc ( vreg -- loc/f ) locs>vregs get value-at ;
  50
  51 SYMBOLS: local-peek-set local-replace-set replace-mapping ;
  52
  53 : stack-changes ( replace-mapping -- insns )
  54     [ [ loc>vreg ] dip ] assoc-map parallel-copy ;
  55
  56 : emit-changes ( -- )
  57     building get pop
  58     replace-mapping get stack-changes %
  59     height-state get height-state>insns %
  60     , ;
  61
  62 : peek-loc ( loc -- vreg )
  63     height-state get swap translate-local-loc
  64     dup replace-mapping get at
  65     [ ] [ dup local-peek-set get conjoin loc>vreg ] ?if ;
  66
  67 : replace-loc ( vreg loc -- )
  68     height-state get swap translate-local-loc
  69     replace-mapping get set-at ;
  70
  71 : compute-local-kill-set ( -- assoc )
  72     basic-block get [ rs-heights get at ] [ ds-heights get at ] bi
  73     height-state get local-kill-set ;
  74
  75 : begin-local-analysis ( -- )
  76     H{ } clone local-peek-set set
  77     H{ } clone replace-mapping set
  78     height-state get
  79     [ reset-emits ] [
  80         first2 [ first ] bi@ basic-block get record-stack-heights
  81     ] bi ;
  82
  83 : remove-redundant-replaces ( -- )
  84     replace-mapping get [ [ loc>vreg ] dip = not ] assoc-filter
  85     [ replace-mapping set ] [ keys unique local-replace-set set ] bi ;
  86
  87 : end-local-analysis ( basic-block -- )
  88     remove-redundant-replaces
  89     emit-changes
  90     [ [ local-peek-set get ] dip peek-sets get set-at ]
  91     [ [ local-replace-set get ] dip replace-sets get set-at ]
  92     [ [ compute-local-kill-set ] dip kill-sets get set-at ] tri ;