basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes classes.struct locals
   8 source-files.errors slots parser generic.parser strings
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 FROM: namespaces => set ;
  20 IN: compiler.codegen
  21
  22 SYMBOL: insn-counts
  23
  24 H{ } clone insn-counts set-global
  25
  26 GENERIC: generate-insn ( insn -- )
  27
  28 ! Mapping _label IDs to label instances
  29 SYMBOL: labels
  30
  31 : generate ( mr -- code )
  32     dup label>> [
  33         H{ } clone labels set
  34         instructions>> [
  35             [ class insn-counts get inc-at ]
  36             [ generate-insn ]
  37             bi
  38         ] each
  39     ] with-fixup ;
  40
  41 : lookup-label ( id -- label )
  42     labels get [ drop <label> ] cache ;
  43
  44 ! Special cases
  45 M: ##no-tco generate-insn drop ;
  46
  47 M: _dispatch-label generate-insn
  48     label>> lookup-label
  49     cell 0 <repetition> %
  50     rc-absolute-cell label-fixup ;
  51
  52 M: _prologue generate-insn
  53     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  54
  55 M: _epilogue generate-insn
  56     stack-frame>> total-size>> %epilogue ;
  57
  58 M: _spill-area-size generate-insn drop ;
  59
  60 ! Some meta-programming to generate simple code generators, where
  61 ! the instruction is unpacked and then a %word is called
  62 <<
  63
  64 : insn-slot-quot ( spec -- quot )
  65     name>> [ reader-word ] [ "label" = ] bi
  66     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  67
  68 : codegen-method-body ( class word -- quot )
  69     [
  70         "insn-slots" word-prop
  71         [ insn-slot-quot ] map cleave>quot
  72     ] dip suffix ;
  73
  74 SYNTAX: CODEGEN:
  75     scan-word [ \ generate-insn create-method-in ] keep scan-word
  76     codegen-method-body define ;
  77 >>
  78
  79 CODEGEN: ##load-immediate %load-immediate
  80 CODEGEN: ##load-reference %load-reference
  81 CODEGEN: ##load-constant %load-reference
  82 CODEGEN: ##peek %peek
  83 CODEGEN: ##replace %replace
  84 CODEGEN: ##inc-d %inc-d
  85 CODEGEN: ##inc-r %inc-r
  86 CODEGEN: ##call %call
  87 CODEGEN: ##jump %jump
  88 CODEGEN: ##return %return
  89 CODEGEN: ##slot %slot
  90 CODEGEN: ##slot-imm %slot-imm
  91 CODEGEN: ##set-slot %set-slot
  92 CODEGEN: ##set-slot-imm %set-slot-imm
  93 CODEGEN: ##string-nth %string-nth
  94 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
  95 CODEGEN: ##add %add
  96 CODEGEN: ##add-imm %add-imm
  97 CODEGEN: ##sub %sub
  98 CODEGEN: ##sub-imm %sub-imm
  99 CODEGEN: ##mul %mul
 100 CODEGEN: ##mul-imm %mul-imm
 101 CODEGEN: ##and %and
 102 CODEGEN: ##and-imm %and-imm
 103 CODEGEN: ##or %or
 104 CODEGEN: ##or-imm %or-imm
 105 CODEGEN: ##xor %xor
 106 CODEGEN: ##xor-imm %xor-imm
 107 CODEGEN: ##shl %shl
 108 CODEGEN: ##shl-imm %shl-imm
 109 CODEGEN: ##shr %shr
 110 CODEGEN: ##shr-imm %shr-imm
 111 CODEGEN: ##sar %sar
 112 CODEGEN: ##sar-imm %sar-imm
 113 CODEGEN: ##min %min
 114 CODEGEN: ##max %max
 115 CODEGEN: ##not %not
 116 CODEGEN: ##neg %neg
 117 CODEGEN: ##log2 %log2
 118 CODEGEN: ##copy %copy
 119 CODEGEN: ##add-float %add-float
 120 CODEGEN: ##sub-float %sub-float
 121 CODEGEN: ##mul-float %mul-float
 122 CODEGEN: ##div-float %div-float
 123 CODEGEN: ##min-float %min-float
 124 CODEGEN: ##max-float %max-float
 125 CODEGEN: ##sqrt %sqrt
 126 CODEGEN: ##unary-float-function %unary-float-function
 127 CODEGEN: ##binary-float-function %binary-float-function
 128 CODEGEN: ##single>double-float %single>double-float
 129 CODEGEN: ##double>single-float %double>single-float
 130 CODEGEN: ##integer>float %integer>float
 131 CODEGEN: ##float>integer %float>integer
 132 CODEGEN: ##zero-vector %zero-vector
 133 CODEGEN: ##fill-vector %fill-vector
 134 CODEGEN: ##gather-vector-2 %gather-vector-2
 135 CODEGEN: ##gather-vector-4 %gather-vector-4
 136 CODEGEN: ##shuffle-vector-imm %shuffle-vector-imm
 137 CODEGEN: ##shuffle-vector %shuffle-vector
 138 CODEGEN: ##tail>head-vector %tail>head-vector
 139 CODEGEN: ##merge-vector-head %merge-vector-head
 140 CODEGEN: ##merge-vector-tail %merge-vector-tail
 141 CODEGEN: ##signed-pack-vector %signed-pack-vector
 142 CODEGEN: ##unsigned-pack-vector %unsigned-pack-vector
 143 CODEGEN: ##unpack-vector-head %unpack-vector-head
 144 CODEGEN: ##unpack-vector-tail %unpack-vector-tail
 145 CODEGEN: ##integer>float-vector %integer>float-vector
 146 CODEGEN: ##float>integer-vector %float>integer-vector
 147 CODEGEN: ##compare-vector %compare-vector
 148 CODEGEN: ##test-vector %test-vector
 149 CODEGEN: ##add-vector %add-vector
 150 CODEGEN: ##saturated-add-vector %saturated-add-vector
 151 CODEGEN: ##add-sub-vector %add-sub-vector
 152 CODEGEN: ##sub-vector %sub-vector
 153 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 154 CODEGEN: ##mul-vector %mul-vector
 155 CODEGEN: ##mul-high-vector %mul-high-vector
 156 CODEGEN: ##mul-horizontal-add-vector %mul-horizontal-add-vector
 157 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 158 CODEGEN: ##div-vector %div-vector
 159 CODEGEN: ##min-vector %min-vector
 160 CODEGEN: ##max-vector %max-vector
 161 CODEGEN: ##avg-vector %avg-vector
 162 CODEGEN: ##dot-vector %dot-vector
 163 CODEGEN: ##sad-vector %sad-vector
 164 CODEGEN: ##sqrt-vector %sqrt-vector
 165 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 166 CODEGEN: ##horizontal-sub-vector %horizontal-sub-vector
 167 CODEGEN: ##horizontal-shl-vector-imm %horizontal-shl-vector-imm
 168 CODEGEN: ##horizontal-shr-vector-imm %horizontal-shr-vector-imm
 169 CODEGEN: ##abs-vector %abs-vector
 170 CODEGEN: ##and-vector %and-vector
 171 CODEGEN: ##andn-vector %andn-vector
 172 CODEGEN: ##or-vector %or-vector
 173 CODEGEN: ##xor-vector %xor-vector
 174 CODEGEN: ##not-vector %not-vector
 175 CODEGEN: ##shl-vector-imm %shl-vector-imm
 176 CODEGEN: ##shr-vector-imm %shr-vector-imm
 177 CODEGEN: ##shl-vector %shl-vector
 178 CODEGEN: ##shr-vector %shr-vector
 179 CODEGEN: ##integer>scalar %integer>scalar
 180 CODEGEN: ##scalar>integer %scalar>integer
 181 CODEGEN: ##vector>scalar %vector>scalar
 182 CODEGEN: ##scalar>vector %scalar>vector
 183 CODEGEN: ##box-alien %box-alien
 184 CODEGEN: ##box-displaced-alien %box-displaced-alien
 185 CODEGEN: ##unbox-alien %unbox-alien
 186 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 187 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 188 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 189 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 190 CODEGEN: ##alien-signed-1 %alien-signed-1
 191 CODEGEN: ##alien-signed-2 %alien-signed-2
 192 CODEGEN: ##alien-signed-4 %alien-signed-4
 193 CODEGEN: ##alien-cell %alien-cell
 194 CODEGEN: ##alien-float %alien-float
 195 CODEGEN: ##alien-double %alien-double
 196 CODEGEN: ##alien-vector %alien-vector
 197 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 198 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 199 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 200 CODEGEN: ##set-alien-cell %set-alien-cell
 201 CODEGEN: ##set-alien-float %set-alien-float
 202 CODEGEN: ##set-alien-double %set-alien-double
 203 CODEGEN: ##set-alien-vector %set-alien-vector
 204 CODEGEN: ##allot %allot
 205 CODEGEN: ##write-barrier %write-barrier
 206 CODEGEN: ##write-barrier-imm %write-barrier-imm
 207 CODEGEN: ##compare %compare
 208 CODEGEN: ##compare-imm %compare-imm
 209 CODEGEN: ##compare-float-ordered %compare-float-ordered
 210 CODEGEN: ##compare-float-unordered %compare-float-unordered
 211 CODEGEN: ##save-context %save-context
 212 CODEGEN: ##vm-field-ptr %vm-field-ptr
 213
 214 CODEGEN: _fixnum-add %fixnum-add
 215 CODEGEN: _fixnum-sub %fixnum-sub
 216 CODEGEN: _fixnum-mul %fixnum-mul
 217 CODEGEN: _label resolve-label
 218 CODEGEN: _branch %jump-label
 219 CODEGEN: _compare-branch %compare-branch
 220 CODEGEN: _compare-imm-branch %compare-imm-branch
 221 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 222 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 223 CODEGEN: _test-vector-branch %test-vector-branch
 224 CODEGEN: _dispatch %dispatch
 225 CODEGEN: _spill %spill
 226 CODEGEN: _reload %reload
 227
 228 ! ##gc
 229 : wipe-locs ( locs temp -- )
 230     '[
 231         _
 232         [ 0 %load-immediate ]
 233         [ swap [ %replace ] with each ] bi
 234     ] unless-empty ;
 235
 236 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 237
 238 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 239     temp int-rep operand %reload
 240     gc-root temp %save-gc-root ;
 241
 242 M: object save-gc-root drop %save-gc-root ;
 243
 244 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 245
 246 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 247
 248 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 249
 250 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 251     gc-root temp %load-gc-root
 252     temp int-rep operand %spill ;
 253
 254 M: object load-gc-root drop %load-gc-root ;
 255
 256 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 257
 258 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 259
 260 M: ##gc generate-insn
 261     "no-gc" define-label
 262     {
 263         [ [ "no-gc" get ] dip [ size>> ] [ temp1>> ] [ temp2>> ] tri %check-nursery ]
 264         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 265         [ data-values>> save-data-regs ]
 266         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 267         [ [ temp1>> ] [ temp2>> ] bi %save-context ]
 268         [ [ tagged-values>> length ] [ temp1>> ] bi %call-gc ]
 269         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 270         [ data-values>> load-data-regs ]
 271     } cleave
 272     "no-gc" resolve-label ;
 273
 274 M: _loop-entry generate-insn drop %loop-entry ;
 275
 276 M: ##alien-global generate-insn
 277     [ dst>> ] [ symbol>> ] [ library>> ] tri
 278     %alien-global ;
 279
 280 ! ##alien-invoke
 281 GENERIC: next-fastcall-param ( rep -- )
 282
 283 : ?dummy-stack-params ( rep -- )
 284     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 285
 286 : ?dummy-int-params ( rep -- )
 287     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 288
 289 : ?dummy-fp-params ( rep -- )
 290     drop dummy-fp-params? [ float-regs inc ] when ;
 291
 292 M: int-rep next-fastcall-param
 293     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 294
 295 M: float-rep next-fastcall-param
 296     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 297
 298 M: double-rep next-fastcall-param
 299     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 300
 301 GENERIC: reg-class-full? ( reg-class -- ? )
 302
 303 M: stack-params reg-class-full? drop t ;
 304
 305 M: reg-class reg-class-full?
 306     [ get ] [ param-regs length ] bi >= ;
 307
 308 : alloc-stack-param ( rep -- n reg-class rep )
 309     stack-params get
 310     [ rep-size cell align stack-params +@ ] dip
 311     stack-params dup ;
 312
 313 : alloc-fastcall-param ( rep -- n reg-class rep )
 314     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 315
 316 : alloc-parameter ( parameter -- reg rep )
 317     c-type-rep dup reg-class-of reg-class-full?
 318     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 319     [ param-reg ] dip ;
 320
 321 : (flatten-int-type) ( type -- seq )
 322     stack-size cell align cell /i void* c-type <repetition> ;
 323
 324 GENERIC: flatten-value-type ( type -- types )
 325
 326 M: object flatten-value-type 1array ;
 327 M: struct-c-type flatten-value-type (flatten-int-type) ;
 328 M: long-long-type flatten-value-type (flatten-int-type) ;
 329 M: c-type-name flatten-value-type c-type flatten-value-type ;
 330
 331 : flatten-value-types ( params -- params )
 332     #! Convert value type structs to consecutive void*s.
 333     [
 334         0 [
 335             c-type
 336             [ parameter-align cell /i void* c-type <repetition> % ] keep
 337             [ stack-size cell align + ] keep
 338             flatten-value-type %
 339         ] reduce drop
 340     ] { } make ;
 341
 342 : each-parameter ( parameters quot -- )
 343     [ [ parameter-offsets nip ] keep ] dip 2each ; inline
 344
 345 : reset-fastcall-counts ( -- )
 346     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 347
 348 : with-param-regs ( quot -- )
 349     #! In quot you can call alloc-parameter
 350     [ reset-fastcall-counts call ] with-scope ; inline
 351
 352 : move-parameters ( node word -- )
 353     #! Moves values from C stack to registers (if word is
 354     #! %load-param-reg) and registers to C stack (if word is
 355     #! %save-param-reg).
 356     [ alien-parameters flatten-value-types ]
 357     [ '[ alloc-parameter _ execute ] ]
 358     bi* each-parameter ; inline
 359
 360 : reverse-each-parameter ( parameters quot -- )
 361     [ [ parameter-offsets nip ] keep ] dip 2reverse-each ; inline
 362
 363 : prepare-unbox-parameters ( parameters -- offsets types indices )
 364     [ parameter-offsets nip ] [ ] [ length iota <reversed> ] tri ;
 365
 366 : unbox-parameters ( offset node -- )
 367     parameters>> swap
 368     '[ prepare-unbox-parameters [ %pop-stack [ _ + ] dip unbox-parameter ] 3each ]
 369     [ length neg %inc-d ]
 370     bi ;
 371
 372 : prepare-box-struct ( node -- offset )
 373     #! Return offset on C stack where to store unboxed
 374     #! parameters. If the C function is returning a structure,
 375     #! the first parameter is an implicit target area pointer,
 376     #! so we need to use a different offset.
 377     return>> large-struct?
 378     [ %prepare-box-struct cell ] [ 0 ] if ;
 379
 380 : objects>registers ( params -- )
 381     #! Generate code for unboxing a list of C types, then
 382     #! generate code for moving these parameters to registers on
 383     #! architectures where parameters are passed in registers.
 384     [
 385         [ prepare-box-struct ] keep
 386         [ unbox-parameters ] keep
 387         \ %load-param-reg move-parameters
 388     ] with-param-regs ;
 389
 390 : box-return* ( node -- )
 391     return>> [ ] [ box-return %push-stack ] if-void ;
 392
 393 GENERIC# dlsym-valid? 1 ( symbols dll -- ? )
 394
 395 M: string dlsym-valid? dlsym ;
 396
 397 M: array dlsym-valid? '[ _ dlsym ] any? ;
 398
 399 : check-dlsym ( symbols dll -- )
 400     dup dll-valid? [
 401         dupd dlsym-valid?
 402         [ drop ] [ compiling-word get no-such-symbol ] if
 403     ] [
 404         dll-path compiling-word get no-such-library drop
 405     ] if ;
 406
 407 : stdcall-mangle ( params -- symbols )
 408     [ function>> ] [ parameters>> parameter-offsets drop number>string ] bi
 409     [ drop ] [ "@" glue ] [ "@" glue "_" prepend ] 2tri
 410     3array ;
 411
 412 : alien-invoke-dlsym ( params -- symbols dll )
 413     [ dup abi>> "stdcall" = [ stdcall-mangle ] [ function>> ] if ]
 414     [ library>> load-library ]
 415     bi 2dup check-dlsym ;
 416
 417 M: ##alien-invoke generate-insn
 418     params>>
 419     ! Unbox parameters
 420     dup objects>registers
 421     %prepare-var-args
 422     ! Call function
 423     dup alien-invoke-dlsym %alien-invoke
 424     ! Box return value
 425     dup %cleanup
 426     box-return* ;
 427
 428 M: ##alien-assembly generate-insn
 429     params>>
 430     ! Unbox parameters
 431     dup objects>registers
 432     %prepare-var-args
 433     ! Generate assembly
 434     dup quot>> call( -- )
 435     ! Box return value
 436     box-return* ;
 437
 438 ! ##alien-indirect
 439 M: ##alien-indirect generate-insn
 440     params>>
 441     ! Save alien at top of stack to temporary storage
 442     %prepare-alien-indirect
 443     ! Unbox parameters
 444     dup objects>registers
 445     %prepare-var-args
 446     ! Call alien in temporary storage
 447     %alien-indirect
 448     ! Box return value
 449     dup %cleanup
 450     box-return* ;
 451
 452 ! ##alien-callback
 453 : box-parameters ( params -- )
 454     alien-parameters [ box-parameter %push-context-stack ] each-parameter ;
 455
 456 : registers>objects ( node -- )
 457     ! Generate code for boxing input parameters in a callback.
 458     [
 459         dup \ %save-param-reg move-parameters
 460         %nest-stacks
 461         box-parameters
 462     ] with-param-regs ;
 463
 464 TUPLE: callback-context ;
 465
 466 : current-callback ( -- id ) 2 special-object ;
 467
 468 : wait-to-return ( token -- )
 469     dup current-callback eq? [
 470         drop
 471     ] [
 472         yield-hook get call( -- ) wait-to-return
 473     ] if ;
 474
 475 : do-callback ( quot token -- )
 476     init-catchstack
 477     [ 2 set-special-object call ] keep
 478     wait-to-return ; inline
 479
 480 : callback-return-quot ( ctype -- quot )
 481     return>> {
 482         { [ dup void? ] [ drop [ ] ] }
 483         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 484         [ c-type c-type-unboxer-quot ]
 485     } cond ;
 486
 487 : callback-prep-quot ( params -- quot )
 488     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 489
 490 : wrap-callback-quot ( params -- quot )
 491     [
 492         [ callback-prep-quot ]
 493         [ quot>> ]
 494         [ callback-return-quot ] tri 3append ,
 495         [ callback-context new do-callback ] %
 496     ] [ ] make ;
 497
 498 M: ##alien-callback generate-insn
 499     params>>
 500     [ registers>objects ]
 501     [ wrap-callback-quot %alien-callback ]
 502     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 503     tri ;