basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes classes.struct locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 ! Mapping _label IDs to label instances
  36 SYMBOL: labels
  37
  38 : init-generator ( -- )
  39     H{ } clone labels set
  40     V{ } clone calls set ;
  41
  42 : generate-insns ( asm -- code )
  43     dup word>> [
  44         init-generator
  45         instructions>> [
  46             [ class insn-counts get inc-at ]
  47             [ generate-insn ]
  48             bi
  49         ] each
  50     ] with-fixup ;
  51
  52 : generate ( mr -- asm )
  53     [
  54         [ label>> ] [ generate-insns ] bi calls get
  55         asm boa
  56     ] with-scope ;
  57
  58 : lookup-label ( id -- label )
  59     labels get [ drop <label> ] cache ;
  60
  61 ! Special cases
  62 M: ##no-tco generate-insn drop ;
  63
  64 M: ##call generate-insn
  65     word>> dup sub-primitive>>
  66     [ second first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  67
  68 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  69
  70 M: _dispatch-label generate-insn
  71     label>> lookup-label
  72     cell 0 <repetition> %
  73     rc-absolute-cell label-fixup ;
  74
  75 M: _prologue generate-insn
  76     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  77
  78 M: _epilogue generate-insn
  79     stack-frame>> total-size>> %epilogue ;
  80
  81 M: _spill-area-size generate-insn drop ;
  82
  83 ! Some meta-programming to generate simple code generators, where
  84 ! the instruction is unpacked and then a %word is called
  85 <<
  86
  87 : insn-slot-quot ( spec -- quot )
  88     name>> [ reader-word ] [ "label" = ] bi
  89     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  90
  91 : codegen-method-body ( class word -- quot )
  92     [
  93         "insn-slots" word-prop
  94         [ insn-slot-quot ] map cleave>quot
  95     ] dip suffix ;
  96
  97 SYNTAX: CODEGEN:
  98     scan-word [ \ generate-insn create-method-in ] keep scan-word
  99     codegen-method-body define ;
 100 >>
 101
 102 CODEGEN: ##load-immediate %load-immediate
 103 CODEGEN: ##load-reference %load-reference
 104 CODEGEN: ##load-constant %load-reference
 105 CODEGEN: ##peek %peek
 106 CODEGEN: ##replace %replace
 107 CODEGEN: ##inc-d %inc-d
 108 CODEGEN: ##inc-r %inc-r
 109 CODEGEN: ##return %return
 110 CODEGEN: ##slot %slot
 111 CODEGEN: ##slot-imm %slot-imm
 112 CODEGEN: ##set-slot %set-slot
 113 CODEGEN: ##set-slot-imm %set-slot-imm
 114 CODEGEN: ##string-nth %string-nth
 115 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 116 CODEGEN: ##add %add
 117 CODEGEN: ##add-imm %add-imm
 118 CODEGEN: ##sub %sub
 119 CODEGEN: ##sub-imm %sub-imm
 120 CODEGEN: ##mul %mul
 121 CODEGEN: ##mul-imm %mul-imm
 122 CODEGEN: ##and %and
 123 CODEGEN: ##and-imm %and-imm
 124 CODEGEN: ##or %or
 125 CODEGEN: ##or-imm %or-imm
 126 CODEGEN: ##xor %xor
 127 CODEGEN: ##xor-imm %xor-imm
 128 CODEGEN: ##shl %shl
 129 CODEGEN: ##shl-imm %shl-imm
 130 CODEGEN: ##shr %shr
 131 CODEGEN: ##shr-imm %shr-imm
 132 CODEGEN: ##sar %sar
 133 CODEGEN: ##sar-imm %sar-imm
 134 CODEGEN: ##min %min
 135 CODEGEN: ##max %max
 136 CODEGEN: ##not %not
 137 CODEGEN: ##neg %neg
 138 CODEGEN: ##log2 %log2
 139 CODEGEN: ##copy %copy
 140 CODEGEN: ##add-float %add-float
 141 CODEGEN: ##sub-float %sub-float
 142 CODEGEN: ##mul-float %mul-float
 143 CODEGEN: ##div-float %div-float
 144 CODEGEN: ##min-float %min-float
 145 CODEGEN: ##max-float %max-float
 146 CODEGEN: ##sqrt %sqrt
 147 CODEGEN: ##unary-float-function %unary-float-function
 148 CODEGEN: ##binary-float-function %binary-float-function
 149 CODEGEN: ##single>double-float %single>double-float
 150 CODEGEN: ##double>single-float %double>single-float
 151 CODEGEN: ##integer>float %integer>float
 152 CODEGEN: ##float>integer %float>integer
 153 CODEGEN: ##zero-vector %zero-vector
 154 CODEGEN: ##fill-vector %fill-vector
 155 CODEGEN: ##gather-vector-2 %gather-vector-2
 156 CODEGEN: ##gather-vector-4 %gather-vector-4
 157 CODEGEN: ##shuffle-vector-imm %shuffle-vector-imm
 158 CODEGEN: ##shuffle-vector %shuffle-vector
 159 CODEGEN: ##tail>head-vector %tail>head-vector
 160 CODEGEN: ##merge-vector-head %merge-vector-head
 161 CODEGEN: ##merge-vector-tail %merge-vector-tail
 162 CODEGEN: ##signed-pack-vector %signed-pack-vector
 163 CODEGEN: ##unsigned-pack-vector %unsigned-pack-vector
 164 CODEGEN: ##unpack-vector-head %unpack-vector-head
 165 CODEGEN: ##unpack-vector-tail %unpack-vector-tail
 166 CODEGEN: ##integer>float-vector %integer>float-vector
 167 CODEGEN: ##float>integer-vector %float>integer-vector
 168 CODEGEN: ##compare-vector %compare-vector
 169 CODEGEN: ##test-vector %test-vector
 170 CODEGEN: ##add-vector %add-vector
 171 CODEGEN: ##saturated-add-vector %saturated-add-vector
 172 CODEGEN: ##add-sub-vector %add-sub-vector
 173 CODEGEN: ##sub-vector %sub-vector
 174 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 175 CODEGEN: ##mul-vector %mul-vector
 176 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 177 CODEGEN: ##div-vector %div-vector
 178 CODEGEN: ##min-vector %min-vector
 179 CODEGEN: ##max-vector %max-vector
 180 CODEGEN: ##dot-vector %dot-vector
 181 CODEGEN: ##sqrt-vector %sqrt-vector
 182 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 183 CODEGEN: ##horizontal-sub-vector %horizontal-sub-vector
 184 CODEGEN: ##horizontal-shl-vector-imm %horizontal-shl-vector-imm
 185 CODEGEN: ##horizontal-shr-vector-imm %horizontal-shr-vector-imm
 186 CODEGEN: ##abs-vector %abs-vector
 187 CODEGEN: ##and-vector %and-vector
 188 CODEGEN: ##andn-vector %andn-vector
 189 CODEGEN: ##or-vector %or-vector
 190 CODEGEN: ##xor-vector %xor-vector
 191 CODEGEN: ##not-vector %not-vector
 192 CODEGEN: ##shl-vector-imm %shl-vector-imm
 193 CODEGEN: ##shr-vector-imm %shr-vector-imm
 194 CODEGEN: ##shl-vector %shl-vector
 195 CODEGEN: ##shr-vector %shr-vector
 196 CODEGEN: ##integer>scalar %integer>scalar
 197 CODEGEN: ##scalar>integer %scalar>integer
 198 CODEGEN: ##vector>scalar %vector>scalar
 199 CODEGEN: ##scalar>vector %scalar>vector
 200 CODEGEN: ##box-alien %box-alien
 201 CODEGEN: ##box-displaced-alien %box-displaced-alien
 202 CODEGEN: ##unbox-alien %unbox-alien
 203 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 204 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 205 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 206 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 207 CODEGEN: ##alien-signed-1 %alien-signed-1
 208 CODEGEN: ##alien-signed-2 %alien-signed-2
 209 CODEGEN: ##alien-signed-4 %alien-signed-4
 210 CODEGEN: ##alien-cell %alien-cell
 211 CODEGEN: ##alien-float %alien-float
 212 CODEGEN: ##alien-double %alien-double
 213 CODEGEN: ##alien-vector %alien-vector
 214 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 215 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 216 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 217 CODEGEN: ##set-alien-cell %set-alien-cell
 218 CODEGEN: ##set-alien-float %set-alien-float
 219 CODEGEN: ##set-alien-double %set-alien-double
 220 CODEGEN: ##set-alien-vector %set-alien-vector
 221 CODEGEN: ##allot %allot
 222 CODEGEN: ##write-barrier %write-barrier
 223 CODEGEN: ##write-barrier-imm %write-barrier-imm
 224 CODEGEN: ##compare %compare
 225 CODEGEN: ##compare-imm %compare-imm
 226 CODEGEN: ##compare-float-ordered %compare-float-ordered
 227 CODEGEN: ##compare-float-unordered %compare-float-unordered
 228 CODEGEN: ##save-context %save-context
 229 CODEGEN: ##vm-field-ptr %vm-field-ptr
 230
 231 CODEGEN: _fixnum-add %fixnum-add
 232 CODEGEN: _fixnum-sub %fixnum-sub
 233 CODEGEN: _fixnum-mul %fixnum-mul
 234 CODEGEN: _label resolve-label
 235 CODEGEN: _branch %jump-label
 236 CODEGEN: _compare-branch %compare-branch
 237 CODEGEN: _compare-imm-branch %compare-imm-branch
 238 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 239 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 240 CODEGEN: _test-vector-branch %test-vector-branch
 241 CODEGEN: _dispatch %dispatch
 242 CODEGEN: _spill %spill
 243 CODEGEN: _reload %reload
 244
 245 ! ##gc
 246 : wipe-locs ( locs temp -- )
 247     '[
 248         _
 249         [ 0 %load-immediate ]
 250         [ swap [ %replace ] with each ] bi
 251     ] unless-empty ;
 252
 253 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 254
 255 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 256     temp int-rep operand %reload
 257     gc-root temp %save-gc-root ;
 258
 259 M: object save-gc-root drop %save-gc-root ;
 260
 261 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 262
 263 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 264
 265 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 266
 267 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 268     gc-root temp %load-gc-root
 269     temp int-rep operand %spill ;
 270
 271 M: object load-gc-root drop %load-gc-root ;
 272
 273 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 274
 275 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 276
 277 M: ##gc generate-insn
 278     "no-gc" define-label
 279     {
 280         [ [ "no-gc" get ] dip [ size>> ] [ temp1>> ] [ temp2>> ] tri %check-nursery ]
 281         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 282         [ data-values>> save-data-regs ]
 283         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 284         [ [ temp1>> ] [ temp2>> ] bi t %save-context ]
 285         [ [ tagged-values>> length ] [ temp1>> ] bi %call-gc ]
 286         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 287         [ data-values>> load-data-regs ]
 288     } cleave
 289     "no-gc" resolve-label ;
 290
 291 M: _loop-entry generate-insn drop %loop-entry ;
 292
 293 M: ##alien-global generate-insn
 294     [ dst>> ] [ symbol>> ] [ library>> ] tri
 295     %alien-global ;
 296
 297 ! ##alien-invoke
 298 GENERIC: next-fastcall-param ( rep -- )
 299
 300 : ?dummy-stack-params ( rep -- )
 301     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 302
 303 : ?dummy-int-params ( rep -- )
 304     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 305
 306 : ?dummy-fp-params ( rep -- )
 307     drop dummy-fp-params? [ float-regs inc ] when ;
 308
 309 M: int-rep next-fastcall-param
 310     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 311
 312 M: float-rep next-fastcall-param
 313     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 314
 315 M: double-rep next-fastcall-param
 316     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 317
 318 GENERIC: reg-class-full? ( reg-class -- ? )
 319
 320 M: stack-params reg-class-full? drop t ;
 321
 322 M: reg-class reg-class-full?
 323     [ get ] [ param-regs length ] bi >= ;
 324
 325 : alloc-stack-param ( rep -- n reg-class rep )
 326     stack-params get
 327     [ rep-size cell align stack-params +@ ] dip
 328     stack-params dup ;
 329
 330 : alloc-fastcall-param ( rep -- n reg-class rep )
 331     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 332
 333 : alloc-parameter ( parameter -- reg rep )
 334     c-type-rep dup reg-class-of reg-class-full?
 335     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 336     [ param-reg ] dip ;
 337
 338 : (flatten-int-type) ( type -- seq )
 339     stack-size cell align cell /i void* c-type <repetition> ;
 340
 341 GENERIC: flatten-value-type ( type -- types )
 342
 343 M: object flatten-value-type 1array ;
 344 M: struct-c-type flatten-value-type (flatten-int-type) ;
 345 M: long-long-type flatten-value-type (flatten-int-type) ;
 346 M: c-type-name flatten-value-type c-type flatten-value-type ;
 347
 348 : flatten-value-types ( params -- params )
 349     #! Convert value type structs to consecutive void*s.
 350     [
 351         0 [
 352             c-type
 353             [ parameter-align cell /i void* c-type <repetition> % ] keep
 354             [ stack-size cell align + ] keep
 355             flatten-value-type %
 356         ] reduce drop
 357     ] { } make ;
 358
 359 : each-parameter ( parameters quot -- )
 360     [ [ parameter-offsets nip ] keep ] dip 2each ; inline
 361
 362 : reset-fastcall-counts ( -- )
 363     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 364
 365 : with-param-regs ( quot -- )
 366     #! In quot you can call alloc-parameter
 367     [ reset-fastcall-counts call ] with-scope ; inline
 368
 369 : move-parameters ( node word -- )
 370     #! Moves values from C stack to registers (if word is
 371     #! %load-param-reg) and registers to C stack (if word is
 372     #! %save-param-reg).
 373     [ alien-parameters flatten-value-types ]
 374     [ '[ alloc-parameter _ execute ] ]
 375     bi* each-parameter ; inline
 376
 377 : reverse-each-parameter ( parameters quot -- )
 378     [ [ parameter-offsets nip ] keep ] dip 2reverse-each ; inline
 379
 380 : prepare-unbox-parameters ( parameters -- offsets types indices )
 381     [ parameter-offsets nip ] [ ] [ length iota reverse ] tri ;
 382
 383 : unbox-parameters ( offset node -- )
 384     parameters>> swap
 385     '[ prepare-unbox-parameters [ %prepare-unbox [ _ + ] dip unbox-parameter ] 3each ]
 386     [ length neg %inc-d ]
 387     bi ;
 388
 389 : prepare-box-struct ( node -- offset )
 390     #! Return offset on C stack where to store unboxed
 391     #! parameters. If the C function is returning a structure,
 392     #! the first parameter is an implicit target area pointer,
 393     #! so we need to use a different offset.
 394     return>> large-struct?
 395     [ %prepare-box-struct cell ] [ 0 ] if ;
 396
 397 : objects>registers ( params -- )
 398     #! Generate code for unboxing a list of C types, then
 399     #! generate code for moving these parameters to registers on
 400     #! architectures where parameters are passed in registers.
 401     [
 402         [ prepare-box-struct ] keep
 403         [ unbox-parameters ] keep
 404         \ %load-param-reg move-parameters
 405     ] with-param-regs ;
 406
 407 : box-return* ( node -- )
 408     return>> [ ] [ box-return ] if-void ;
 409
 410 : check-dlsym ( symbols dll -- )
 411     dup dll-valid? [
 412         dupd '[ _ dlsym ] any?
 413         [ drop ] [ compiling-word get no-such-symbol ] if
 414     ] [
 415         dll-path compiling-word get no-such-library drop
 416     ] if ;
 417
 418 : stdcall-mangle ( symbol params -- symbol )
 419     parameters>> parameter-offsets drop number>string "@" glue ;
 420
 421 : alien-invoke-dlsym ( params -- symbols dll )
 422     [ [ function>> dup ] keep stdcall-mangle 2array ]
 423     [ library>> library dup [ dll>> ] when ]
 424     bi 2dup check-dlsym ;
 425
 426 M: ##alien-invoke generate-insn
 427     params>>
 428     ! Unbox parameters
 429     dup objects>registers
 430     %prepare-var-args
 431     ! Call function
 432     dup alien-invoke-dlsym %alien-invoke
 433     ! Box return value
 434     dup %cleanup
 435     box-return* ;
 436
 437 ! ##alien-indirect
 438 M: ##alien-indirect generate-insn
 439     params>>
 440     ! Save alien at top of stack to temporary storage
 441     %prepare-alien-indirect
 442     ! Unbox parameters
 443     dup objects>registers
 444     %prepare-var-args
 445     ! Call alien in temporary storage
 446     %alien-indirect
 447     ! Box return value
 448     dup %cleanup
 449     box-return* ;
 450
 451 ! ##alien-callback
 452 : box-parameters ( params -- )
 453     alien-parameters [ box-parameter ] each-parameter ;
 454
 455 : registers>objects ( node -- )
 456     ! Generate code for boxing input parameters in a callback.
 457     [
 458         dup \ %save-param-reg move-parameters
 459         %nest-stacks
 460         box-parameters
 461     ] with-param-regs ;
 462
 463 TUPLE: callback-context ;
 464
 465 : current-callback ( -- id ) 2 getenv ;
 466
 467 : wait-to-return ( token -- )
 468     dup current-callback eq? [
 469         drop
 470     ] [
 471         yield-hook get call( -- ) wait-to-return
 472     ] if ;
 473
 474 : do-callback ( quot token -- )
 475     init-catchstack
 476     [ 2 setenv call ] keep
 477     wait-to-return ; inline
 478
 479 : callback-return-quot ( ctype -- quot )
 480     return>> {
 481         { [ dup void? ] [ drop [ ] ] }
 482         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 483         [ c-type c-type-unboxer-quot ]
 484     } cond ;
 485
 486 : callback-prep-quot ( params -- quot )
 487     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 488
 489 : wrap-callback-quot ( params -- quot )
 490     [
 491         [ callback-prep-quot ]
 492         [ quot>> ]
 493         [ callback-return-quot ] tri 3append ,
 494         [ callback-context new do-callback ] %
 495     ] [ ] make ;
 496
 497 M: ##callback-return generate-insn
 498     #! All the extra book-keeping for %unwind is only for x86.
 499     #! On other platforms its an alias for %return.
 500     params>> %callback-return ;
 501
 502 M: ##alien-callback generate-insn
 503     params>>
 504     [ registers>objects ]
 505     [ wrap-callback-quot %alien-callback ]
 506     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 507     tri ;